Neo4j Browser（图数据库）学习笔记——Cypher小结

最新推荐文章于 2023-01-13 10:54:50 发布

LOONGV

最新推荐文章于 2023-01-13 10:54:50 发布

阅读量4.4k

点赞数 3

分类专栏： Neo4j 画像 Cypherv 文章标签： Cypher Neo4j 画像

本文链接：https://blog.csdn.net/u013032852/article/details/82997088

版权

Neo4j 同时被 3 个专栏收录

4 篇文章 0 订阅

订阅专栏

画像

3 篇文章 0 订阅

订阅专栏

Cypherv

2 篇文章 0 订阅

订阅专栏

一、创建节点及关系：

/*创建一个节点*/
CREATE (sanlang:People{name:'三浪',age:36,gender:'man'});

/*创建三个节点，以及节点之间的关系*/
CREATE (ashiliu:People{name:'阿十六',age:15,gender:'girl'}),
(basong:People{name:'霸宋',age:18,gender:'boy'}),
(balong:People{name:'霸龙',age:18,gender:'boy'}),
(basong)-[rel1:LIKES{since:'2017'}]->(ashiliu),
(balong)-[rel2:LIKES{since:'2017'}]->(ashiliu);

CREATE：创建关键字，用于创建新节点，可以一个个创建，也可一次创建多个

()：定义节点内容

sanlang：用于存储创建节点的变量

People：创建节点的标签（类别）

{}：定义节点属性，内容为键值对，值可以为字符串、数值、布尔值

-[]->：创建两个节点之间的关系(>说明关系方向是由左向右)

二、查询节点：

/*查询名字为霸龙、年龄超过14岁、标签（类别）为People的节点并返回*/
MATCH (somebody:People{name:'霸龙'}) WHERE somebody.age > 14 RETURN somebody;
/*查询关系为LIKES且关系属性since为2017的节点及关系并返回*/
MATCH (peo1:People)-[rel:LIKES{since:'2017'}]->(peo2:People) RETURN peo1,rel,peo2;
/*查询所有标签（类别）为People的节点并返回上限25*/
MATCH (peo:People) RETURN peo LIMIT 25;

MATCH：查询关键字，用于匹配节点或关系（关键词与节点信息之间需要加空格）

()：定义查询节点条件

somebody：用于存储查询结果的变量

People：查询节点条件——节点标签（类别），可为零个或多个

{}：查询节点条件——属性限制

WHERE：查询节点条件限制关键字——属性限制

RETURN：返回关键字，用于返回查询结果

LIMIT：限制返回查询结果

根据id查找节点：

MATCH (ashiliu:People) WHERE id(ashiliu)=206 RETURN ashiliu;

字符串首尾可以使用STARTS WITH和ENDS WITH去匹配定位字符串，还可以使用CONTAINS匹配字符串中包含的字符串，在前面添加NOT就是字符串排除匹配：

/*查询name中以'霸'开头的字符串节点*/
MATCH (peo) where peo.name STARTS WITH '霸' return peo;
/*查询name中以'龙'结尾的字符串节点*/
MATCH (peo) where peo.name ENDS WITH '龙' return peo;
/*查询name中含有'十'的字符串节点*/
MATCH (peo) where peo.name CONTAINS '十' return peo;
/*查询name中不含有'霸'的字符串节点*/
MATCH (peo) where NOT peo.name CONTAINS '霸' return peo;

字符串正则表达式匹配，正则表达式使用的解析符号是=~：

/*查找name属性中含有'霸'的节点，类似于mysql中的 like '%霸%'*/
MATCH (peo:People) WHERE peo.name =~ '.*霸.*' RETURN peo;

/*不区分大小写正则匹配，name属性中以'ANNY'开头的节点*/
MATCH (peo:People) WHERE peo.name =~ '(?!)ANNY.*' RETURN peo;

WHERE句子中使用路径匹配进行过滤：

/*在图中匹配name属性为'霸儒'，'霸龙'的节点*/
MATCH (peo:People) WHERE peo.name IN ['霸儒','霸龙'] RETURN peo;
/*使用NOT匹配与'阿十六'无关的人*/
MATCH (ashiliu:People{name:'阿十六'}),(peo) WHERE NOT (peo)-[]-(ashiliu) RETURN peo;
/*在图中匹配阿十六节点和与阿十六节点关系类型以L开头的所有关系*/
MATCH (ashiliu:People{name:'阿十六'})-[r]-(peo) WHERE type(r)=~'L.*' RETURN peo;

使用“或”逻辑匹配关系：

/*返回关系为LIKES和Friend的所有节点关系*/
MATCH p=(n)-[:LIKES|:Friend]-(m) RETURN p;

关系深度匹配（具体效果不明···运行的时候neo4j浏览器直接黑屏了···）：

/*匹配从n到m，任意关系、深度1到5的节点*/
MATCH p=(n)-[*1..5]-(m) RETURN p;
/*匹配从n到m，任意关系、任意深度的节点*/
MATCH p=(n)-[*]-(m) RETURN p;

