[动态规划]能量项链

NOIP2006 提高组 第一道
描述 Description
在Mars星球上，每个Mars人都随身佩带着一串能量项链。在项链上有N颗能量珠。能量珠是一颗有头标记与尾标记的珠子，这些标记对应着某个正整数。并且，对于相邻的两颗珠子，前一颗珠子的尾标记一定等于后一颗珠子的头标记。因为只有这样，通过吸盘（吸盘是Mars人吸收能量的一种器官）的作用，这两颗珠子才能聚合成一颗珠子，同时释放出可以被吸盘吸收的能量。如果前一颗能量珠的头标记为m，尾标记为r，后一颗能量珠的头标记为r，尾标记为n，则聚合后释放的能量为（Mars单位），新产生的珠子的头标记为m，尾标记为n。
需要时，Mars人就用吸盘夹住相邻的两颗珠子，通过聚合得到能量，直到项链上只剩下一颗珠子为止。显然，不同的聚合顺序得到的总能量是不同的，请你设计一个聚合顺序，使一串项链释放出的总能量最大。
例如：设N=4，4颗珠子的头标记与尾标记依次为(2，3) (3，5) (5，10) (10，2)。我们用记号⊕表示两颗珠子的聚合操作，(j⊕k)表示第j，k两颗珠子聚合后所释放的能量。则第4、1两颗珠子聚合后释放的能量为：
(4⊕1)=10*2*3=60。
这一串项链可以得到最优值的一个聚合顺序所释放的总能量为
((4⊕1)⊕2)⊕3）=10*2*3+10*3*5+10*5*10=710。
输入格式 InputFormat
输入文件energy.in的第一行是一个正整数N（4≤N≤100），表示项链上珠子的个数。第二行是N个用空格隔开的正整数，所有的数均不超过1000。第i个数为第i颗珠子的头标记（1≤i≤N），当i<N< span>时，第i颗珠子的尾标记应该等于第i+1颗珠子的头标记。第N颗珠子的尾标记应该等于第1颗珠子的头标记。
至于珠子的顺序，你可以这样确定：将项链放到桌面上，不要出现交叉，随意指定第一颗珠子，然后按顺时针方向确定其他珠子的顺序。
输出格式 OutputFormat
输出文件energy.out只有一行，是一个正整数E（E≤2.1*109），为一个最优聚合顺序所释放的总能量。
样例输入 SampleInput [复制数据]

样例输出 SampleOutput [复制数据]

时间限制 TimeLimitation

各个测试点1s

先无视环，考虑一条链的情况，最后只剩下一个珠子，而且这个珠子一定是由两个珠子合并而来的。

假设这个珠子编号为k，那么必然由1..k-1号珠子合并之后的珠子与k..n号珠子合并的珠子得到。

这就有了区间动归的前提。

小范围数据模拟一下子，可以搞出具体的方程。

 

f[i,j]表示i..j号珠子合并的最大值。

     f[i,i+1]=a[i]*a[i+1]*a[i+2]

     f[i,i]:=0

     f[i,j]=f[i,k]+f[k+1,j]+a[i]*a[k+1]*a[j+1]

     f[1,n]即为答案。

再来考虑环的情况

可以将1..n的环扩展为1..2n的链.

ans=max(dp(i,i+n-1))

var i,n,ans:longint;
    a:array[1..200]of longint;
    f:array[1..200,1..200]of longint;

function max(a,b:longint):longint;
begin
    if a>b then exit(a) else exit(b);
end;

function dp(i,j:longint):longint;
var k,s:longint;
begin
   if i>j then exit;
   if f[i,j]<>-1 then exit(f[i,j]);
   s:=0;
   for k:=i to j-1 do
   s:=max(s,dp(i,k)+dp(k+1,j)+a[i]*a[k+1]*a[j+1]);
   f[i,j]:=s;
   exit(s);
end;

begin
  fillchar(f,sizeof(f),-1);
  readln(n);
  for i:=1 to n do read(a[i]);
  for i:=n+1 to 2*n do a[i]:=a[i-n];
  for i:=1 to 2*n-1 do f[i,i]:=0;
  for i:=1 to 2*n-2 do f[i,i+1]:=a[i]*a[i+1]*a[i+2];
  ans:=0;
  for i:=1 to n do
  ans:=max(ans,dp(i,i+n-1));
  writeln(ans);
  readln;readln;
end.