使用AutoHotKey(AHK)自动根据文献名查找文献DOI，并查找pdf

最新推荐文章于 2024-07-29 10:50:55 发布
最新推荐文章于 2024-07-29 10:50:55 发布
阅读量1.2k 收藏 1
点赞数 1
分类专栏： AutoHotKey 文章标签： autohotkey
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/wangpeng246300/article/details/107217679
版权

引子

google学术上的文章有些没有pdf链接，其中大部分可以在scihub上下载到。如果要在scihub上下载文献pdf，需要文献的DOI号，通常需要再在crossref上查找DOI，之后再去scihub上查找pdf。这样一套下来效率太低，因此有了这篇文章。
如果你认为此脚本可以有更多的可能性或者有更好的实现方式，欢迎在评论区讨论；如果你觉得脚本对你有用，还请顺手点赞收藏，你的支持是对我最大的鼓励😊

脚本功能

该脚本可以实现的功能如下：

  1. 自动查找与鼠标选中内容相同标题的文献DOI，如果多篇文献标题相同（概率极低），则只会查找crossref中第一篇文章的DOI，并保存到系统剪贴板；
  2. 根据第1步中的DOI信息，自动在默认浏览器中打开这篇文献的scihub链接，方便查看和下载；

脚本使用方法

单击F3键，实现功能2；
双击F3键，实现功能1
长按F3键，F3键的原始功能。

脚本

$F3::
    KeyWait, F3, T0.6 ;wait 0.6s
    if (ErrorLevel)
        sendinput {F3} ;long press
    else {
        KeyWait, F3, D T0.3 ;wait 0.3s
        if (ErrorLevel)
            GetPdfFromSciHub(false) ;single press
        else
            GetPdfFromSciHub(true) ;double press
    }
    KeyWait, F3
return

; get pdf according to title
GetPdfFromSciHub(onlyDOI := false)
{
    transMultiToSingle()
    ti:=RegExReplace(clipboard,"[ ]+"," ") ; keep only one space
    title:=StrReplace(ti," ","+") ; replace space by +
    url := "https://api.crossref.org/works?query=" . title ; create url
    sJson := GetTxtFromUrl(url) ; get json
    parsed := JSON.Load(sJson) ; parse json
    for item in parsed.message.items
    {
        StringLower, oti, % parsed.message.items[item].title[1] 
        StringLower, iti, ti
        if(oti == iti)
        {
            doi:=parsed.message.items[item].DOI
            if onlyDOI
            {
                msgbox,0x40000 ,,% doi,1
                clipboard:=doi
            }
            else
                run, https://sci-hub.tw/%doi%
            return
        }
    }
    MsgBox,,,No article, 3
}

; transform multiline clipboard string to single line
transMultiToSingle()
{
    Clipboard := ""
    SendInput, ^c
    ClipWait, 1
    if ErrorLevel
        Return
    
    ;Later two lines transform multiline string to single line string, and save results in clipboard. This is very useful when copying multiline string from pdf.
    Clipboard:=RegExReplace(Clipboard,"\r\n[ #;%]*([\x{3002}\x{ff1b}\x{ff0c}\x{ff1a}\x{201c}\x{201d}\x{ff08}\x{ff09}\x{3001}\x{ff1f}\x{300a}\x{300b}\x{4e00}-\x{9fa5}])","$1")
    Clipboard:=RegExReplace(Clipboard,"\r\n[ #;%]*"," ")
    ;Clipboard:=RegExReplace(Clipboard,"\r\n[ #;%]*([A-z])"," $1")
    ;Clipboard:=RegExReplace(Clipboard,"\r\n[ #;%]*([^A-z])","$1")
}

; get text content from url and return
GetTxtFromUrl(url) 
{
    whr := ComObjCreate("WinHttp.WinHttpRequest.5.1") 
    whr.Open("GET", url, true)
    whr.Send()
    ; Using 'true' above and the call below allows the script to remain responsive.
    whr.WaitForResponse()
return whr.ResponseText
}

