RChain运行原理[1] - 初识Rholang

初识Rholang

本文的代码可以复制到http://rchain.cloud/在线执行。

1、理论背景

回顾计算机理论发展史，现今几乎所有软件都基于上世纪的理论：

• 上世纪30年代发展的图灵机理论，将程序与数据分离，程序根据当前状态输出下一个状态。
• 和图灵机理论等价的lambda演算(λ-calculus)，对函数调用进行聚合，现今几乎所有的编程语言都基于这一理论模型。
• 接下来40年代发展出的冯诺依曼体系架构，使用随机存储器(内存)来保存程序状态。

这些理论奠定了当今主流的计算机模型-冯诺依曼计算机模型。发展到今天，即使在引入线程、纤程、mailbox、channel、异步等概念后，并没有从根本上改变其顺序执行的本质， 其在大规模分布式并行执行的环境下（比如区块链网络）相形见绌。

前人早已洞悉到了这些问题并逐渐发展出了一些以并行计算作为着眼点的形式系统。 其中以Actor模型和process-calculus最为著名。

RChain的分布式并行计算模型来自于Rho-caculus， 它是process-calculus的分支。它的发展脉络可以从下图中了解到。

• λ演算(Lambda-Calculus)最早是由Alonzo Church(图灵的博导)在20世纪30年代引入，当时的背景是解决函数可计算的本质性问题，初期λ演算成功的解决了在可计算理论中的判定性问题。
  后来根据Church–Turing thesis，证明了λ演算与图灵机是等价的。
  Lambda演算可比拟是最根本的编程语言，它是现今几乎所有编程语言(C#、Java、Python、Erlang、Scala、Haskell等）的理论基础。
• 随后在上世纪80年代，Robin Milner、Tony Hoare(快速排序算法的发明者)、Jan Bergstra以及Jan Willem Klop等科学家通过对并行计算进行建模，发展了Process-calculus。
• 而后的90年代以Robin Milner为代表的科学家继续在此基础上发展出来了π-calculus。π-calculus是第一个成功实现在动态变化的网络环境中进行并行计算的理论模型。
  这即是说，在多个计算节点组成的网络中，即使计算过程中有节点加入或者离开网络，计算过程也能平滑地在网络上继续下去。从这点上来说，它非常适合于区块链网络这种的多变的网络环境。
• 21世纪初期以来开始发展的Reflective Higher-Order calculus和π-calculus一脉相承， 它在π-calculus的基础上加入了反射(reflection)， 是第一种支持反射的并行计算模型。
  注意这里所说的反射不同于JAVA/C#程序员熟悉的结构化反射，具体会在后面说明。

2、Rho-calculus

RChain的编程语言Rholang衍生自Rho-calculus，自然地继承了Rho-calculus的四个C属性：

1. Completeness 图灵完备
2. Complexity 有确切的时间、空间复杂度
3. Concurrency 并行性
4. Compositionality 可组合性

Rho-calculus可以用下面的项(term)进行表述

P, Q, R ::= 0
  |   for( ptrn1 <- x1; … ; ptrnN <- xN ) P
  |   x!( Q )
  |   *x
  |   P|Q

x, ptrn ::= @P

接下来一项一项对照代码解释。

2.1 Rholang的世界观

假想一辆自动驾驶的汽车， 传感器监控着道路、速度、方向等参数， 行车电脑根据它们控制着方向、油门刹车。而它们又影响着转向机构、变速箱、发动机等等， 在它们的内部又是各种机械结构相互作用最终决定汽车的行进。
在这个复杂系统中，所有的参与者都是process， 而各部分通过消息相互作用，组成一个有机的整体。 以这样的眼光看世界的话，随会发现世界也是由通过消息相互影响的process构成。

在Rholang的世界中，亦是如此：

1. 一切皆是process
2. process通过消息进行通信

2.2 Process和Quoted Process

有如下代码

new myName in {
   Nil
}

• Nil 是最简单的process，它表示一个已经停止的process(就是啥都不做)，对应rho-calculus中的0
• new myName in申明一个quoted process，也叫做name。其中myName是这个name的标识符，对应rho-calculus中的 @P。 它的作用域仅在后面的花括号范围内。

2.3 发送消息

name(quoted process)提供了消息的通信机制作为channel使用，可以将它视为一个无序队列(Unordered Queue)。

通过!操作，可以向这个channel发送一个process作为消息。 比如如下代码将Hello World发送到myName中。发送的必须是一个process，而一切都是process，当然也包括字符串。

new myName in {
   myName!("Hello World")
}

2.4 接收消息

而通过<-操作，可以从channel接收并删除一个消息，接收到的消息是一个name(quoted process)

new myName in {
   for( v <- myName ) {  
    Nil
   }
}

for后面的花括号是一个在接受到消息后执行的process，称之为continuation。

2.5 并行执行

在Rholang的世界中，是不存在顺序执行的。
如果需要先执行完A然后执行B，那么A和B之间一定有某种数据依赖，需要通过上面的消息机制实现。

一般地，通过P|Q操作并行地执行多个process。 比如:

new myName in {
   for( v <- myName ) {
    Nil
   } |
   myName!("Hello World")
}

这段代码并行执行了两个process：其中一个process向myName发送了”Hello World”字符串；另一个process从myName读取一条消息后啥也不做。

2.6 Reflect和Reify

上面讲到的几个基本操作实际上都继承自π-calculus。 那么剩下的两个操作，就是rho-calculus对π-calculus的发展。

在rho-calculus中， name(quoted process)是process的引用，它代表的是指向的process的代码，亦既process的语法结构(syntactic structure)，
可以简单地类比为磁盘上的可执行文件;

而process是一个可运行的实例，类比于执行文件启动后创建的进程，是一个动态的概念。

通过* 和 @ 两个操作符可以让name(quoted process)和process相互转换，如下图。

• *x Reify操作将name(quoted process)反序列为process
• @P Reflect操作将process序列化为相应的name(quoted process)

例1:

@"stdout"!("Hello World")

如前文所说，一切都是process。那么"stdout"和"Hello World"都是process。将”Hello World”这个process发送给”stdout”肯定是不行的。
因为根据x!(Q)，发送的目的必须是一个name。因此@"stdout"操作将”stdout”这个process转换成了相应的name。实际上这就是一个系统合约：使用标准输出返回消息。

例2:

new myName in {
   for( v <- myName ) {
    @"stdout"!(*v)
   } |
   myName!("Hello World")
}

从myName中获取的消息以v标识，根据前面的文法for( ptrn1 <- x1; … ; ptrnN <- xN ) P，v一定是一个name。
而接下来需要将v发送到@"stdout"，又根据x!(Q)发送的必须是process而不能是name，因此需要*v装换成了相应的process。

例3:

new myName in {
   for( @v <- myName ) {
    @"stdout"!(v)
   } |
   myName!("Hello World")
}

这段代码和例2的代码非常类似。不同的是，接受到的消息用@v标识符表示，那么这里v是一个process，因此可以直接发送给@"stdout"

*x和@P两个操作的加入让rholang具备了反射的能力。这里所说的反射不同于JAVA/C#程序员熟悉的元编程(meta-programming)。
rholang的反射是一种过程化的反射，它使得process具有迁移到网络上其它节点执行的能力，因此Rho-calculus还有个别名叫移动进程演算(Mobile process calculus)。

例4:

new myName in {
  for( v <- myName ) {
     *v
  } |
  myName!({ @"stdout"!("Hello World") })
}

这段代码将{ @"stdout"!("Hello World") }这个process发送到了myName，另一个process在接收到后执行该process。
需要注意的是myName!({ @"stdout"!("Hello World") })和for( v <- myName ) { *v } 这两个process是可以在不同的网络节点上执行。
但是对于rholang程序开发者是透明的。这就是rholang的可迁移性(Mobility)，它使Rholang程序在RChain的网络上“流动”，具体的细节在后文名字空间一节中详述。

转载请注明出处
本文地址: https://blog.csdn.net/wangjia184/article/details/80090924

下一篇《元组空间》