/************************************************************************
arm920t总共由37个寄存器,其中31个通用32位寄存器和6个状态寄存器,但不能在同一时刻对
所有的寄存器可见.处理状态和运行模式决定了哪些寄存器对程序员可见.
在arm状态(user)16个寄存器和1个状态寄存器可见,R0~R15(除了R15,其它寄存器都为通用寄存器)
可用来保存数据和地址值
R14: 此寄存器被用作子程序的链接寄存器, 当执行分支和链接(BL)指令时该寄存器接收R15的备份
其余时间可作为通用寄存器
相对应的分组寄存器R14_svc,R14_irq,R14_fiq,R14_abt,R14_und也类似用于中断或异常
发生时R15的返回值
R15: 此寄存器存放程序计数器(PC),在ARM状态,[1:0]为0,[31:2]为PC值
R16: 此寄存器为CPRS(当前程序状态寄存器),包含条件码标示位和当前模式位.
************************************************************************/
/************************************************************************
ARM920T包含一个当前程序状态寄存器,还有5个用于异常程序处理的保存程序状态寄存器(SPSR)
功能:
1. 保存最近处理的ALU信息
2. 控制中断的使能和禁止
3. 设置处理器的运行模式
************************************************************************/
/*************************************************************************
u-boot启动流程:
_start: --> reset: --> cpu_init_crit: --> lowlevel_init: --> cpu_init_crit
|
|
mian_loop() <-- Start_armboot() <-- _start_armboot <-- relocate: <-- reset:
*************************************************************************/
#include <config.h>
#include <version.h>
/*
*************************************************************************
*
* Jump vector table as in table 3.1 in [1]
*
*************************************************************************
*/
.globl _start
_start: b reset //跳转到复位
ldr pc, _undefined_instruction //为定义的指令异常 0x4
ldr pc, _software_interrupt //软件中断异常 0x8
ldr pc, _prefetch_abort //预取指令操作异常 0xc
ldr pc, _data_abort //数据操作异常 0x10
ldr pc, _not_used //未使用异常 0x14
ldr pc, _irq //慢中断异常 0x18
ldr pc, _fiq //快中断异常 0x1c
/*****************************************************
定义了七种异常,复位异常放在0x0上,开始就执行它.
当一个异常出现时,执行步骤如下:
1.将下一条指令的地址放到连接寄存器LR(通常是R14),这样就能够从处理异常返回时从正确的位置继续执行
2.将相应的CPSR复制到SPSR中,从异常退出时,可以从SPSR来恢复
3.根据异常类型,强制设置CPSR的运行模式
4.PC(程序计数器)被强制设置成相关异常处理函数的地址,从而跳转到相应的异常处理程序中去
异常处理完成,返回执行步骤:
1.将LR的值减去相应的偏移量后送到PC中
2.将SPSR复制到CPSR中
3.若在进入异常处理时设置了中断禁止位,要在此清除
*****************************************************/
_undefined_instruction: .word undefined_instruction //.word 分配一个32byte的内存空间
_software_interrupt: .word software_interrupt
_prefetch_abort: .word prefetch_abort
_data_abort: .word data_abort
_not_used: .word not_used
_irq: .word irq
_fiq: .word fiq
.balignl 16,0xdeadbeef //将地址对齐到16位, 0xdeadbeef为填充值
/*
*************************************************************************
*
* Startup Code (reset vector)
*
* do important init only if we don't start from memory!
* relocate armboot to ram
* setup stack
* jump to second stage
*
*************************************************************************
*/
/* 保存变量的数据区 */
_TEXT_BASE:
.word TEXT_BASE //定义在开发板目录名称下的config.mk文件中
.globl _armboot_start
_armboot_start:
.word _start
/*
* These are defined in the board-specific linker script.
*/
/**************************************************************************
bss简介
一个程序本质上有bss ,data, text段三部分组成
bss段: 在采用段式内存管理的框架中,bss段通常指用来存放程序中未初始化的全局变量
的一个区域,属于静态内存分配
data段: 在采用段式管理的框架中,data段通常指用来存放程序中已经初始化的全局变量
的一个区域,属于静态内存分配
text段: 在采用段式管理的框架中,text段通常指用来存放程序执行代码的一个区域,这
部分区域在代码运行前就应经确定, 并且内存区域属于只读,在代码段可能也包含一
些只读的常数变量
详细在 http://www.cnblogs.com/fengyv/p/3789252.html
***************************************************************************/
/*
用来存储bbs开始和结束地址
*/
.globl _bss_start
_bss_start:
.word __bss_start
.globl _bss_end
_bss_end:
.word _end
/*
用来存储ram位置
*/
.globl FREE_RAM_END
FREE_RAM_END:
.word 0x0badc0de
.globl FREE_RAM_SIZE
FREE_RAM_SIZE:
.word 0x0badc0de
#ifdef CONFIG_USE_IRQ
/* IRQ stack memory (calculated at run-time) */
.globl IRQ_STACK_START //预处理标号,让IRQ_STACK_START指向0x0badc0de
IRQ_STACK_START:
.word 0x0badc0de
/* IRQ stack memory (calculated at run-time) */
.globl FIQ_STACK_START //定义快速中断
FIQ_STACK_START:
.word 0x0badc0de
#endif
/*
上面的代码定义了一些全局变量,用于boot程序将flase拷贝到ram
*/
/*
* the actual reset code
系统的复位代码,一上电,跳到该处运行
*/
reset:
/*
* set the cpu to SVC32 mode
*/
mrs r0,cpsr //mrs指令将状态寄存器的内容传送到通用寄存器中
bic r0,r0,#0x1f //bic 位清除指令,清除中断控制位,bic指令将r0与上0x1f
orr r0,r0,#0xd3 //计算机为超级保护模式
msr cpsr,r0 //设置cpsr为超级保护模式
/****************************************************
arm共有7中模式
1.用户模式(user) 正常的程序执行状态
2.快速中断模式(fiq) 高速数据传输或通道传输
3.外部中断模式(irq) 通用的中断处理
4.超级保护模式(svc) 操作系统使用的保护模式
5.数据访问终止模式 (abt) 当数据或指令预取终止时进入该模式,可用于虚拟存储及存储仿真
6.系统模式(sys) 运行具有特权的操作系统任务
7.未定义指令模式(und) 当未定义的指令执行时进入该模式
通过设置arm的cpsr寄存器,让cpu运行在操作系统保护模式
*****************************************************/
/* 关闭看门狗 (s3c2440) */
#if defined(CONFIG_S3C2400)
# define pWTCON 0x15300000
# define INTMSK 0x14400008 /* Interupt-Controller base addresses */
# define CLKDIVN 0x14800014 /* clock divisor register */
#elif defined(CONFIG_S3C2410) || defined(CONFIG_S3C2440)
# define pWTCON 0x53000000 /* 看门狗时钟控制寄存器 */
# define INTMOD 0X4A000004 /* 中断方式 */
# define INTMSK 0x4A000008 /* 中断控制寄存器地址 */
# define INTSUBMSK 0x4A00001C /* 中断子程序掩码 */
# define CLKDIVN 0x4C000014 /* 时钟分频控制 */
#endif
#if defined(CONFIG_S3C2400) || defined(CONFIG_S3C2410) || defined(CONFIG_S3C2440)
/*
* 将WTCON寄存器清零(禁用了watchdog timer, interrupt和 reset)
*/
ldr r0, =pWTCON
mov r1, #0x0
str r1, [r0]
/*
* mask all IRQs by setting all bits in the INTMR - default
* 禁止所有的中断请求
*/
mov r1, #0xffffffff
ldr r0, =INTMSK
str r1, [r0]
# if defined(CONFIG_S3C2410)
ldr r1, =0x3ff
ldr r0, =INTSUBMSK
str r1, [r0]
# elif defined(CONFIG_S3C2440)
/*
* INTSUBMSK寄存器的[0:14]设置成1
* 禁用所有中断请求服务
*/
ldr r1, =0x7fff
ldr r0, =INTSUBMSK
str r1, [r0]
# endif
#if 0
/* FCLK:HCLK:PCLK = 1:2:4 */
/* default FCLK is 120 MHz ! */
/* 设置 HCLK = FCLK/2 */
ldr r0, =CLKDIVN
mov r1, #3
str r1, [r0]
#endif
#endif /* CONFIG_S3C2400 || CONFIG_S3C2410 || CONFIG_S3C2440 */
/*
* we do sys-critical inits only at reboot,
* not when booting from ram!
*/
#ifndef CONFIG_SKIP_LOWLEVEL_INIT
bl cpu_init_crit //配置MMU
/********************************************************************
BL为相对寻址, 以程序计数器PC的当前值为基地址,指令中的地址标号作为偏移量,将
两者相加之后得到的操作数的有效地址
arm指令集中4条跳转指令可以完成当前指令先前或向后的32MB的地址空间的跳转
分别是:B BL BLX BX
*********************************************************************/
#endif
/* 建立栈 */
stack_setup:
ldr r0, _TEXT_BASE /* upper 128 KiB: relocated uboot */
sub r0, r0, #CFG_MALLOC_LEN /* malloc area */
sub r0, r0, #CFG_GBL_DATA_SIZE /* bdinfo */
#ifdef CONFIG_USE_IRQ
sub r0, r0, #(CONFIG_STACKSIZE_IRQ+CONFIG_STACKSIZE_FIQ)
#endif
sub sp, r0, #12 /* leave 3 words for abort-stack */
bl clock_init
/*
将uboot搬移到ram中
*/
#ifndef CONFIG_SKIP_RELOCATE_UBOOT
relocate: /* relocate U-Boot to RAM */
adr r0, _start /* r0 <-- 当前代码位置 */
ldr r1, _TEXT_BASE /* 判断是从flase还是ram中启动 r1 == 0x33D00000 */
cmp r0, r1 /* 测试时不需要重定位 */
/* 如果当前的位置就是0x33D00000,那肯定是从nor flase 中启动 */
beq clear_bss // r0=r1时,跳转到clear_bss
/* 如果不是从ram中运行的话,将代码拷贝到_TEXT_BASE */
ldr r2, _armboot_start /* _armboot_start = _start */
ldr r3, _bss_start
sub r2, r3, r2 /* r2 <- size of armboot */
#if 1
bl CopyCode2Ram /* r0: source, r1: dest, r2: size */
#else
add r2, r0, r2 /* r2 <- source end address 复制代码的末尾地址 */
copy_loop:
ldmia r0!, {r3-r10} /* copy from source address [r0] */ //从r0中读取8个字到r3-r10
stmia r1!, {r3-r10} /* copy to target address [r1] */ //将r3-r10的数据保存到目标地址
cmp r0, r2 /* until source end addreee [r2] */
blo copy_loop // r0 != r2, 跳转copy_loop
#endif
#endif /* CONFIG_SKIP_RELOCATE_UBOOT */
/* 初始化内存中bss段中数据为0*/
clear_bss:
ldr r0, _bss_start /* find start of bss segment */
ldr r1, _bss_end /* stop here */
mov r2, #0x00000000 /* clear */
/* 循环清零 */
clbss_l:str r2, [r0] /* 将r2的值赋值到r0地址的寄存器中 */
add r0, r0, #4 /* r0+4 -> r0 */
cmp r0, r1 /* 判断 r0 < r1 */
ble clbss_l /* 小于或等于跳转循环 */
#if 0
/* try doing this stuff after the relocation */
ldr r0, =pWTCON
mov r1, #0x0
str r1, [r0] //wtcon寄存器清零
/*
* mask all IRQs by setting all bits in the INTMR - default
*/
mov r1, #0xffffffff
ldr r0, =INTMR
str r1, [r0] //intmr寄存器置1,禁止中断请求
/* FCLK:HCLK:PCLK = 1:2:4 */
/* default FCLK is 120 MHz ! */
ldr r0, =CLKDIVN
mov r1, #3
str r1, [r0]
/* END stuff after relocation */
#endif
/*
已经准备好了堆栈,跳转到C写的代码里了,也就是跳转到
board.c-->start_armboot中运行
*/
ldr pc, _start_armboot
_start_armboot: .word start_armboot
/*
*************************************************************************
*
* CPU_init_critical registers
*
* setup important registers
* setup memory timing
*
*************************************************************************
*/
/* 从214行跳转到这运行 */
/*************************************************************************
1. 关闭MMU和CPU 内部指令/数据cache
2. 设置CPU的速度和时钟频率
3. RAM初始化
**************************************************************************/
#ifndef CONFIG_SKIP_LOWLEVEL_INIT
cpu_init_crit:
/*
* flush v4 I/D caches
*/
mov r0, #0
mcr p15, 0, r0, c7, c7, 0 /* flush v3/v4 cache */
mcr p15, 0, r0, c8, c7, 0 /* flush v4 TLB */
/**********************************************************************
mcr指令用于将arm处理器寄存器中的数据传送到协处理器中,如果协处理器不能成功的执
行该操作,将产生未定义的指令异常
格式为:
MCR{<cond>} p15, 0, <Rd>, <CRn>, <CRm>{,<opcode_2>}
cond:为指令执行的条件码
rd: 其值将传送到协处理器中
crn:为协处理器
crm:附加的目录寄存器或者原操作数寄存器(区分同一个编号的不同物理寄存器)
***********************************************************************/
/*
* disable MMU stuff and caches
*/
mrc p15, 0, r0, c1, c0, 0
bic r0, r0, #0x00002300 @ clear bits 13, 9:8 (--V- --RS)
bic r0, r0, #0x00000087 @ clear bits 7, 2:0 (B--- -CAM)
orr r0, r0, #0x00000002 @ set bit 2 (A) Align
orr r0, r0, #0x00001000 @ set bit 12 (I) I-Cache
mcr p15, 0, r0, c1, c0, 0
/*
* before relocating, we have to setup RAM timing
* because memory timing is board-dependend, you will
* find a lowlevel_init.S in your board directory.
*/
mov ip, lr
bl lowlevel_init // board/开发板目录下的lowlevel_init.S, 内存控制配置
mov lr, ip
mov pc, lr //从子函数返回
#endif /* CONFIG_SKIP_LOWLEVEL_INIT */
/*
*************************************************************************
*
* Interrupt handling
*
*************************************************************************
*/
@
@ IRQ stack frame.
@
#define S_FRAME_SIZE 72
#define S_OLD_R0 68
#define S_PSR 64
#define S_PC 60
#define S_LR 56
#define S_SP 52
#define S_IP 48
#define S_FP 44
#define S_R10 40
#define S_R9 36
#define S_R8 32
#define S_R7 28
#define S_R6 24
#define S_R5 20
#define S_R4 16
#define S_R3 12
#define S_R2 8
#define S_R1 4
#define S_R0 0
#define MODE_SVC 0x13
#define I_BIT 0x80
/*
* use bad_save_user_regs for abort/prefetch/undef/swi ...
* use irq_save_user_regs / irq_restore_user_regs for IRQ/FIQ handling
*/
.macro bad_save_user_regs
sub sp, sp, #S_FRAME_SIZE
stmia sp, {r0 - r12} @ Calling r0-r12
ldr r2, _armboot_start
sub r2, r2, #(CONFIG_STACKSIZE+CFG_MALLOC_LEN)
sub r2, r2, #(CFG_GBL_DATA_SIZE+8) @ set base 2 words into abort stack
ldmia r2, {r2 - r3} @ get pc, cpsr
add r0, sp, #S_FRAME_SIZE @ restore sp_SVC
add r5, sp, #S_SP
mov r1, lr
stmia r5, {r0 - r3} @ save sp_SVC, lr_SVC, pc, cpsr
mov r0, sp
.endm
.macro irq_save_user_regs
sub sp, sp, #S_FRAME_SIZE
stmia sp, {r0 - r12} @ Calling r0-r12
add r8, sp, #S_PC
stmdb r8, {sp, lr}^ @ Calling SP, LR
str lr, [r8, #0] @ Save calling PC
mrs r6, spsr
str r6, [r8, #4] @ Save CPSR
str r0, [r8, #8] @ Save OLD_R0
mov r0, sp
.endm
.macro irq_restore_user_regs
ldmia sp, {r0 - lr}^ @ Calling r0 - lr
mov r0, r0
ldr lr, [sp, #S_PC] @ Get PC
add sp, sp, #S_FRAME_SIZE
subs pc, lr, #4 @ return & move spsr_svc into cpsr
.endm
.macro get_bad_stack
ldr r13, _armboot_start @ setup our mode stack
sub r13, r13, #(CONFIG_STACKSIZE+CFG_MALLOC_LEN)
sub r13, r13, #(CFG_GBL_DATA_SIZE+8) @ reserved a couple spots in abort stack
str lr, [r13] @ save caller lr / spsr
mrs lr, spsr
str lr, [r13, #4]
mov r13, #MODE_SVC @ prepare SVC-Mode
@ msr spsr_c, r13
msr spsr, r13
mov lr, pc
movs pc, lr
.endm
.macro get_irq_stack @ setup IRQ stack
ldr sp, IRQ_STACK_START
.endm
.macro get_fiq_stack @ setup FIQ stack
ldr sp, FIQ_STACK_START
.endm
/*
* exception handlers
*/
.align 5
undefined_instruction:
get_bad_stack
bad_save_user_regs
bl do_undefined_instruction
.align 5
software_interrupt:
get_bad_stack
bad_save_user_regs
bl do_software_interrupt
.align 5
prefetch_abort:
get_bad_stack
bad_save_user_regs
bl do_prefetch_abort
.align 5
data_abort:
get_bad_stack
bad_save_user_regs
bl do_data_abort
.align 5
not_used:
get_bad_stack
bad_save_user_regs
bl do_not_used
@ HJ
.globl Launch
.align 4
Launch:
mov r7, r0
@ diable interrupt
@ disable watch dog timer
mov r1, #0x53000000
mov r2, #0x0
str r2, [r1]
ldr r1,=INTMSK
ldr r2,=0xffffffff @ all interrupt disable
str r2,[r1]
ldr r1,=INTSUBMSK
ldr r2,=0x7ff @ all sub interrupt disable
str r2,[r1]
ldr r1, = INTMOD
mov r2, #0x0 @ set all interrupt as IRQ (not FIQ)
str r2, [r1]
@
mov ip, #0
mcr p15, 0, ip, c13, c0, 0 @ /* zero PID */
mcr p15, 0, ip, c7, c7, 0 @ /* invalidate I,D caches */
mcr p15, 0, ip, c7, c10, 4 @ /* drain write buffer */
mcr p15, 0, ip, c8, c7, 0 @ /* invalidate I,D TLBs */
mrc p15, 0, ip, c1, c0, 0 @ /* get control register */
bic ip, ip, #0x0001 @ /* disable MMU */
mcr p15, 0, ip, c1, c0, 0 @ /* write control register */
@ MMU_EnableICache
@mrc p15,0,r1,c1,c0,0
@orr r1,r1,#(1<<12)
@mcr p15,0,r1,c1,c0,0
#ifdef CONFIG_SURPORT_WINCE
bl Wince_Port_Init
#endif
@ clear SDRAM: the end of free mem(has wince on it now) to the end of SDRAM
ldr r3, FREE_RAM_END
ldr r4, =PHYS_SDRAM_1+PHYS_SDRAM_1_SIZE @ must clear all the memory unused to zero
mov r5, #0
ldr r1, _armboot_start
ldr r2, =On_Steppingstone
sub r2, r2, r1
mov pc, r2
On_Steppingstone:
2: stmia r3!, {r5}
cmp r3, r4
bne 2b
@ set sp = 0 on sys mode
mov sp, #0
@ add by HJ, switch to SVC mode
msr cpsr_c, #0xdf @ set the I-bit = 1, diable the IRQ interrupt
msr cpsr_c, #0xd3 @ set the I-bit = 1, diable the IRQ interrupt
ldr sp, =0x31ff5800
nop
nop
nop
nop
mov pc, r7 @ Jump to PhysicalAddress
nop
mov pc, lr
#ifdef CONFIG_USE_IRQ
.align 5
irq:
/* add by www.embedsky.net to use IRQ for USB and DMA */
sub lr, lr, #4 @ the return address
ldr sp, IRQ_STACK_START @ the stack for irq
stmdb sp!, { r0-r12,lr } @ save registers
ldr lr, =int_return @ set the return addr
ldr pc, =IRQ_Handle @ call the isr
int_return:
ldmia sp!, { r0-r12,pc }^ @ return from interrupt
.align 5
fiq:
get_fiq_stack
/* someone ought to write a more effiction fiq_save_user_regs */
irq_save_user_regs
bl do_fiq
irq_restore_user_regs
#else
.align 5
irq:
get_bad_stack
bad_save_user_regs
bl do_irq
.align 5
fiq:
get_bad_stack
bad_save_user_regs
bl do_fiq
#endif
uboot之start.S详解(tq2440)
最新推荐文章于 2019-01-08 00:01:10 发布