SKIP LIMIT匹配分页返回：

/*匹配标签（分类）为People的节点，2个节点之后的5个节点（类似于每5个节点做为一页，2个节点后的第一页）*/
MATCH (peo) where labels(peo)="People" RETURN peo SKIP 2 LIMIT 5;

DISTINCT去重:

MATCH (peo) where labels(peo)="People" RETURN DISTINCT peo;

ORDER BY排序,DESC 倒序：

MATCH (peo) where labels(peo)="People" RETURN peo ORDER BY peo.gender DESC;

AS使用别名返回节点属性：

MATCH (peo) WHERE labels(peo)="People" RETURN peo.name AS nickname;

WITH将第一部分匹配的输出作为下一部分匹配的输入，若在WITH语句中没有声明第一部分的变量，那么在下一部分匹配时就无法使用此变量：

1.查找喜爱者少于10个的阿姓节点：

MATCH (ashiliu:People)-[:LIKES]-(liker)
WHERE ashiliu.name =~ '阿.*'
/*若下句未声明liker，哪怕声明了count(liker)，下面也无法获取到liker*/
WITH ashiliu,liker,count(liker) as likers    
WHERE likers<10
RETURN liker

2.WITH中使用排序和分页

MATCH (peo:People)-[:Friend]-(friend)
WITH peo,friend,count(friend) as friends
ORDER BY friends DESC
SKIP 1 LIMIT 3
RETURN friend

UNION合并求并集：

1.使用UNION结果去重求并集

MATCH (a:People)-[:Friend]->(b)
RETURN a.name AS name
UNION
MATCH (a:People)-[:LIKES]->(b)
RETURN b.name AS name

2.使用UNION ALL结果不去重求和集

MATCH (a:People)-[:Friend]->(b)
RETURN a.name AS name
UNION ALL
MATCH (a:People)-[:LIKES]->(b)
RETURN b.name AS name

START语句匹配节点信息：

1.匹配所有节点

STRAT n=node(*) RETURN n

2.根据节点的具体id匹配

START n=node(1) RETURN n

三、查询创建结合

MATCH (boy:People) WHERE boy.gender='boy' 
CREATE (bai:People:xiuzhen{name:'白',age:26,gender:'man'}),
(boy)-[:Friend]->(bai),(bai)-[:Friend]->(boy);

MATCH (bai:People{name:'白'}),(ashiliu:People{name:'阿十六'}),(peo:People)-[:LIKES]-(ashiliu)
CREATE (bai)-[:Friend]->(peo),(peo)-[:Friend]->(bai),(bai)-[:Friend]->(ashiliu),(ashiliu)-[:Friend]->(bai);

使用MATCH查询后直接换行（或空格间隔）就可以继续CREATE创建了，不需要用,或;分隔

四、查询创建合一关键字——MERGE

MERGE (yurouzi:People{name:'羽柔子',age:19,gender:'girl'})-[:Friend]->(bai:People{name:'白'});

MATCH (yurouzi:People{name:'羽柔子'}),(balong:People{name:'霸龙'})
MERGE (yurouzi)-[:Friend]->(balong);

MERGE：此关键字表示若节点/关系不存在就创建新节点/关系，否则不做操作；用此关键字同时进行匹配创建时需要注意模式要完全匹配，否则就会创建新的模式，如下就会创建新的节点和关系：

MERGE (ashiliu:People{name:'阿十六'})-[l:LIKES]->(balong:People{name:'霸龙'}) RETURN ashiliu;

在MERGE子句之后，可以显式指定on creae和on match子句，用于修改绑定的节点或关系的属性：

/*根据name属性为'阿十六'且标签为'People'查找到对应节点，将该节点的hobby属性设置为'渡劫'*/
MERGE (ashiliu:People{name:'阿十六'}) on MATCH SET ashiliu.hobby='渡劫' return ashiliu;
/*创建霸儒节点，并将该节点的hobby属性设置为'组团渡劫'*/
MERGE (baru:People{name:'霸儒',age:18,gender:'boy'}) on CREATE SET baru.hobby='组团渡劫' return baru;
/*同时指定on create和 on match，当节点不存在时仅执行 on create否则仅执行 on match*/
MERGE (bamo:People{name:'霸魔',age:18,gender:'boy'}) 
ON CREATE SET bamo.hobby = '怼大佬'
ON MATCH SET bamo.nickname = '书山压力大'
RETURN bamo;

其他MERGE的运用，匹配时不同于MATCH的地方是MERGE匹配多个节点时不能直接用','间隔：

MERGE (ashiliu:People{name:'阿十六'}) 
MERGE (baru:People{name:'霸儒'}) 
MERGE (baru)-[l:LIKES]->(ashiliu) return l
MERGE (baru)<-[l:LIKES]-(ashiliu) return l;
/*上面的等同于下面的*/
MATCH (ashiliu:People{name:'阿十六'}),(baru:People{name:'霸儒'})
MERGE (baru)-[l:LIKES]->(ashiliu) return l
MERGE (baru)<-[l:LIKES]-(ashiliu) return l;

