Groovy12_Json、xml、swing与生成器

最新推荐文章于 2022-11-04 11:25:19 发布
最新推荐文章于 2022-11-04 11:25:19 发布
阅读量289 收藏
点赞数
分类专栏： Groovy、Gradle
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/urrjdg/article/details/80344342
版权

1. Json 生成器 : JsonBuilder

import groovy.json.JsonBuilder
import groovy.json.JsonOutput
import groovy.json.JsonSlurper

""""""
// json 生成器
def builder = new JsonBuilder()
builder.json{
    first 'zeking'
    last 'haha'
}

println builder  // {"json":{"first":"zeking","last":"haha"}}

builder{
    first 'zeking'
    last 'haha'
}

println builder  // {"first":"zeking","last":"haha"}

class Person{
    def first
    def last
}

def p = new Person(first: 'zekign',last:'haha')
// 转换对象为json数据
def b = new JsonBuilder(p)
println b.toString()      // {"first":"zekign","last":"haha"}

println JsonOutput.toJson(p) // {"first":"zekign","last":"haha"}
// 格式化json数据
println JsonOutput.prettyPrint(JsonOutput.toJson(p))
//{
//    "first": "zekign",
//    "last": "haha"
//}

// 反序列化
def slurper = new JsonSlurper()
Person person = slurper.parseText(JsonOutput.toJson(p))
println person.first  // zekign
println person.last   // haha

2.xml 生成器 : MarkupBuilder

2.1 创建xml

xml_create.groovy

import groovy.xml.MarkupBuilder
import groovy.xml.StreamingMarkupBuilder

// xml 生成

"""<html><head m="a">hello</head></html>"""

//new File("baidu.html").write("https://www.baidu.com/".toURL().text)
def sw = new FileWriter(new File("normal.xml"))
def builder = new MarkupBuilder(sw)
builder.html{
    mkp.comment("测试")  // 注释
    head("hello",m:"a"){
        title("ZekingLee")
    }
    body{

    }
}

//<html><!-- 测试 -->
//  <head m='a'>hello
//    <title>ZekingLee</title>
//  </head>
//  <body />
//</html>

def sb = new StreamingMarkupBuilder()
sb.encoding = 'UTF-8'
def closure = {
    // 生成xml文件的版本和标识的方法
    mkp.xmlDeclaration()
    html{
        head(id:1){

        }
    }
}
def sw2 = sb.bind(closure)

println sw2.toString()
// <?xml version='1.0' encoding='UTF-8'?>
// <html><head id='1'></head></html>
2.2 解析xml

AndroidManifest.xml

<?xml version="1.0" encoding="utf-8"?>
<manifest xmlns:android="http://schemas.android.com/apk/res/android"
          package="com.example.administrator.androidprotobuf">

    <application
            android:allowBackup="true"
            android:icon="@mipmap/ic_launcher"
            android:label="@string/app_name"
            android:supportsRtl="true"
            android:theme="@style/AppTheme">

        <meta-data android:name="hello" android:value="1"/>
        <activity android:name=".MainActivity">
            <intent-filter>
                <action android:name="android.intent.action.MAIN"/>

                <category android:name="android.intent.category.LAUNCHER"/>
            </intent-filter>
        </activity>
    </application>

</manifest>

xml_parse.groovy

import groovy.xml.Namespace

// parser 是个Node  就是 manifest节点
def parser = new XmlParser().parse(new File("AndroidManifest.xml"))

// 1.需求：拿到activity节点的name属性
// name属性有一个 android： 的命名空间

//命名空间
def ns = new Namespace('http://schemas.android.com/apk/res/android','android')

Node node = parser.application[0].activity[0]
println node.attributes()[ns.name]    // .MainActivity


// 2.移除meta-data节点，添加节点
// 获得application节点
Node node2 = parser.application[0]
//NodeList
Node meta = node2.'meta-data'[0]
node2.remove(meta)
node2.appendNode('meta-data',[(ns.name):'a',(ns.value):'b',(ns.hh):'hh'])
new XmlNodePrinter(new PrintWriter(new File("replace.xml"))).print(parser)

