<自己动手写操作系统>第三章——pmtest3源码解析：使用LDT

最新推荐文章于 2020-10-24 23:15:12 发布
最新推荐文章于 2020-10-24 23:15:12 发布
阅读量2.1k 收藏 3
点赞数
分类专栏： 自己动手写操作系统 文章标签： 自己动手写操作系统 保护模式 LDT
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/trochiluses/article/details/20442291
版权
摘要：在本节中，我们将添加一个LDT段，在段中打印一个字符L，从而学习如何利用程序的LDT段。程序的执行流程随之也会发生变化，我们将分析代码和分析代码结构。


一、概要分析：

在pmtest2的基础上，我们增加一个段LDT和一个LDT中的一个段codeA。需要注意的是，LDT存在的前提是GDT，因为LDT本身是一个段中，需要由GDT中的信息，得到基地址。另外，这个场景，给出了段选择子，我们如何去索引描述符呢？思考以后，我们知道，我们需要判断但选择子属于GDT还是LDT中的段——这个需要通过选择子的第二位来判断。


我们来理一下程序的执行流程：
初始在实模式下，初始化GDT段描述符，做好进入保护模式的准备工作，经过一个长跳转，进入
保护模式32b代码段，加载相关段选择子，打印相关字符串信息，加载ldtr，进入局部任务codeA段
局部任务段codeA：打印字符，跳转到GDT中的code16段；
code16段：初始化相关寄存器，然后重新跳回实模式（通过jmp0）


二、代码解惑

注意，selector部分是不暂用GDT的存储空间的，所以计算GDT的时候，不包括selector部分。另外，汇编与一些高级语言相比，之所以在程序上难以理解，主要是因为它的结构化不是很强，也没有什么模块的概念，完全是计算的最底层，通过顺序，判断，跳转三条基本的指令来完成相应的功能。这就导致，程序之间的耦合性比较大，调用函数输入和输出不是很明显，所以会比较困难。另外，有很多处理器架构和汇编本身的语法问题，也给理解带来了额外的困难。为了理解代码，我们需要有如下的意识：


1）一个段往往是为了完成特定的功能（存储数据或者执行代码）：比如说，初始的实模式下的段，就是为了进入保护模式，那么就需要设置GDT、CR0、关中断、打开A20、跳转等。进入保护模式下32b的代码段之后，需要打印字符串信息和跳转到LDT中的段，所以需要设置相应的段寄存器....等等，只有从宏观上理解了程序的执行流程，才能写出代码。代码段是逻辑的主体，数据段主要完成数据结构的定义等。
2)另外，要注意的是，很多东西都是通过寄存器的设置来实现的：访问GDT之前要设置GDTR，同理有ss、ds、cs、sp、ldtr等。 

代码如下：
; ==========================================
; pmtest3.asm
; 编译方法：nasm pmtest3.asm -o pmtest3.com
; ==========================================


%include	"pm.inc"	; 常量, 宏, 以及一些说明


org	0100h
	jmp	LABEL_BEGIN


[SECTION .gdt]
; GDT
;                                         段基址,       段界限     , 属性
LABEL_GDT:		Descriptor	       0,                 0, 0     		; 空描述符
LABEL_DESC_NORMAL:	Descriptor	       0,            0ffffh, DA_DRW		; Normal 描述符
LABEL_DESC_CODE32:	Descriptor	       0,  SegCode32Len - 1, DA_C + DA_32	; 非一致代码段, 32
LABEL_DESC_CODE16:	Descriptor	       0,            0ffffh, DA_C		; 非一致代码段, 16
LABEL_DESC_DATA:	Descriptor	       0,	DataLen - 1, DA_DRW		; Data
LABEL_DESC_STACK:	Descriptor	       0,        TopOfStack, DA_DRWA + DA_32	; Stack, 32 位
LABEL_DESC_LDT:		Descriptor	       0,        LDTLen - 1, DA_LDT		; LDT
LABEL_DESC_VIDEO:	Descriptor	 0B8000h,            0ffffh, DA_DRW		; 显存首地址
; GDT 结束


GdtLen		equ	$ - LABEL_GDT	; GDT长度
GdtPtr		dw	GdtLen - 1	; GDT界限
		dd	0		; GDT基地址


