基于元神操作系统编程读取硬盘文件

1. 背景

本文介绍了在元神操作系统上读取硬盘文件的方法，示例所用的硬盘是NTFS文件系统的、有2个分区的硬盘。

2. 方法

（1）编写程序

本例通过调用元神操作系统的API来读取指定文件的内容，并以二进制数据（十六进制格式）的形式打印到屏幕上，代码如下所示：

use32

START:
	pusha
	
	call demo_read_disk_file
	
	popa
	iret

include 'api_def.inc'

OS_API equ 0x00030C16
API_PARAM equ 0x03000000
SEG_BASE equ 0x00040000
cursor_x equ 0x02004B10
cursor_y equ 0x02004B12

sector_buff: times 512 db 0
file_name_disk db 'd1:\test0.txt',0
demo_read_disk_file:
	pusha
	mov edi, API_PARAM
	mov dword [fs:edi], API_READ_DISK_FILE
	mov dword [fs:edi+4], 2		;2 parameters
	xor eax, eax
	mov ax, ds
	add eax, SEG_BASE
	mov bh,byte [fs:eax+7]
    mov bl,byte [fs:eax+4]
    shl ebx,16
    mov bx,word [fs:eax+2]
    mov eax, ebx
	add ebx, file_name_disk
	add eax, sector_buff
	mov dword [fs:edi+8], ebx	;parameter_1: file name
	mov dword [fs:edi+12], eax	;parameter_2: start address of buffer to store result

	call pword [fs:OS_API]
	
	mov eax, [fs:edi+8]
	movzx ebx, word [fs:cursor_y]
	movzx ecx, word [fs:cursor_x]
	mov esi, [fs:edi+12]
	call print_bytes_hex
	
	add word [fs:cursor_y], 2
	popa
	ret

;print hex bytes
;input:
;	eax: byte count to print
;	ebx: y coordinate to print (from 0)
;	ecx: x coordinate to print (from 0)
;	esi: buffer storing data to print
print_bytes_hex:
	pusha
	imul edi,ebx,80*2
	add edi,ecx
	add edi,ecx
	
	mov ecx,eax
	mov ah,0x0F
 .next_char:
	mov bl,byte [fs:esi]
 .hex_char:
	mov al,bl
	and al,0x0F
	add al,0x30
	cmp al,0x39
	jbe .num_char
	add al,'A'-0x30-10
 .num_char:
	mov [gs:edi+2],ax
	shr ebx,4
	mov al,bl
	and al,0x0F
	add al,0x30
	cmp al,0x39
	jbe .num_char2
	add al,'A'-0x30-10
 .num_char2:
	mov [gs:edi],ax
	mov al,' '
	mov [gs:edi+4],ax
	add edi,6
	inc esi
	loop .next_char
	
	popa
	ret

代码中先对系统调用参数进行设置：第一个参数的API类型设置为API_READ_DISK_FILE，表示读取硬盘文件；第二个参数设置为2，表示该API需要两个输入参数；第三个参数为要读取的文件名称，传入的是绝对文件路径的起始地址；第四个参数为存放文件内容的内存区起始地址，本例使用预定义的变量sector_buff，若要动态申请内存来存放文件内容，可以通过调用元神操作系统的API （API_ALLOC_MEMORY）来获取动态内存的起始地址，并将该地址作为参数进行设置。

设置好调用参数后通过call指令进行调用，获取目标文件的大小和内容，并将结果以十六进制序列的形式输出到屏幕上。此处文件的大小以字节为单位。

本例中的API类型定义如下：

API_READ_DISK_FILE	equ	0x00000006

备注：本例中的文件名称为绝对路径文件名，包含着完整的路径和文件名称，开头的第一个字母D表示该文件位于硬盘（disk）上，第二个字母1表示该文件在硬盘的第一个分区上，依此类推。

（2）运行程序

将上述代码保存为demo.asm文件，用FASM编译该文件生成二进制文件demo.bin，并将文件复制到装有元神操作系统的U盘的根目录，用该U盘启动进入元神操作系统，通过命令ZX执行该二进制文件，结果如下图所示：

本例中的硬盘文件test0.txt仅包含17个字符“1234567890ABCDEFG”，因此只显示了17个字节。若想以字符形式显示文件内容，可以自行编写程序替换print_bytes_hex函数。

3. 总结

本文示例程序通过元神操作系统的API调用来读取硬盘上的文件。文件名称以绝对路径的形式提供，包含着完整的路径；而保存文件内容的内存块可以使用预定义的缓冲区变量，也可以动态申请获得。读取硬盘文件的API调用返回了文件内容及其长度，之后可以根据自己的需要和文件格式来输出或操作文件内容。