//<manifest package="com.example.administrator.androidprotobuf">
//  <application android:allowBackup="true" xmlns:android="http://schemas.android.com/apk/res/android" android:icon="@mipmap/ic_launcher" android:label="@string/app_name" android:supportsRtl="true" android:theme="@style/AppTheme">
//    <activity android:name=".MainActivity">
//      <intent-filter>
//        <action android:name="android.intent.action.MAIN"/>
//        <category android:name="android.intent.category.LAUNCHER"/>
//      </intent-filter>
//    </activity>
//    <meta-data android:name="a" android:value="b" android:hh="hh"/>
//  </application>
//</manifest>
//</manifest>

3. swing生成器 ：SwingBuilder

import groovy.swing.SwingBuilder

import javax.swing.JButton
import javax.swing.JFrame
import javax.swing.JLabel
import javax.swing.WindowConstants
import java.awt.FlowLayout

// 使用groovy 写
def builder  = new SwingBuilder()
def swing = builder.frame(title: '测试',size: [100,100],
        layout: new FlowLayout(),defaultCloseOperation: WindowConstants.EXIT_ON_CLOSE){
    label(text:'文本')
    button(text:'按钮',actionPerformed:{

    })
}
swing.setVisible(true)

// 使用java代码写 ，对比一下，groovy简单很多
//def frame = new JFrame()
//frame.setTitle('测试')
//frame.setSize(100,100)
//frame.setLayout(new FlowLayout())
//frame.setDefaultCloseOperation(WindowConstants.EXIT_ON_CLOSE)
//new JLabel()
//new JButton().addActionListener {
//
//}

4. 模仿xm生成器 的 BuilderSupport自定义html生成器

MyBuildSupport.groovy

package builder
// 模仿xm生成器 的 MarkupBuilder 自定义生成器
class MyBuildSupport extends BuilderSupport{


    class Node{
        String name
        String value
        Map attr
        def children // 将Node这个节点的所有子节点都保存到这个集合里面

        Node(String name, String value, Map attr) {
            this.name = name
            this.value = value
            this.attr = attr
            children = []
        }

        //<xml key='value'/>
        //<xml>xxx</xml>
        def build(Writer writer){
            // 生成xml
            writer.write("<$name")
            if (attr){
                attr.each {
                    key,value->
                        writer.write(" $key='$value")
                }
            }
            if (value || children){
                writer.write(">")
                if (value){
                    writer.write(value)
                }
                children.each{
                    it.build(writer)
                }
                writer.write("</$name>")
            }else {
                writer.write("/>")
            }
        }
    }

    def nodes
    Writer writer
    MyBuildSupport(Writer writer){
        nodes = [:]
        this.writer = writer
    }

    /**
     * 节点与节点的关系
     * @param parent    父节点
     * @param child     子节点
     */
    @Override
    protected void setParent(Object parent, Object child) {
        println "seParent $parent $child" // 这样是没有任何回调的
        // 如何有回调，createNode 的 返回值会作为seParent的 参数 传递过来
    }

    /**
     * 完成节点调用
     * 通过这个方法可以知道
     * 节点之间的关系 也可以知道 节点的完成情况
     * @param parent
     * @param node
     */
    @Override
    protected void nodeCompleted(Object parent, Object node) {
        super.nodeCompleted(parent, node)
        println "nodeCompleted $parent $node"
        def currentNode = nodes[node]
        if (parent){
            nodes[parent].children << currentNode
        }else{
            // 构建需要的格式
            currentNode.build(writer)
        }
    }

    @Override
    protected Object createNode(Object name) {
        return createNode(name,null,null)
    }

    @Override
    protected Object createNode(Object name, Object value) {
        return createNode(name,null,value)
    }

    @Override
    protected Object createNode(Object name, Map attributes) {
        return createNode(name,attributes,null)
    }

    @Override
    protected Object createNode(Object name, Map attributes, Object value) {
        println("create Node:$name $value $attributes")
        nodes.put(name,new Node(name,value,attributes))
        return name
    }
}

MyBuilderTest.groovy

package builder

StringWriter sw = new StringWriter()
def builder = new MyBuildSupport(sw)
builder.html{
    head("zeking",key:'value'){
        title("Test")
    }

    body{

    }
    x{
        y{
            z{

            }
        }
    }
}