; GDT 选择子
SelectorNormal		equ	LABEL_DESC_NORMAL	- LABEL_GDT
SelectorCode32		equ	LABEL_DESC_CODE32	- LABEL_GDT
SelectorCode16		equ	LABEL_DESC_CODE16	- LABEL_GDT
SelectorData		equ	LABEL_DESC_DATA		- LABEL_GDT
SelectorStack		equ	LABEL_DESC_STACK	- LABEL_GDT
SelectorLDT		equ	LABEL_DESC_LDT		- LABEL_GDT
SelectorVideo		equ	LABEL_DESC_VIDEO	- LABEL_GDT
; END of [SECTION .gdt]


[SECTION .data1]	 ; 数据段
ALIGN	32
[BITS	32]
LABEL_DATA:
SPValueInRealMode	dw	0
; 字符串
PMMessage:		db	"In Protect Mode now. ^-^", 0	; 进入保护模式后显示此字符串
OffsetPMMessage		equ	PMMessage - $$
StrTest:		db	"ABCDEFGHIJKLMNOPQRSTUVWXYZ", 0
OffsetStrTest		equ	StrTest - $$
DataLen			equ	$ - LABEL_DATA
; END of [SECTION .data1]




; 全局堆栈段
[SECTION .gs]
ALIGN	32
[BITS	32]
LABEL_STACK:
	times 512 db 0


TopOfStack	equ	$ - LABEL_STACK - 1


; END of [SECTION .gs]




[SECTION .s16]
[BITS	16]
LABEL_BEGIN:
	mov	ax, cs
	mov	ds, ax
	mov	es, ax
	mov	ss, ax
	mov	sp, 0100h


	mov	[LABEL_GO_BACK_TO_REAL+3], ax
	mov	[SPValueInRealMode], sp


	; 初始化 16 位代码段描述符
	mov	ax, cs
	movzx	eax, ax
	shl	eax, 4
	add	eax, LABEL_SEG_CODE16
	mov	word [LABEL_DESC_CODE16 + 2], ax
	shr	eax, 16
	mov	byte [LABEL_DESC_CODE16 + 4], al
	mov	byte [LABEL_DESC_CODE16 + 7], ah


	; 初始化 32 位代码段描述符
	xor	eax, eax
	mov	ax, cs
	shl	eax, 4
	add	eax, LABEL_SEG_CODE32
	mov	word [LABEL_DESC_CODE32 + 2], ax
	shr	eax, 16
	mov	byte [LABEL_DESC_CODE32 + 4], al
	mov	byte [LABEL_DESC_CODE32 + 7], ah


	; 初始化数据段描述符
	xor	eax, eax
	mov	ax, ds
	shl	eax, 4
	add	eax, LABEL_DATA
	mov	word [LABEL_DESC_DATA + 2], ax
	shr	eax, 16
	mov	byte [LABEL_DESC_DATA + 4], al
	mov	byte [LABEL_DESC_DATA + 7], ah


	; 初始化堆栈段描述符
	xor	eax, eax
	mov	ax, ds
	shl	eax, 4
	add	eax, LABEL_STACK
	mov	word [LABEL_DESC_STACK + 2], ax
	shr	eax, 16
	mov	byte [LABEL_DESC_STACK + 4], al
	mov	byte [LABEL_DESC_STACK + 7], ah


	; 初始化 LDT 在 GDT 中的描述符
	xor	eax, eax
	mov	ax, ds
	shl	eax, 4
	add	eax, LABEL_LDT
	mov	word [LABEL_DESC_LDT + 2], ax
	shr	eax, 16
	mov	byte [LABEL_DESC_LDT + 4], al
	mov	byte [LABEL_DESC_LDT + 7], ah


	; 初始化 LDT 中的描述符
	xor	eax, eax
	mov	ax, ds
	shl	eax, 4
	add	eax, LABEL_CODE_A
	mov	word [LABEL_LDT_DESC_CODEA + 2], ax
	shr	eax, 16
	mov	byte [LABEL_LDT_DESC_CODEA + 4], al
	mov	byte [LABEL_LDT_DESC_CODEA + 7], ah


	; 为加载 GDTR 作准备
	xor	eax, eax
	mov	ax, ds
	shl	eax, 4
	add	eax, LABEL_GDT		; eax <- gdt 基地址
	mov	dword [GdtPtr + 2], eax	; [GdtPtr + 2] <- gdt 基地址


	; 加载 GDTR
	lgdt	[GdtPtr]


	; 关中断
	cli


	; 打开地址线A20
	in	al, 92h
	or	al, 00000010b
	out	92h, al


	; 准备切换到保护模式
	mov	eax, cr0
	or	eax, 1
	mov	cr0, eax


	; 真正进入保护模式
	jmp	dword SelectorCode32:0	; 执行这一句会把 SelectorCode32 装入 cs, 并跳转到 Code32Selector:0  处


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;


