qmake设置技巧

1. debug下添加d作为后缀

   build_pass:CONFIG(debug, debug|release) {
     unix: TARGET = $$join(TARGET,,,_debug)
     else: TARGET = $$join(TARGET,,,d)
   }

    

2. 设置生成的DLL要复制到的路径

   # 设置输出路径等
   DESTDIR = $${OUT_PWD}/../lib
   DLLDESTDIR = $${OUT_PWD}/../bin

    

3. 多项目，设置依赖关系

   TEMPLATE = subdirs
   
   project1.file = $$PWD/project1/project1.pro
   
   project2.file = $$PWD/project2/project2.pro
   project2.depends += project1
   
   project3.file = $$PWD/project3/project3.pro
   project3.depends += project1
   
   
   SUBDIRS += project1
   SUBDIRS += project2
   SUBDIRS += project3

    

4. 移除CONFIG内多余的的变量

   defineReplace(remove_extra_config_parameter) {
       configs = $$1
       debug_and_release_params = # 匹配预选队列
       keys = debug Debug release Release debug_and_release
       for (iter, configs) {
           contains(keys, $$iter) {
               debug_and_release_params += $$iter
           }
       }
   
       for (iter, debug_and_release_params) {
           configs -= $$iter # 移除预选队列的属性
       }
   
       configs += $$last(debug_and_release_params) # 添加(保留)预选队列的最后属性
   
       return($$configs)
   }
   CONFIG = $$remove_extra_config_parameter($$CONFIG)

    

5. 导入依赖库

   # 添加依赖库
   win32:CONFIG(release, debug|release): LIBS += -L$$OUT_PWD/../lib/ -lXXXXX
   else:win32:CONFIG(debug, debug|release): LIBS += -L$$OUT_PWD/../lib/ -lXXXXXd
   else:unix:!macx: LIBS += -L$$OUT_PWD/../lib/ -lXXXXX
   
   INCLUDEPATH += $$PWD/../XXXXX
   DEPENDPATH += $$PWD/../XXXXX

    

6.  设置并行编译数

   QMAKE_CXXFLAGS += -j8

    

7.  待续...