println(sw)
//create Node:html null null
//create Node:head zeking [key:value]
//seParent html head
//create Node:title Test null
//seParent head title
//nodeCompleted head title
//nodeCompleted html head
//create Node:body null null
//seParent html body
//nodeCompleted html body
//create Node:x null null
//seParent html x
//create Node:y null null
//seParent x y
//create Node:z null null
//seParent y z
//nodeCompleted y z
//nodeCompleted x y
//nodeCompleted html x
//nodeCompleted null html
//<html><head key='value>zeking<title>Test</title></head><body/><x><y><z/></y></x></html>

5. 模仿swing生成器 的 FactoryBuilderSupport自定义html生成器

MyFactoryBuilderSupport.groovy

package builder

// 模仿swing生成器
// 工厂 buildsupport工厂

class Node{
    String name
    String value
    Map attr
    def children // 将Node这个节点的所有子节点都保存到这个集合里面

    Node(String name, String value, Map attr) {
        this.name = name
        this.value = value
        this.attr = attr
        children = []
    }

    //<xml key='value'/>
    //<xml>xxx</xml>
    def build(Writer writer){
        // 生成xml
        writer.write("<$name")
        if (attr){
            attr.each {
                key,value->
                    writer.write(" $key='$value")
            }
        }
        if (value || children){
            writer.write(">")
            if (value){
                writer.write(value)
            }
            children.each{
                it.build(writer)
            }
            writer.write("</$name>")
        }else {
            writer.write("/>")
        }
    }
}

class MyFactoryBuilderSupport extends FactoryBuilderSupport{

    {
        def nodeFactory = new NodeFactory()
        // 注册html的工厂
        registerFactory('html',new NodeFactory())
        registerFactory('head',new NodeFactory())
    }
}


class NodeFactory extends AbstractFactory{

    def name

    /**
     * 返回的参数就是我们调用html方法的结果
     * @param builder
     * @param name
     * @param value
     * @param attributes
     * @return
     * @throws InstantiationException
     * @throws IllegalAccessException
     */
    @Override
    Object newInstance(FactoryBuilderSupport builder, Object name, Object value, Map attributes) throws InstantiationException, IllegalAccessException {
        println "newInstance $name $value $attributes"
        this.name = name
        return new Node(name,value,attributes)
    }

    // 在newInstance 之后调用
    // 处理属性的方法
    @Override
    boolean onHandleNodeAttributes(FactoryBuilderSupport builder, Object node, Map attributes) {
        //如果返回true会从newInstance返回中寻找attributes对应key的属性
        return false
    }

    // false 表示可以接收闭包
    // true  表示不能接收
    @Override
    boolean isLeaf() {
        return super.isLeaf()
    }

    // 设置当前节点的父节点
    @Override
    void setParent(FactoryBuilderSupport builder, Object parent, Object child) {
        super.setParent(builder, parent, child)
        println "$name setParent ${parent.name} ${child.name}"
    }

    // 设置当前节点的子节点
    @Override
    void setChild(FactoryBuilderSupport builder, Object parent, Object child) {
        super.setChild(builder, parent, child)
        println "$name setChild ${parent.name} ${child.name}"
        parent.children << child
    }
}

MyFactoryBuilderSupportTest.groovy

package builder



//new MyFactoryBuilderSupport().xml{
//
//}
// 会报错，因为我没有注册xml工厂
//五月 16, 2018 10:11:22 下午 groovy.util.FactoryBuilderSupport createNode
//警告: Could not find match for name 'xml'
//Caught: groovy.lang.MissingMethodException: No signature of method: java.lang.Object.xml() is applicable for argument types: (java.util.Collections$EmptyMap, null) values: [[:], null]
//Possible solutions: dump(), any(), wait(), find(), grep(), is(java.lang.Object)
//groovy.lang.MissingMethodException: No signature of method: java.lang.Object.xml() is applicable for argument types: (java.util.Collections$EmptyMap, null) values: [[:], null]
//Possible solutions: dump(), any(), wait(), find(), grep(), is(java.lang.Object)
//  at builder.MyFactoryBuilderSupportTest.run(MyFactoryBuilderSupportTest.groovy:5)