/**
 * Lib: JSON.ahk
 *     JSON lib for AutoHotkey.
 * Version:
 *     v2.1.3 [updated 04/18/2016 (MM/DD/YYYY)]
 * License:
 *     WTFPL [http://wtfpl.net/]
 * Requirements:
 *     Latest version of AutoHotkey (v1.1+ or v2.0-a+)
 * Installation:
 *     Use #Include JSON.ahk or copy into a function library folder and then
 *     use #Include <JSON>
 * Links:
 *     GitHub:     - https://github.com/cocobelgica/AutoHotkey-JSON
 *     Forum Topic - http://goo.gl/r0zI8t
 *     Email:      - cocobelgica <at> gmail <dot> com
 */


/**
 * Class: JSON
 *     The JSON object contains methods for parsing JSON and converting values
 *     to JSON. Callable - NO; Instantiable - YES; Subclassable - YES;
 *     Nestable(via #Include) - NO.
 * Methods:
 *     Load() - see relevant documentation before method definition header
 *     Dump() - see relevant documentation before method definition header
 */
class JSON
{
	/**
	 * Method: Load
	 *     Parses a JSON string into an AHK value
	 * Syntax:
	 *     value := JSON.Load( text [, reviver ] )
	 * Parameter(s):
	 *     value      [retval] - parsed value
	 *     text    [in, ByRef] - JSON formatted string
	 *     reviver   [in, opt] - function object, similar to JavaScript's
	 *                           JSON.parse() 'reviver' parameter
	 */
	class Load extends JSON.Functor
	{
		Call(self, ByRef text, reviver:="")
		{
			this.rev := IsObject(reviver) ? reviver : false
		; Object keys(and array indices) are temporarily stored in arrays so that
		; we can enumerate them in the order they appear in the document/text instead
		; of alphabetically. Skip if no reviver function is specified.
			this.keys := this.rev ? {} : false

			static quot := Chr(34), bashq := "\" . quot
			     , json_value := quot . "{[01234567890-tfn"
			     , json_value_or_array_closing := quot . "{[]01234567890-tfn"
			     , object_key_or_object_closing := quot . "}"

			key := ""
			is_key := false
			root := {}
			stack := [root]
			next := json_value
			pos := 0

			while ((ch := SubStr(text, ++pos, 1)) != "") {
				if InStr(" `t`r`n", ch)
					continue
				if !InStr(next, ch, 1)
					this.ParseError(next, text, pos)

				holder := stack[1]
				is_array := holder.IsArray

				if InStr(",:", ch) {
					next := (is_key := !is_array && ch == ",") ? quot : json_value

				} else if InStr("}]", ch) {
					ObjRemoveAt(stack, 1)
					next := stack[1]==root ? "" : stack[1].IsArray ? ",]" : ",}"

				} else {
					if InStr("{[", ch) {
					; Check if Array() is overridden and if its return value has
					; the 'IsArray' property. If so, Array() will be called normally,
					; otherwise, use a custom base object for arrays
						static json_array := Func("Array").IsBuiltIn || ![].IsArray ? {IsArray: true} : 0
					
					; sacrifice readability for minor(actually negligible) performance gain
						(ch == "{")
							? ( is_key := true
							  , value := {}
							  , next := object_key_or_object_closing )
						; ch == "["
							: ( value := json_array ? new json_array : []
							  , next := json_value_or_array_closing )
						
						ObjInsertAt(stack, 1, value)

						if (this.keys)
							this.keys[value] := []
					
					} else {
						if (ch == quot) {
							i := pos
							while (i := InStr(text, quot,, i+1)) {
								value := StrReplace(SubStr(text, pos+1, i-pos-1), "\\", "\u005c")

								static tail := A_AhkVersion<"2" ? 0 : -1
								if (SubStr(value, tail) != "\")
									break
							}

							if (!i)
								this.ParseError("'", text, pos)

							  value := StrReplace(value,  "\/",  "/")
							, value := StrReplace(value, bashq, quot)
							, value := StrReplace(value,  "\b", "`b")
							, value := StrReplace(value,  "\f", "`f")
							, value := StrReplace(value,  "\n", "`n")
							, value := StrReplace(value,  "\r", "`r")
							, value := StrReplace(value,  "\t", "`t")

							pos := i ; update pos
							
							i := 0
							while (i := InStr(value, "\",, i+1)) {
								if !(SubStr(value, i+1, 1) == "u")
									this.ParseError("\", text, pos - StrLen(SubStr(value, i+1)))

								uffff := Abs("0x" . SubStr(value, i+2, 4))
								if (A_IsUnicode || uffff < 0x100)
									value := SubStr(value, 1, i-1) . Chr(uffff) . SubStr(value, i+6)
							}

							if (is_key) {
								key := value, next := ":"
								continue
							}
						
						} else {
							value := SubStr(text, pos, i := RegExMatch(text, "[\]\},\s]|$",, pos)-pos)

							static number := "number", integer :="integer"
							if value is %number%
							{
								if value is %integer%
									value += 0
							}
							else if (value == "true" || value == "false")
								value := %value% + 0
							else if (value == "null")
								value := ""
							else
							; we can do more here to pinpoint the actual culprit
							; but that's just too much extra work.
								this.ParseError(next, text, pos, i)

							pos += i-1
						}

						next := holder==root ? "" : is_array ? ",]" : ",}"
					} ; If InStr("{[", ch) { ... } else

					is_array? key := ObjPush(holder, value) : holder[key] := value

					if (this.keys && this.keys.HasKey(holder))
						this.keys[holder].Push(key)
				}
			
			} ; while ( ... )

			return this.rev ? this.Walk(root, "") : root[""]
		}

		ParseError(expect, ByRef text, pos, len:=1)
		{
			static quot := Chr(34), qurly := quot . "}"
			
			line := StrSplit(SubStr(text, 1, pos), "`n", "`r").Length()
			col := pos - InStr(text, "`n",, -(StrLen(text)-pos+1))
			msg := Format("{1}`n`nLine:`t{2}`nCol:`t{3}`nChar:`t{4}"
			,     (expect == "")     ? "Extra data"
			    : (expect == "'")    ? "Unterminated string starting at"
			    : (expect == "\")    ? "Invalid \escape"
			    : (expect == ":")    ? "Expecting ':' delimiter"
			    : (expect == quot)   ? "Expecting object key enclosed in double quotes"
			    : (expect == qurly)  ? "Expecting object key enclosed in double quotes or object closing '}'"
			    : (expect == ",}")   ? "Expecting ',' delimiter or object closing '}'"
			    : (expect == ",]")   ? "Expecting ',' delimiter or array closing ']'"
			    : InStr(expect, "]") ? "Expecting JSON value or array closing ']'"
			    :                      "Expecting JSON value(string, number, true, false, null, object or array)"
			, line, col, pos)

			static offset := A_AhkVersion<"2" ? -3 : -4
			throw Exception(msg, offset, SubStr(text, pos, len))
		}

		Walk(holder, key)
		{
			value := holder[key]
			if IsObject(value) {
				for i, k in this.keys[value] {
					; check if ObjHasKey(value, k) ??
					v := this.Walk(value, k)
					if (v != JSON.Undefined)
						value[k] := v
					else
						ObjDelete(value, k)
				}
			}
			
			return this.rev.Call(holder, key, value)
		}
	}

	/**
	 * Method: Dump
	 *     Converts an AHK value into a JSON string
	 * Syntax:
	 *     str := JSON.Dump( value [, replacer, space ] )
	 * Parameter(s):
	 *     str        [retval] - JSON representation of an AHK value
	 *     value          [in] - any value(object, string, number)
	 *     replacer  [in, opt] - function object, similar to JavaScript's
	 *                           JSON.stringify() 'replacer' parameter
	 *     space     [in, opt] - similar to JavaScript's JSON.stringify()
	 *                           'space' parameter
	 */
	class Dump extends JSON.Functor
	{
		Call(self, value, replacer:="", space:="")
		{
			this.rep := IsObject(replacer) ? replacer : ""

			this.gap := ""
			if (space) {
				static integer := "integer"
				if space is %integer%
					Loop, % ((n := Abs(space))>10 ? 10 : n)
						this.gap .= " "
				else
					this.gap := SubStr(space, 1, 10)

				this.indent := "`n"
			}

			return this.Str({"": value}, "")
		}

		Str(holder, key)
		{
			value := holder[key]

			if (this.rep)
				value := this.rep.Call(holder, key, ObjHasKey(holder, key) ? value : JSON.Undefined)

			if IsObject(value) {
			; Check object type, skip serialization for other object types such as
			; ComObject, Func, BoundFunc, FileObject, RegExMatchObject, Property, etc.
				static type := A_AhkVersion<"2" ? "" : Func("Type")
				if (type ? type.Call(value) == "Object" : ObjGetCapacity(value) != "") {
					if (this.gap) {
						stepback := this.indent
						this.indent .= this.gap
					}

					is_array := value.IsArray
				; Array() is not overridden, rollback to old method of
				; identifying array-like objects. Due to the use of a for-loop
				; sparse arrays such as '[1,,3]' are detected as objects({}). 
					if (!is_array) {
						for i in value
							is_array := i == A_Index
						until !is_array
					}

					str := ""
					if (is_array) {
						Loop, % value.Length() {
							if (this.gap)
								str .= this.indent
							
							v := this.Str(value, A_Index)
							str .= (v != "") ? v . "," : "null,"
						}
					} else {
						colon := this.gap ? ": " : ":"
						for k in value {
							v := this.Str(value, k)
							if (v != "") {
								if (this.gap)
									str .= this.indent

								str .= this.Quote(k) . colon . v . ","
							}
						}
					}

					if (str != "") {
						str := RTrim(str, ",")
						if (this.gap)
							str .= stepback
					}

					if (this.gap)
						this.indent := stepback

					return is_array ? "[" . str . "]" : "{" . str . "}"
				}
			
			} else ; is_number ? value : "value"
				return ObjGetCapacity([value], 1)=="" ? value : this.Quote(value)
		}

		Quote(string)
		{
			static quot := Chr(34), bashq := "\" . quot

			if (string != "") {
				  string := StrReplace(string,  "\",  "\\")
				; , string := StrReplace(string,  "/",  "\/") ; optional in ECMAScript
				, string := StrReplace(string, quot, bashq)
				, string := StrReplace(string, "`b",  "\b")
				, string := StrReplace(string, "`f",  "\f")
				, string := StrReplace(string, "`n",  "\n")
				, string := StrReplace(string, "`r",  "\r")
				, string := StrReplace(string, "`t",  "\t")

				static rx_escapable := A_AhkVersion<"2" ? "O)[^\x20-\x7e]" : "[^\x20-\x7e]"
				while RegExMatch(string, rx_escapable, m)
					string := StrReplace(string, m.Value, Format("\u{1:04x}", Ord(m.Value)))
			}

			return quot . string . quot
		}
	}

	/**
	 * Property: Undefined
	 *     Proxy for 'undefined' type
	 * Syntax:
	 *     undefined := JSON.Undefined
	 * Remarks:
	 *     For use with reviver and replacer functions since AutoHotkey does not
	 *     have an 'undefined' type. Returning blank("") or 0 won't work since these
	 *     can't be distnguished from actual JSON values. This leaves us with objects.
	 *     Replacer() - the caller may return a non-serializable AHK objects such as
	 *     ComObject, Func, BoundFunc, FileObject, RegExMatchObject, and Property to
	 *     mimic the behavior of returning 'undefined' in JavaScript but for the sake
	 *     of code readability and convenience, it's better to do 'return JSON.Undefined'.
	 *     Internally, the property returns a ComObject with the variant type of VT_EMPTY.
	 */
	Undefined[]
	{
		get {
			static empty := {}, vt_empty := ComObject(0, &empty, 1)
			return vt_empty
		}
	}

	class Functor
	{
		__Call(method, ByRef arg, args*)
		{
		; When casting to Call(), use a new instance of the "function object"
		; so as to avoid directly storing the properties(used across sub-methods)
		; into the "function object" itself.
			if IsObject(method)
				return (new this).Call(method, arg, args*)
			else if (method == "")
				return (new this).Call(arg, args*)
		}
	}
}

参考资料

脚本中的JSON解析部分代码是从Github上copy的，在此附上参考地址AutoHotkey-JSON

步子大了吧
关注
专栏目录
AutoHotkey脚本.ahk文件关联工具-解决方案-注册表.zip
02-04
在Windows系统中，.ahk文件是AutoHotkey脚本的扩展名，通常需要通过AutoHotkey解释器来执行。然而，有时用户可能希望将.ahk文件与AutoHotkey程序关联，以便双击这些脚本时能够直接运行。这涉及到文件关联和注册表...
Ahk2Exe:官方 AutoHotkey 脚本编译器 - 用 AutoHotkey 编写
07-24
Ahk2Exe 是官方的 AutoHotkey 脚本到 EXE 转换器，它是用 AutoHotkey 编写的。 如何编译 Ahk2Exe 必须与自身一起编译，因为它使用编译器指令。 （确保使用最新的 AutoHotkey 自包含二进制文件，版本 1.1。） 解压...
截屏、文字提取一气呵成，超实用 OCR 开源小工具
程序员小乐
10-04 1503
点击上方 "程序员小乐"关注,星标或置顶一起成长关注订阅号「程序员小乐」，收看更多精彩内容每日英文Not every effort there is a harvest...
[AHK]Dictionary Search
liuyukuan的专栏
06-25 723
Preforms a dictionary search at Dictionary.com of the highlighted text or text input if no text is highlighted. The results are trimmed down and displayed in a Gui using an ActiveX control. Whe
sci-hub下载不了的文献去哪里获取全文
最新发布
yunhk的博客
07-29 773
我们在查找外文文献时经常会用到sci-hub，但sci-hub也有没有收录的文献，遇到这种情况我们可以用另一个途径来获取该文献。
autohotkey调用词典应用程序
liuyukuan的专栏
10-18 1983
autohotkey昨天试了下autohotkey感觉还好 。语法简单，但我不是很喜欢语法的style，觉得如果代码的比较长时检错会很困难。但对于autohotkey这个名字来讲是它是很称职的，编写快捷键很方便。<br /><br />昨天拼凑的autohotkey代码, alt+滚轮横向转屏，选词后ctrl+alt+D直接调用Lingoes，Merriam-Webster，Collins COBUILD，Babylon字典查词。<br /><br />DetectHiddenWindows, On <br
SSCI及SCI撰写|查找文献doi的八大方法
weixin_63253486的博客
01-04 1万+
本文介绍了几个常用的DOI解析网站，包括CrossRef、Resolve a DOI Name和China DOI。这些网站不仅可以通过文献检索获得DOI，还能通过DOI查找全文信息。对于外文文献，用户可在CrossRef输入篇名检索到DOI链接，并跳转至文献来源数据库的全文页；Resolve a DOI Name则专门解析外文文献DOI。对于中文文献，China DOI提供直接使用DOI查找文献来源数据库全文详情页的功能。最后，文献党下载器可作为获取全文权限的补充途径。这些工具的介绍将有助于科研人员更便捷
AutoHotKey + Longman Dictionary of Contemparory English
liuyukuan的专栏
10-27 1411
<br /><br />由 khliu 發表於 2008-09-06, 19:24<br />http://lsmls.org/forum/viewtopic.php?t=104AutoHotKey是一個類似Linux上shell script的軟體, 或者簡單來說, 他是一個設定快速鍵的軟體,<br />有興趣的話可以看一下這個介紹, http://blog.nownews.com/jazzdog/textview.php?file=54048<br />接下來我要講的是, 如何使用Alt-1當成查單字的
利用python脚本根据DOI号自动查询参考文献信息
热门推荐
huitest的博客
09-22 1万+
背景： 某人写了一篇论文，需要将参考文献信息内容查询出来，第一步，就是利用人名及年份查询所引用的文献或者文章及文章的doi，如果没用，也可也复制文章在百度里面查找， 第二步，拿到doi号在网址里面查询 如此往复，如果文章引用超过100jiao多，如此重重，无聊，而且易出错， 接下来，我们利用python 编写脚步，自动查询，然后把值保存在txt里面 步骤： ...
AutoHotKey 帮助文档 AutoHotKey 帮助文档
03-01
AutoHotKey 脚本是指使用 AutoHotKey 语言编写的脚本，用于自动完成特定的任务。脚本可以包含多种命令和函数。 9. 变量和表达式 AutoHotKey 中的变量和表达式是指用户可以使用的变量和表达式来存储和处理数据。 ...
ahk：AutoHotkey的Python包装器。 利用Python的美丽来利用AutoHotkey的自动化功能
02-06
AHK周围的Python包装器。 安装 pip install ahk 需要Python 3.6+ 需要Python 3.8+ 另请参见 用法 from ahk import AHK ahk = AHK () ahk . mouse_move ( x = 100 , y = 100 , blocking = True ) # Blocks until ...
zotero-shortdoi:Zotero扩展以检索和验证DOI和shortDOI
05-02
Zotero DOI经理 这是Zotero（研究源管理工具）的附加组件。 该插件可以使用CrossRef API自动获取期刊文章的DOI名称，也可以使用查找shortDOI名称。 该附加组件还验证存储的DOI是否有效，并标记无效的DOI。 请在Zotero论坛上报告所有错误，问题或功能请求。 此扩展的代码部分基于Anton Beloglazov撰写的。 插件功能 获取shortDOI：对于所选项目，请查找shortDOI（替换存储的DOI，如果有的话）并标记无效的DOI。 获得较长的DOI：对于选定的项目，请查找完整的DOI（如果有的话，请替换存储的DOI）并标记无效的DOI。 验证并清理DOI：对于选定的项目，请查找完整的DOI（如果有，则替换存储的DOI），验证存储的DOI是否有效，并标记无效的DOI。 此函数还会从DOI字段中删除不必要的前缀（例如doi: ， https:/
PDF论文自动检索脚本
11-11
使用本脚本可以自动地将文件夹下所有论文进行按照相应的检索条件进行检索，对文件进行重命名并复制到目标文件夹
AutoHotkey.py:用Python编写AutoHotkey脚本
05-04
AutoHotkey.py提供了一个用户友好的API，使用户可以利用AutoHotkey的功能在Python中编写热键和自动化脚本。 它是通过将Python DLL嵌入AutoHotkey进程来实现的。 快速开始 确保已安装 3.7或更高版本以及 1.1.28或更高...
请用AUTOHOTKEY2.0版本编写一段获取控件内文字的代码
weixin_42604188的博客
12-25 504
使用 AutoHotkey 2.0 版本可以使用以下代码来获取控件内的文字： 首先，使用 ControlGetText 函数获取控件内的文本。该函数的语法如下： ControlGetText, OutputVar, ControlID, WinTitle, WinText, ExcludeTitle, ExcludeText 其中： OutputVar 是用于存储获取到的文本的变量名。 Co...
用 AutoHotkey 做一个文件查找工具之四：根据输入实时更新过滤文件列表
liuyukuan的专栏
05-28 2045
http://www.cnblogs.com/yonken/archive/2010/05/10/Smart_Open_Files_Update_File_List_On_Pattern_Changed.html
使用AutoHotKey(AHK)自动将多行内容转成单行，并翻译，或获取中文拼音
步子大了吧
07-08 2912
动机 你曾遇到过下面这些情况吗？在上网或看文献时总是会遇到不认识的单词还要打开词典软件或谷歌翻译查词？或者有些汉字不知道它的拼音还要去百度它的拼音？又或者想不起来一个词语的英文翻译？又又或者在复制pdf中的多行文本时还得手动把复制出来的换行删掉？ 相信你或多或少都和遇到过上面的烦恼，下面分享一个我使用的AutoHotKey脚本帮大家解决这些问题。如果你认为此脚本可以有更多的可能性或者有更好的实现方式，欢迎在评论区讨论；如果你觉得脚本对你有用，还请顺手点赞收藏，你的支持是对我最大的鼓励???? 脚本功能 该脚
ahk系列-windows超级运行框-表达式计算（2）—set /sets表达式
qq_34407846的博客
12-06 466
改造windows的运行框，让运行框除了执行系统的快捷方式之外，还可以执行我们自定义的操作！
【ahk】映射按键到执行函数
qq_20679687的博客
06-15 243
【代码】【ahk】映射按键到执行函数。
AutoHotkey脚本：ahk_spy.txt，实现窗口和鼠标信息监控
"ahk_spy.txt 是一个使用AutoHotkey编写的脚本，用于获取和显示系统中的各种监控信息，如窗口信息、鼠标指针下的内容、鼠标坐标、激活窗口的位置以及窗口文本等。用户需要先下载并安装AutoHotkey.exe执行环境来运行...
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值