LABEL_REAL_ENTRY:		; 从保护模式跳回到实模式就到了这里
	mov	ax, cs
	mov	ds, ax
	mov	es, ax
	mov	ss, ax


	mov	sp, [SPValueInRealMode]


	in	al, 92h		; ┓
	and	al, 11111101b	; ┣ 关闭 A20 地址线
	out	92h, al		; ┛


	sti			; 开中断


	mov	ax, 4c00h	; ┓
	int	21h		; ┛回到 DOS
; END of [SECTION .s16]




[SECTION .s32]; 32 位代码段. 由实模式跳入.
[BITS	32]


LABEL_SEG_CODE32:
	mov	ax, SelectorData
	mov	ds, ax			; 数据段选择子
	mov	ax, SelectorVideo
	mov	gs, ax			; 视频段选择子


	mov	ax, SelectorStack
	mov	ss, ax			; 堆栈段选择子


	mov	esp, TopOfStack




	; 下面显示一个字符串
	mov	ah, 0Ch			; 0000: 黑底    1100: 红字
	xor	esi, esi
	xor	edi, edi
	mov	esi, OffsetPMMessage	; 源数据偏移
	mov	edi, (80 * 10 + 0) * 2	; 目的数据偏移。屏幕第 10 行, 第 0 列。
	cld
.1:
	lodsb
	test	al, al
	jz	.2
	mov	[gs:edi], ax
	add	edi, 2
	jmp	.1
.2:	; 显示完毕


	call	DispReturn


	; Load LDT
	mov	ax, SelectorLDT
	lldt	ax


	jmp	SelectorLDTCodeA:0	; 跳入局部任务


; ------------------------------------------------------------------------
DispReturn:
	push	eax
	push	ebx
	mov	eax, edi
	mov	bl, 160
	div	bl
	and	eax, 0FFh
	inc	eax
	mov	bl, 160
	mul	bl
	mov	edi, eax
	pop	ebx
	pop	eax


	ret
; DispReturn 结束---------------------------------------------------------


SegCode32Len	equ	$ - LABEL_SEG_CODE32
; END of [SECTION .s32]




; 16 位代码段. 由 32 位代码段跳入, 跳出后到实模式
[SECTION .s16code]
ALIGN	32
[BITS	16]
LABEL_SEG_CODE16:
	; 跳回实模式:
	mov	ax, SelectorNormal
	mov	ds, ax
	mov	es, ax
	mov	fs, ax
	mov	gs, ax
	mov	ss, ax


	mov	eax, cr0
	and	al, 11111110b
	mov	cr0, eax


LABEL_GO_BACK_TO_REAL:
	jmp	0:LABEL_REAL_ENTRY	; 段地址会在程序开始处被设置成正确的值


Code16Len	equ	$ - LABEL_SEG_CODE16


; END of [SECTION .s16code]




; LDT
[SECTION .ldt]
ALIGN	32
LABEL_LDT:
;                                         段基址       段界限     ,   属性
LABEL_LDT_DESC_CODEA:	Descriptor	       0,     CodeALen - 1,   DA_C + DA_32	; Code, 32 位


LDTLen		equ	$ - LABEL_LDT


; LDT 选择子
SelectorLDTCodeA	equ	LABEL_LDT_DESC_CODEA	- LABEL_LDT + SA_TIL
; END of [SECTION .ldt]




; CodeA (LDT, 32 位代码段)
[SECTION .la]
ALIGN	32
[BITS	32]
LABEL_CODE_A:
	mov	ax, SelectorVideo
	mov	gs, ax			; 视频段选择子(目的)


	mov	edi, (80 * 12 + 0) * 2	; 屏幕第 10 行, 第 0 列。
	mov	ah, 0Ch			; 0000: 黑底    1100: 红字
	mov	al, 'L'
	mov	[gs:edi], ax


	; 准备经由16位代码段跳回实模式
	jmp	SelectorCode16:0
