查看元神操作系统的版本

1. 背景

本文通过元神操作系统的API调用来获取元神系统的版本，并显示在屏幕上。

2. 方法

（1）编写程序

本例先设置系统调用的参数：第一个参数设置为API_OS_VER，表示获取元神操作系统的版本号；第二个参数设置为0，表示调用API时没有输入参数。设置完参数后通过call指令调用API，代码如下所示：

use32

START:
	pusha
	
	call demo_os_version
	
	popa
	iret

include 'api_def.inc'

OS_API equ 0x00030C16
API_PARAM equ 0x03000000
cursor_x equ 0x02004B10
cursor_y equ 0x02004B12

demo_os_version:
	pusha
	
	mov edi, API_PARAM
	mov dword [fs:edi], API_OS_VER
	mov dword [fs:edi+4], 0
	call pword [fs:OS_API]
	
	mov eax, [fs:edi+8]
	movzx ebx, word [fs:cursor_y]
	movzx ecx, word [fs:cursor_x]
	call print_dword		;print major version
	
	mov eax, [fs:edi+12]
	add ecx, 10
	call print_dword		;print minor version
	
	mov eax, [fs:edi+16]
	add ecx, 10
	call print_dword		;print beta version
	
	mov eax, [fs:edi+20]
	add ecx, 10
	call print_dword		;print update version
	
	add word [fs:cursor_y], 1
	
	popa
	ret
	
;print dword value
;input:
;	eax: value to print
;	ebx: y position to print
;	ecx: x position to print
print_dword:
	pusha
	
	imul edi, ebx, 80*2
	add edi, ecx
	add edi, ecx
	add edi, 14
	mov ecx, 8
	mov edx, eax
	mov ah, 0x0F
 .next_char:
	mov al, dl
	shr edx, 4
	and al, 0x0F
	cmp al, 10
	jb .num
	add al, 'A'-10
	jmp .out
 .num:
	add al, 0x30
 .out:
	mov word [gs:edi], ax
	sub edi, 2
	loop .next_char
	
 .end:
	popa
	ret

获取到的版本号有4个，依次为主版本号、次版本号、beta号、更新号。主版本号表示操作系统的主版本，例如，32位版本、64位版本、安装于U盘的版本、安装于硬盘的版本、安装于机器人的版本等；次版本号表示重要阶段的子版本，例如，只支持OS本身功能的版本、支持应用软件执行的版本、只支持单任务的版本、支持多任务的版本、支持文本交互CUI的版本、支持图形化交互GUI的版本、支持自然人机交互NUI的版本等；beta号表示子版本下修复严重Bug、较大功能修改等形成的版本；更新号表示beta版下修复小Bug、较小功能修改等形成的版本。

代码中新增加了获取版本号的API类型定义如下：

API_OS_VER	equ	0x0000FFFF

（2）执行程序

将上述代码保存为demo.asm文件，使用FASM编译代码生成可执行文件demo.bin并将之复制到装有元神操作系统的U盘的根目录，用该U盘启动机器进入元神操作系统，执行命令如下图所示：

第一个值表示主版本号，为0；第二个值为次版本号，为4；第三个值为beta号，为6；第四个值为更新号，为0。所以，元神操作系统的当前版本号为0.4.6.0。

3. 总结

本文通过示例代码介绍了获取元神操作系统版本号的过程，若想直接显示为0.4.6.0这样的表示形式，可以编写打印字符串的函数来替换打印DWORD函数。