ARM汇编总结

一：ARM裸机重定位汇编代码到解读

本文转自 ​​​​​​ARM裸机重定位汇编代码到解读_aoxiang_ywj的博客-CSDN博客

为什么需要重定位？
本来代码是运行在0xd0020010的，但因为一些原因我们又希望代码实际是在0xd0024000位置运行的。这时候就需要重定位了。

ARM裸机重定位汇编代码到解读
任务：在SRAM中将代码从0xd0020010重定位到0xd0024000

思路： 第一点：通过链接脚本将代码链接到0xd0024000
            第二点：dnw下载时将bin文件下载到0xd0020010
            第三点：代码执行时通过代码前段的少量位置无关码将整个代码搬移到0xd0024000
            第四点：使用一个长跳转跳转到0xd0024000处的代码继续执行，重定位完成

// 重定位汇编指令
// adr指令用于加载_start当前运行地址
   adr r0, _start       // adr加载时就叫短加载		
// ldr指令用于加载_start的链接地址:0xd0024000
   ldr r1, =_start      // ldr加载时如果目标寄存器是pc就叫长跳转，如果目标寄存器是r1等就叫长加载，_start地址链接文件指定	
// bss段的起始地址
   ldr r2, =bss_start   // 就是我们重定位代码的结束地址，也就是重定位只需重定位代码段和数据段即可，bss_start地址链接文件指定
   cmp r0, r1           // 比较_start的运行时地址和链接地址是否相等
   beq clean_bss        // 如果相等说明不需要重定位，所以跳过copy_loop，直接到clean_bss
                        // 如果不相等说明需要重定位，那么直接执行下面的copy_loop进行重定位
                        // 重定位完成后继续执行clean_bss。
// 用汇编来实现的一个while循环，这段代码是用来完成重定位的
copy_loop:
	ldr r3, [r0], #4    // 源
	str r3, [r1], #4    // 目的   这两句代码就完成了4个字节内容的拷贝
	cmp r1, r2          // r1和r2都是用ldr加载的，都是链接地址，所以r1不断+4，最后总能等于r2
	bne copy_loop       // 只要r1与r2不相等即跳转到copy_loop
 
// 清bss段，其实就是在链接地址处把bss段全部清零（因为bss段全是被初始化为0的全局变量，不需要重定位，只需要在bss处清零即可）
clean_bss:
	ldr r0, =bss_start					
	ldr r1, =bss_end
	cmp r0, r1              // 如果r0等于r1，说明bss段为空，直接下去(beq跳转到run_on_dram)
	beq run_on_dram	        // 清除bss完之后的地址
	mov r2, #0              // 如果不相等，说明bss段有内容，则清零r2
clear_loop:
	str r2, [r0], #4        // 先将r2中的值放入r0所指向的内存地址（r0中的值作为内存地址），然后r0 = r0 + 4
	cmp r0, r1              //str r2, [r0], #4相当于在C语言中相当于int *p = &r0； 然后*p++ = r2；              
	bne clear_loop
 
run_on_dram:	
    // 长跳转到led_blink开始第二阶段
	ldr pc, =led_blink             // ldr指令实现长跳转
	 
    // 从这里之后就可以开始调用C程序了
	//bl led_blink                 // bl指令实现短跳转
	
// 汇编最后的这个死循环不能丢
	b .

清理完bss段后，重定位就结束了。然后当前的状况是：
    1、当前运行地址还在0xd0020010开头的（重定位前的）那一份代码中运行着。
    2、此时SRAM中已经有了2份代码，1份在d0020010开头，另一份在d0024000开头的位置。
    然后就要长跳转了（这时候短跳转实际执行的是运行地址处的那一份，而长跳转执行的是链接地址处那一份）

长加载与长跳转的异同
长加载与长跳转都是用ldr指令实现的。

ldr加载时如果目标寄存器是pc就叫长跳转，如果目标寄存器是r1等就叫长加载    

ldr pc, =led_blink                // ldr指令实现长跳转

ldr r1, =_start                      // ldr指令实现常佳仔

上面代码段中出现的一些汇编指令cmp、bne、beq详解
cmp：算数处理指令，用于比较两个寄存器中的数是否相同（把一个寄存器的内容和另一个寄存器的内容或立即数进行减法比较），cmp后不存储结果，都会更改标志位
bne: 数据跳转指令，标志寄存器中Z标志位不等于零时（也就是cmp的两个寄存器中的数如果不相等）, 跳转到BNE后标签处
beq: 数据跳转指令，标志寄存器中Z标志位等于零时（也就是cmp的两个寄存器中的数如果相等）, 跳转到BEQ后标签处