软件自动安装脚本学习总结-自动安装TightVNC

据目前了解自动安装分两类

1.带参数安装包支持静默安装，一般是msi格式软件。

a.简单编写bat脚本即可安装。（已经实现。见： 自动安装TightVNC.bat）

实现功能：
1.关闭阻挡安装安装策略弹窗，组织bat文件的自动安装。
2.根据系统版本x64 x86 安装对应软件，输出log日志。

::::::::::::::::::::::修改注册表，获取管理员权限::::::::::::::::::
@echo off
echo 获取Administrator权限
cacls.exe "%SystemDrive%\System Volume Information" >nul 2>nul
if %errorlevel%==0 goto Admin
if exist "%temp%\getadmin.vbs" del /f /q "%temp%\getadmin.vbs"
echo Set RequestUAC = CreateObject^("Shell.Application"^)>"%temp%\getadmin.vbs"
echo RequestUAC.ShellExecute "%~s0","","","runas",1 >>"%temp%\getadmin.vbs"
echo WScript.Quit >>"%temp%\getadmin.vbs"
"%temp%\getadmin.vbs" /f
if exist "%temp%\getadmin.vbs" del /f /q "%temp%\getadmin.vbs"
exit
:Admin
echo 成功取得Administrator权限
::::::::::::::::::::::修改注册表，关闭UAC::::::::::::::::::
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\System" /v "ConsentPromptBehaviorAdmin" /t reg_dword /d 0 /F
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\System" /v "EnableLUA" /t reg_dword /d 0 /F
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\System" /v "PromptOnSecureDesktop" /t reg_dword /d 0 /F

:::::::::::::::::::::安装VNC::::::::::::::::::
echo 开始安装,请勿关闭.......

if /i %PROCESSOR_ARCHITECTURE% EQU AMD64 goto installX64
if /i %PROCESSOR_ARCHITECTURE% NEQ AMD64 goto installX86

rem 安装64位程序
:installX64
cd  %~dp0
msiexec.exe /i tightvnc-2.8.59-gpl-setup-64bit.msi /quiet /norestart ADDLOCAL="Server" SET_USEVNCAUTHENTICATION=1 VALUE_OF_USEVNCAUTHENTICATION=1 SET_PASSWORD=1 VALUE_OF_PASSWORD=zlkj123 SET_VIEWONLYPASSWORD=1 VALUE_OF_VIEWONLYPASSWORD=zlkjview SET_USECONTROLAUTHENTICATION=1 VALUE_OF_USECONTROLAUTHENTICATION=1 SET_CONTROLPASSWORD=1 VALUE_OF_CONTROLPASSWORD=zlkj123 /log VNCx64.log
echo 安装日志：VNCx64.log
goto endend

rem 安装32位程序
:installX86
cd  %~dp0
msiexec.exe /i tightvnc-2.8.59-gpl-setup-32bit.msi /quiet /norestart ADDLOCAL="Server" SET_USEVNCAUTHENTICATION=1 VALUE_OF_USEVNCAUTHENTICATION=1 SET_PASSWORD=1 VALUE_OF_PASSWORD=zlkj123 SET_VIEWONLYPASSWORD=1 VALUE_OF_VIEWONLYPASSWORD=zlkjview SET_USECONTROLAUTHENTICATION=1 VALUE_OF_USECONTROLAUTHENTICATION=1 SET_CONTROLPASSWORD=1 VALUE_OF_CONTROLPASSWORD=zlkj123 /log VNCx86.log
echo 安装日志：VNCx86.log
goto endend

:endend
echo 安装完毕
pause

TightvncVNC静默安装参数文档说明详见https://www.tightvnc.com/doc/win/TightVNC_2.7_for_Windows_Installing_from_MSI_Packages.pdf
其中：
VALUE_OF_PASSWORD 远程控制密码
VALUE_OF_VIEWONLYPASSWORD 远程观看密码
VALUE_OF_CONTROLPASSWORD 配置VNCServer密码

B.也可以采用wix toolset (未深入了解)
注：wix目前高支持VS2019 https://wixtoolset.org/ 也可以通过vs软件的扩展-》管理扩展 进行安装。

2.模拟按键安装（此方法会显示安装界面，只是模拟手动点击输入）

1.按键精灵（未测试）
2.au3脚本（评论都说好，可以获取界面文字，直接触发按钮点击事件（比模拟按键靠谱，抗干扰）等）
3.ahk脚本 （也是传说中的好脚本）