build.gradle——单个项目的配置解释

//指定第三方插件, 类似maven的plugins标签
plugins {
    id 'io.spring.dependency-management' version '1.0.11.RELEASE'//dependency-management插件实现依赖管理，对等maven中的dependencyManagement元素
    id 'java' //java插件预定义了很多task，其中就包括编译、测试、生成jar包等task
    id 'idea' //定义idea插件，是让idea开发工具可以自动识别该项目，并正确导入至idea开发工具
//    id 'maven-publish' //定义maven-publish插件，比如发布jar至maven私服仓库时的配置就需要该插件。因为本项目不需要上传jar至私服，因此不需要配置。
}

//设置变量值，方便后面多个地方表达式引用
ext {
    springBootVersion = "2.1.13.RELEASE"
    springCloudVersion = "Greenwich.SR5"
}

//依赖管理
dependencyManagement {
    imports {
        mavenBom "org.springframework.cloud:spring-cloud-dependencies:${springCloudVersion}"
        mavenBom "org.springframework.boot:spring-boot-dependencies:${springBootVersion}"
    }
}

//指定jar下载的仓库地址
repositories {
    //使用本地maven的setting.xml的配置
    mavenLocal()
    //使用默认配置的https://repo.maven.apache.org/maven2/仓库地址
    mavenCentral()
    maven { url "http://nexus.xxx.com/repository/maven-public/" }
    //正式包私服地址
    maven { url "http://nexus.xxx.com/repository/xxx-releases/" }
    maven { url "https://plugins.gradle.org/m2/" }
}

//设置此项目所属的组
group = 'cn.xxx.xxx.report'
//设置此项目的版本
version = '0.0.1-SNAPSHOT'
//设置此项目源码编译的jdk版本
sourceCompatibility = '1.8'

configurations {
    compileOnly {//仅在编译时依赖，此处为lombok使用，相关注解在编译时生成getter/setter等方法
        extendsFrom annotationProcessor //编译时使用lombok的注解处理器AnnotationProcessor
    }
}

// 修改打包位置
buildDir = "$rootDir/build/"

//指定的依赖包
dependencies {
//    格式如 implementation/testImplementation/compileOnlyannotationProcessor/annotationProcessor/testCompileOnly group:'org.springframework', name:'spring-core', version:'4.0.3.RELEASE
//    其中group、name、version省略了。版本如果没有指定，则会使用dependencyManagement里面的依赖包。
    //如这样写也是可以的   implementation group:'org.springframework.cloud',name:'spring-cloud-starter-openfeign'
    implementation 'org.springframework.cloud:spring-cloud-starter-openfeign'
    // web
    implementation 'org.springframework.boot:spring-boot-starter-web'
    //lombok
    compileOnly 'org.projectlombok:lombok'
    annotationProcessor 'org.projectlombok:lombok'
    testCompileOnly 'org.projectlombok:lombok'
    testAnnotationProcessor 'org.projectlombok:lombok'

    //其他依赖包...
}