MERGE上使用唯一性约束，添加约束后便可通过该属性获取到（若没有则创建）唯一的节点：

/*将name属性做为唯一性约束*/
CREATE CONSTRAINT ON (n:People) ASSERT n.name IS UNIQUE;
MERGE (ashiliu:People{name:'阿十六'}) RETURN ashiliu;

添加唯一性约束后再使用下面的脚本便会报错Neo.ClientError.Schema.ConstraintValidationFailed: Node(208) already exists with label `People` and property `name` = '霸龙'：

MERGE (ashiliu:People{name:'阿十六'})
MERGE (ashiliu)-[:LIKES]->(balong:People{name:'霸龙'})
RETURN ashiliu;

报错是因为阿十六喜欢霸龙的关系是不存在的，所以需要创建此关系，然而霸龙是存在的，所以无法再次创建霸龙节点。

所以解决此错误有三种方案：

上策：在match的时候直接把霸龙节点一起找到，在merge创建阿十六和霸龙之间的关系时直接使用找到的变量
~~中策：修改现有霸龙节点name属性或新建霸龙节点的name属性~~
~~下策：删掉现有的霸龙节点，然后直接创建霸龙节点和阿十六与霸龙之间的关系~~

五、特殊函数

1.获取节点或关系的id

MATCH (bai:People{name:'白'})-[r]->(ashiliu:People{name:'阿十六'}) RETURN id(bai),id(r),id(ashiliu)

2.获取节点类型

MATCH (bai:People{name:'白'})-[r]->(ashiliu:People{name:'阿十六'}) RETURN type(r)

3.获取节点标签（类别）

MATCH (bai:People{name:'白'})-[r]->(ashiliu) RETURN labels(ashiliu)

4.获取节点或关系的属性键值

MATCH (bai:People{name:'白'})-[r]->(ashiliu:People{name:'阿十六'}) RETURN keys(bai),keys(r)

5.获取节点或关系的属性

MATCH (bai:People{name:'白'})-[r]->(ashiliu:People{name:'阿十六'}) RETURN properties(bai),properties(r)

六、节点更新和删除

1.更新和添加一个属性

MATCH (n:People{name:'霸龙'})
SET n.name='霸霸龙'           //修改name属性值为'霸霸龙'
SET n.hobby='享受疼痛'        //添加一个属性hobby='享受疼痛'
RETURN n

2.修改节点信息，覆盖节点属性(=)

//删除原有属性，新增nickName属性
MATCH (peo:People{name:'白'})
SET peo={nickName:'白尊者'}
RETURN peo

3.删除节点属性

MATCH (peo{nickName:'白尊者'}) REMOVE peo.nickName RETURN peo

4.修改节点信息，新增节点属性(+=)

MATCH (peo:People{name:'白'})
SET peo+={nickName:'白尊者'}
RETURN peo

5.为节点添加新标签

//添加一个标签
MATCH (peo:People{name:'白'}) SET peo:ZunZhe RETURN peo
//添加多个标签
MATCH (peo:People{name:'白'}) SET peo:ZunZhe:XuanSheng RETURN peo

6.删除节点标签

MATCH (peo:People{name:'白'}) REMOVE peo:XuanSheng RETURN peo

7.删除节点和关系（带关系的节点删除的时候需要先删除关系，否则会报错）

MATCH (a)-[r:Friend]->(b) DELETE r,b

8.级联删除（删除“白”节点之后，将与白节点级联关系也删除掉）

MATCH (peo:People{name:'白'}) DETACH DELETE peo

七、索引和约束

1.创建索引：不可以为已经创建节点属性唯一约束的属性创建索引

//为“People”标签的name属性创建索引
CREATE INDEX ON : People(name)

2.删除索引

//删除“People”标签的name属性的索引
DROP INDEX ON: People(name)

3.匹配条件中使用索引

MATCH (peo:People) WHERE peo.name = '白' RETURN n

4.创建节点属性唯一约束:创建一个唯一约束保证图数据库中同一个标签内的节点的属性值不重复，不过不可以为已经创建索引的属性创建唯一约束

CREATE CONSTRAINT ON (peo:People) ASSERT peo.name IS UNIQUE

5.删除节点属性唯一性约束

DROP CONSTRAINT ON (peo:People) ASSERT peo.name is UNIQUE

LOONGV

关注

3
点赞
踩
9

收藏

觉得还不错? 一键收藏
2
评论
Neo4j Browser（图数据库）学习笔记——Cypher小结

一、创建节点及关系：/*创建一个节点*/CREATE (sanlang:People{name:'三浪',age:36,gender:'man'});/*创建三个节点，以及节点之间的关系*/CREATE (ashiliu:People{name:'阿十六',age:15,gender:'girl'}),(basong:People{name:'霸宋',age:18,gend...
复制链接

扫一扫