//new MyFactoryBuilderSupport().html{
//
//}
// 不会报错，只是警告 这就是registerFactory 的作用
//五月 16, 2018 10:11:01 下午 groovy.util.FactoryBuilderSupport createNode
//警告: Factory for name 'html' returned null

StringWriter sw = new StringWriter()
new MyFactoryBuilderSupport().html{
    head('Zeking',key:'value'){

    }
}.build(sw)
println sw

//newInstance html null [:]
//newInstance head Zeking [key:value]
//head setParent html head
//html setChild html head
//<html><head key='value>Zeking</head></html>

6. FactoryBuilderSupport 和 BuilderSupport 的区别

FactoryBuilderSupport 适用于 固定的方法，必须注册工厂
而BuilderSupport 可以用户高度自定义
FactoryBuilderSupport不适合创建html 但是会非常适合创建swing

李樟清
关注
  • 0
    点赞
  • 踩
  • 0
    收藏
    觉得还不错? 一键收藏
  • 0
    评论
专栏目录
java开源包7
06-28
jActionScript 是一个使用了 JavaSWF2 的 Flash 解析器和生成器。提供了一个基于对象模型的 ActionScript 字节码，并提供了 ActionScript 字节码统计工具。 Java类重加载工具 JReloader JReloader 是一个用来重新...
groovy.json.JsonSlurper 需要引用什么Maven依赖
最新发布
qq_16313575的博客
11-30 734
groovy
groovy java联合,避免跨不同的Groovy脚本共享Java元类
weixin_33206743的博客
03-11 281
我的情况我从Java调用多个Groovy脚本，它们都包含长期存在的Groovy对象 .我希望我的Groovy脚本能够对Java类(具有大约100个实例)的Java元类进行一些更改 . 但是，脚本应该能够进行不同的更改，其中一个脚本中的更改不应该反映在其他脚本中 .问题：Java类的元类在所有脚本中共享 .示例代码SameTest.javapublic interface SameTest {voi...
【看一遍就会】使用Groovy遍历解析多层嵌套json
weixin_53273474的博客
11-04 3275
【看一遍就会】结合demo进行讲解，使用Groovy遍历解析多层嵌套json。
JSON Viewer丨Json格式查看器
热门推荐
Mr_沉溺的博客
04-17 2万+
JSON Viewer丨Json格式查看器插件特征插件功能插件特色注意事项 JSON Viewer是一款非常实用的Json格式查看器。在日程开发调试中难免会遇到Json格式的数据需要解析阅读，但Json格式数据阅读性极差，而JSONViewer不仅帮我们解决Json格式的阅读问题，而且在官方版的基础上进行集成打包，无需安装，运行软件即可轻松使用。 JSON Viewer支持粘贴数据进行可视化展示以及自动格式化数据等功能，对JSON字符串进行格式化显示，快速将Json字符串排列成规则的树结构，以便于数据浏览和
JAVA上百实例源码以及开源项目
01-03
　Java二进制IO类与文件复制操作实例，好像是一本书的例子，源代码有的是独立运行的，与同目录下的其它代码文件互不联系，这些代码面向初级、中级Java程序员。 Java访问权限控制源代码 1个目标文件 摘要:Java源码,...
JAVA上百实例源码以及开源项目源代码
12-11
[ConfigLine.java] 控制条类 [RoundBox.java] 限定选择控件 [MonthMaker.java] 月份表算法类 [Pallet.java] 调色板，统一配色类 Java扫雷源码 Java生成自定义控件源代码 2个目标文件 Java实现HTTP连接与浏览，...
java开源包1
06-28
jActionScript 是一个使用了 JavaSWF2 的 Flash 解析器和生成器。提供了一个基于对象模型的 ActionScript 字节码，并提供了 ActionScript 字节码统计工具。 Java类重加载工具 JReloader JReloader 是一个用来重新...
实战 Groovy(3)- Groovy中的SwingBuilder 简介
萌萌的It人 www.itmmd.com
06-25 4272
Swing 是一个极其强大的 GUI 工具集。但糟糕的是，有时候其复杂性会影响开发人员挥发它的能力。如果您刚接触 Swing，会觉得像是在学习开波音 747，而您实际上只需要开单引擎的 Cessna 或滑翔机。Groovy 的 SwingBuilder 并不能降低各种任务内在的复杂性，比如选择适当的 LayoutManager 或处理线程问题。它降低的是语法复杂性。Groovy 的命名参数/变量参
Json视图查看器JsonView
07-27
JsonView是一款视图查看器，可以识别JSON字符串格式是否正确，将json字符串转换成试图，查看JSON树状结构，对JSON字符串节点一目了然
JSON树形分析查看器
11-27
JSON树形分析查看器网页版，使用方法：打开 JSON查看器.html 文件即可。可以将json字符串分析成树形结构，是最好用的json可视化分析工具。
java使用groovy中的JsonSlurper来解析json
jianghuihong2012的专栏
11-11 1万+
Binding binding = new Binding(); GroovyShell shell = new GroovyShell(binding); Object data = shell.evaluate("return new groovy.json.JsonSlurper().parseText('{ \"name\": \"John Doe\"
Java | 使用Java Swing做的时间戳转换和JSON格式化的桌面程序
jonssonyan
09-28 681
引言 内网开发以后一些在线的工具都用不了了，时间戳互转和JSON还是经常用到的，因此只能自己用Swing写一个单机版的自己用用。本来打算用C++ QT做的，后来发现QT安装包足足有2G，我自己不喜欢在电脑上装太多的开发工具（其实电脑里好多都是绿色版的），而且使用C++ 开发速度相比较也会慢一点，再加上对java比较熟悉，也想过用Elctron，想想还是Java swing写的方便一点。于是在周末随手做好了。 代码 Tools public class Tools { public static vo
【实用软件】Json文件查看器（支持查看超大JSON文件）
枫叶小屋
10-24 1万+
内容信息 软件类型：绿色 软件平台：电脑 软件版本：v1.0 软件大小：3.4MB 软件特点 Json文件查看器是一个用来查看Json文件的的绿色软件????。 【无惧大小】可以快速打开GB单位的Json文件。 【支持拖拽】人性化设计之一，支持直接将Json文件拖拽打开。 【支持搜索】人性化设计之一，支持搜索Json文件中的内容。 【历史记录】人性化设计之一，通过历史记录可以快速打开之前的Json文件。 【不收费】免费使用，没有任何套路。用收费的标准，做免费的产品。 下载地址 极速下载-蓝奏云：http
教程– Griffon：使用Groovy构建桌面应用程序
06-27 773
如果您愿意在其中混用一些Groovy，则构建桌面应用程序将是一种愉快的体验。 Griffon是一个遵循Grails精神的应用程序框架，将乐趣带回了桌面开发。 桌面应用程序开发 ，这是当今Web开发，并发性和并行性都很少听到的术语。 但是，这并不意味着它就已经死了。 实际上，在某些行业中，桌面应用程序是解决特定问题的最佳选择。 在某些其他环境中，出于安全原因，这是唯一的选择。 想想金融机构，...
Groovy 转换JSON和生产JSON
weixin_30835649的博客
04-09 2393
Groovy 类和JSON之间的相互转换，主要在groovy.json包下面 1. JsonSlurper JsonSlurper 这个类用于转换JSON文本或从Groovy 数据结构中读取内容例如map、list和一些基本的数据类型如Integer, Double, Boolean和String. 这个类有一系列重载的Parse的方法和一些指定特殊的方法,例如parseText，par...
Groovy笔记(10)_Swing界面
escaflone的专栏
04-28 3405
构造器  1、可以生成XML/HTML/SWING等嵌套树状数据结构2、在语法级别上实现GOF的Builder设计模式 NodeBuilder      创建嵌套的节点树DomBuilder       创建W3C DOM树SwingBuilder     创建Swing界面AntBuilder         生成ANT脚本MarkupBuilder   
脱离jenkins之groovy定制化自动化构建打包
neo的博客
10-24 1146
脚本无什么多说的，需要注意的是构建后的归档操作请拖拽到groovy执行之后 修改：上个版本文件copy的时候忘记关闭流，导致后续操作部分返回false 现在版本增加了源文件删除，和权限修改为775，以及内部压缩使用tar.gz格式 import groovy.json.JsonSlurper import org.apache.tools.ant.Project import org.ap...
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值