Idea使用Groovy脚本生成代码
配置Database
Idea安装插件Database tools and SQL,一般安装默认会有,社区版是不支持安装此插件的。
设置完链接之后,可以对表进行一些操作,利用groovy脚本可以快速生成代码。
右键->Tools->scripted extensions->选择脚本
生成代码
生成pojo代码
import com.intellij.database.model.DasTable
import com.intellij.database.util.Case
import com.intellij.database.util.DasUtil
import java.text.SimpleDateFormat
/*
* Available context bindings:
* SELECTION Iterable<DasObject>
* PROJECT project
* FILES files helper
*/
packageName = "com.sample;"
typeMapping = [
(~/(?i)int8/) : "Long",
(~/(?i)tinyint/) : "Integer",
(~/(?i)int/) : "Integer",
(~/(?i)bool/) : "Boolean",
(~/(?i)float|double|decimal|real/): "Double",
(~/(?i)jsonb/) : "String",
(~/(?i)datetime|timestamp/) : "LocalDateTime",
(~/(?i)date/) : "Date",
(~/(?i)time/) : "Time",
(~/(?i)/) : "String"
]
FILES.chooseDirectoryAndSave("Choose directory", "Choose where to store generated files") { dir ->
SELECTION.filter { it instanceof DasTable }.each { generate(it, dir) }
}
def generate(table, dir) {
def className = javaName(table.getName(), true)
def fields = calcFields(table)
packageName = getPackageName(dir)
new File(dir, className + ".java").withPrintWriter { out -> generate(out, className, fields) }
}
// 获取包所在文件夹路径
def getPackageName(dir) {
return dir.toString().replaceAll("\\\\", ".").replaceAll("/", ".").replaceAll("^.*src(\\.main\\.java\\.)?", "") + ";"
}
def generate(out, className, fields) {
out.println "package $packageName"
out.println ""
out.println "import java.io.Serializable;"
out.println "import java.time.LocalDateTime;"
out.println "import java.util.Date;"
out.println "import java.sql.Time;"
out.println "import lombok.Data;"
out.println "import lombok.AllArgsConstructor;"
out.println "import lombok.NoArgsConstructor;"
out.println ""
out.println '''
/**
* @author: author
* @date: '''+new SimpleDateFormat("yyyy-MM-dd HH:mm:ss").format(new Date()) +'''
* @description:
*/'''
out.println ""
out.println "@Data"
out.println "@NoArgsConstructor"
out.println "@AllArgsConstructor"
out.println "public class $className implements Serializable {"
out.println " private static final long serialVersionUID = 1L;"
out.println ""
fields.each() {
if (it.annos != "") out.println " ${it.annos}"
out.println " private ${it.type} ${it.name};"
}
out.println ""
// fields.each() {
// out.println ""
// out.println " public ${it.type} get${it.name.capitalize()}() {"
// out.println " return ${it.name};"
// out.println " }"
// out.println ""
// out.println " public void set${it.name.capitalize()}(${it.type} ${it.name}) {"
// out.println " this.${it.name} = ${it.name};"
// out.println " }"
// out.println ""
// }
out.println "}"
}
def calcFields(table) {
DasUtil.getColumns(table).reduce([]) { fields, col ->
def spec = Case.LOWER.apply(col.getDasType().getSpecification())
def typeStr = typeMapping.find { p, t -> p.matcher(spec).find() }.value
fields += [[
name : javaName(col.getName(), false),
type : typeStr,
annos: ""]]
}
}
def javaName(str, capitalize) {
def s = com.intellij.psi.codeStyle.NameUtil.splitNameIntoWords(str)
.collect { Case.LOWER.apply(it).capitalize() }
.join("")
.replaceAll(/[^\p{javaJavaIdentifierPart}[_]]/, "_")
capitalize || s.length() == 1? s : Case.LOWER.apply(s[0]) + s[1..-1]
}
生成CustomMapper代码
package cn.example.vo
import com.intellij.database.model.DasTable
import com.intellij.database.util.Case
import com.intellij.database.util.DasUtil
import java.text.SimpleDateFormat
/*
* Available context bindings:
* SELECTION Iterable<DasObject>
* PROJECT project
* FILES files helper
*/
packageName = "com.sample;"
tableName = ""
FILES.chooseDirectoryAndSave("Choose directory", "Choose where to store generated files") { dir ->
SELECTION.filter { it instanceof DasTable }.each { generate(it, dir) }
}
def generate(table, dir) {
tableName = table.getName()
def className = javaName(table.getName(), true)
def fields = calcFields(table)
packageName = getPackageName(dir)
new File(dir, className + "CustomMapper.java").withPrintWriter { out -> generateInterface(out, className, fields) }
new File(dir, className + "CustomMapper.xml").withPrintWriter { out -> generateXml(out, className, fields) }
}
// 获取包所在文件夹路径
def getPackageName(dir) {
return dir.toString().replaceAll("\\\\", ".").replaceAll("/", ".").replaceAll("^.*src(\\.main\\.java\\.)?", "");
}
def generateInterface(out, className, fields) {
out.println "package $packageName;"
out.println ""
out.println "import org.apache.ibatis.annotations.Mapper;"
out.println "import org.apache.ibatis.annotations.Param;"
out.println "import java.util.List;"
out.println ""
out.println '''
/**
* @author: author
* @date: '''+new SimpleDateFormat("yyyy-MM-dd HH:mm:ss").format(new Date()) +'''
* @description:
*/'''
out.println ""
out.println "@Mapper"
out.println "public interface ${className}CustomMapper {"
out.println "void batchInsert(@Param(\"list\") List<$className> list);"
out.println ""
out.println "}"
}
def generateXml(out, className, fields) {
out.println "<?xml version=\"1.0\" encoding=\"UTF-8\"?>"
out.println "<!DOCTYPE mapper PUBLIC \"-//mybatis.org//DTD Mapper 3.0//EN\" \"http://mybatis.org/dtd/mybatis-3-mapper.dtd\">"
out.println "<mapper namespace=\"$packageName.${className}CustomMapper\">"
out.println ""
out.println " <insert id=\"batchInsert\">"
out.print " INSERT INTO $tableName("
fields.eachWithIndex(){ it,i ->{
out.print "`${it.colName}`"
if(i<fields.size()-1){
out.print ","
}
}
}
out.println ") VALUES"
out.println " <foreach open='' close='' collection='list' item='item' separator=','>"
out.print " ("
fields.eachWithIndex(){ it,i ->{
out.print "#{item.${it.name}}"
if(i<fields.size()-1){
out.print ","
}
}
}
out.println ")"
out.println " </foreach>"
out.println " </insert>"
out.println "</mapper>"
}
def calcFields(table) {
DasUtil.getColumns(table).reduce([]) { fields, col ->
def spec = Case.LOWER.apply(col.getDasType().getSpecification())
fields += [[
colName:col.getName(),
name : javaName(col.getName(), false),
annos: ""]]
}
}
def javaName(str, capitalize) {
def s = com.intellij.psi.codeStyle.NameUtil.splitNameIntoWords(str)
.collect { Case.LOWER.apply(it).capitalize() }
.join("")
.replaceAll(/[^\p{javaJavaIdentifierPart}[_]]/, "_")
capitalize || s.length() == 1? s : Case.LOWER.apply(s[0]) + s[1..-1]
}