CodeALen	equ	$ - LABEL_CODE_A
; END of [SECTION .la]


谁不小心的
关注
  • 0
    点赞
  • 踩
  • 3
    收藏
    觉得还不错? 一键收藏
  • 0
    评论
专栏目录
PM3发布资料_DEC_2017_pm3_PM3RFID资料_
10-02
购买的PM3读卡器资料
PM3环境搭建和M1卡复制
i_can1的博客
09-03 1879
PM3环境搭建 windows的环境搭建比较麻烦，有虚拟机的话可以用虚拟机，强烈安利WSL(Windows subsystem for Linux)，非常友好。 接下来介绍基于Ubuntu的环境搭建，参考PM3Wiki 首先检查更新 sudo apt-get update && sudo apt-get upgrade 然后安装所依赖的工具 sudo apt install p7zip git build-essential libreadline5 libreadline-dev lib
在Ubuntu环境下配置Proxmark3（PM3）使用环境
weixin_30920513的博客
07-11 486
参考资料：PM3官方Wiki 因为国内网络上大多是在Kali系统上使用PM3的教程（链接1、链接2、链接3），而这些教程的步骤对于Ubuntu系统并不完全适用。所以写下本文，记录我个人的安装经历。 本教程与官方Wiki相比省略了部分步骤，仅验证过在全程root用户操作时可行，建议按照官方英文教程进行安装 官方Wiki中的刷写固件步骤（Flashing XXX）非必须且风险较大，除非有需求，否则不要...
[自己动手写操作系统]的学习实践【第三章】
“秋天的叶子”的专栏
05-03 772
因为第二章主要是讲系统的一些配置，所以我们在这里就不准备怎么费多少笔墨描述了，第三章 保护模式第一节  认识保护模式本章我们要学习计算机如何由实模式转入保护模式。实模式向保护模式的转变需要更改一系列的参数。实质是通过一个数据结构来使得16位寄存器访问了4GB的空间。我们下面的程序就显示了这个例子。我们对此的分析将以旁注的方式表现。; ========================
PM3官方windows GUI客户端软件
07-11
PM3官方编译的windows GUI客户端软件，集合了PM3的所有命令。在win7测试使用通过。请注意PM3的固件版本与客户端软件要匹配，本软件适合v2.5固件。
baohumoshi.rar_pmtest5b.asm
09-24
《操作系统保护模式实战指南——基于pmtest5b.asm》 在深入探讨操作系统内核的奥秘时，我们往往会遇到一个难题：理论与实践的脱节。然而，通过研究"baohumoshi.rar"中的"pmtest5b.asm"，我们可以跨越这个鸿沟，亲手...
pmtest.asm理解.pdf
最新发布
02-27
pmtest.asm理解.pdf
《自己动手写操作系统》第三章 pmtest1——从实模式到保护模式
河西无名式
03-02 3539
摘要：本节，我们将学习如何从实模式进入保护模式，剖析pmtest1.asm源码。详细讲解如何从保护模式进入实模式。 1.头文件编写： 这一部分，你需要把一些关键物理器件和数据结构的布局记在脑子里 GDT描述符：32b段基地址（B2、B3、B4、B7）+20b段限长（B0、B1、B6的低4位）+12b段属性（B5、B6的高4位），详细布局见下图（针对代码段和数据段）: 所
http://blog.csdn.net/zgh1988/article/details/7098981
yu_chenglong的专栏
08-07 963
[置顶]全面剖析《自己动手写操作系统》第三章---保护模式                分类：            操作系统2011-12-24 00:30649人阅读评论(16)收藏举报 《自己动手写操作系统》读后感                http://blog.csdn.net/zgh1988/article/details/7059936 全面剖析《自己动手写操
pm 源码分析
jason的笔记
08-09 2188
platform_frameworks_base/cmds/pm/Android.mk 从下面可以看出pm是一个可执行bin档。 LOCAL_PATH:= $(call my-dir) include $(CLEAR_VARS) LOCAL_SRC_FILES := $(call all-subdir-java-files) LOCAL_MODULE := pmlib LOCA
Proxmark3初学：用PM3克隆M1普通门禁卡方法
热门推荐
qq_37400312的博客
07-12 3万+
将门禁卡放到PM3设备的高频发射区 确保PM3已连接，然后点击读卡类型，确定门禁卡位置正确并查看门禁卡类型   点击一键自动解析，PM3开始破解并读取卡片内容，期间会弹出选择操作类型，我们选择块区读取到编辑区。直到读取完成，数据会显示在右侧 将另一张空卡放到PM3的高频区 点击右下角的克隆到UID卡直至克隆完成   此时，我们已成功将门禁卡复制...
pmtest3.asm
世界上有两种人，一种是改变世界的人，另一种是被世界同化的人！
04-13 993
; ==================实现局部任务========================; pmtest3.asm; 编译方法：nasm pmtest3.asm -o pmtest3.com;;本程序共八部分：; 1)全局描述符表gdt, ; 2)局部描述符表ldt;; 3)数据段data, ; 4)全局栈段stack, ; 5)初始化16位代码段, ; 6)32位保护模式代码段, ;
一个操作系统的实现 第四章 pmtest3
glorin的专栏
08-28 1594
1、首先在ubuntu中用vim按照书中所述写文件pmtest3.asm，然后使用命令 nasm pmtest3.asm -o pmtest3.com 2、在这之后，将软盘挂载 sudo mount -o loop pm.img /mnt/floppy 注：pm.img用
Oranges操作系统-保护模式pmtest1、pmtest2、pmtest3代码分析
CarfLearningCode
10-24 891
一、pmtest1.asm 下面对pmtest1.asm中的文件进行简单的分析 1.首先在先定义一个定义全局描述符表GDT的节[SECTION.gdt]，GDT为操作系统提供了段式存储机制。 其中包括三个描述符，分别为 LABEL_GDT，LABEL_DESC_CODE32和LABEL_DESC_VIDEO，每一个描述符定义了一个段，第一个描述符段基址和段界限都为0；第二个描述符指向一个还没有规定大小的代码段，其段基址为0；第三个描述符指向的段...
自己动手写操作系统读书笔记——第三章：保护模式（上）
weixin_42559271的博客
09-27 274
自己动手写操作系统读书笔记——第三章：保护模式准备环境关于CPU的一些说明保护模式段式内存管理全局描述符表（GDT）局部描述符表（LDT）描述符选择子进入保护模式进入保护模式A20地址线及寄存器说明 准备环境 在测试本书源码的时候，我选择的环境是Vmware+IDA，当然也可以使用单纯的gdb调试器，但是IDA集成了源码分析，汇编等功能，使用起来较为方便。至于选择这个环境的原因在于Vmware使用的人较多，而且联合IDA调试比较方便。 这里就记录一下Vmware的相关设置 debugStub.listen.
《自己动手写操作系统》源码解析——第三章pmtest5.asm
河西无名式
02-27 2507
在pmtest4中，我们已经看到，对于非一致性代码，如何从低特权级转移向高特权级。但是我们该怎样从高特权级别，转移到低特权级别呢？一开始我们在实模式，是ring 0，我们怎样从ring 0到ring3 ，这个通过call和jmp没法做到，我们该通过什么方式实现？本文，主要是为你解答这些疑问，展现实现这种特权级别转移的方法。通过本节，你将学会如何在特权级之间自由切换。 一、预备理论 1.
（实模式+保护模式）模式切换的过程步骤（代码+文字解析）
weixin_30896825的博客
08-26 696
【0】写在前面 文末的个人总结是干货，前面代码仅供参考的，且source code from orange’s implemention of a os. ; ========================================== ; pmtest2.asm ; 编译方法：nasm pmtest2.asm -o p...
（第三章 5）保护模式下，读写大地址内存 & 从32位保护模式跳回16位实模式（一）...
chuanwang66的专栏
06-05 216
一、主要功能        在本章最基本代码（P25、chapter3/a/）的基础上实现大地址（超过1M）的读写。在前面程序的基础上新建一个段，这个段以5MB为基址，远远超过1MB的界限。先读出开始处8字节的内容，然后写入一个字符串，再从中读出8字节。        如果读写成功的话，两次读出的内容应该不同，而且第二次读出的内容应该就是我们写进的字符串。字符串是保存在数据段中的，也是新增加的...

“相关推荐”对你有帮助么？

  • 非常没帮助
  • 没帮助
  • 一般
  • 有帮助
  • 非常有帮助
提交
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值