【Qt 学习之路】QML翻转效果

目录

1、简述

2、效果

3、源码分享

4、核心代码

5、Flipable讲解

---

1、简述

此示例仅供大家学习参考

2、效果

3、源码分享

这个Demo的源码我已经上传到CSDN，可以下载O(∩_∩)O哈！

源码地址：http://download.csdn.net/detail/u014597198/9748736

4、核心代码

核心的卡片代码如下：

import QtQuick 2.0

Flipable {
    id: container

    property alias source: frontImage.source
    property bool flipped: true
    property int xAxis: 0
    property int yAxis: 0
    property int angle: 0

//    width: front.width; height: front.height
    width: 60;
    height: 80;
    front: Image { id: frontImage; anchors.fill: parent }
    back: Image { source: "qrc:/puke/back.png"; anchors.fill: parent }

    state: "back"

    MouseArea { anchors.fill: parent; onClicked: container.flipped = !container.flipped }

    transform: Rotation {
        id: rotation; origin.x: container.width / 2; origin.y: container.height / 2
        axis.x: container.xAxis; axis.y: container.yAxis; axis.z: 0
    }

    states: State {
        name: "back"; when: container.flipped
        PropertyChanges { target: rotation; angle: container.angle }
    }

    transitions: Transition {
        ParallelAnimation {
            NumberAnimation { target: rotation; properties: "angle"; duration: 600 }
            SequentialAnimation {
                NumberAnimation { target: container; property: "scale"; to: 0.75; duration: 300 }
                NumberAnimation { target: container; property: "scale"; to: 1.0; duration: 300 }
            }
        }
    }
}

5、Flipable讲解

此类型提供一个可以翻转的界面。此类型提供一种可以在其正面和背面之间翻转的 Item，就像一张卡片。它可以与 Rotation、State 和 Transition 类型结合使用来产生翻转效果。

属性成员

1、back : Item

      front : Item

正面和背面。

2、side : enumeration

当前可见的一侧。可能值：

• Flipable.Front
• Flipable.Back