linux 终端 画圆,linux - 我如何在gnuplot绘图的每个点绘制一个圆？ - SO中文参考 - www.soinside.com...

如果您真的想要圈子，以下可能是我想到的解决方案。但是也许您实际上想要绘制表面？为此，可能还有其他解决方案。

代码：### circles along datapoints

reset session

# create some 3D test data

set samples 50

set table $Data

plot [0:1.5] '+' u (cos(2*pi*$1)):(sin(2*pi*$1)):($1*10) w table

unset table

# define the circle

Radius = 0.1

set samples 24

set table $Circle

plot [0:1] '+' u (cos(2*pi*$1)):(sin(2*pi*$1)) w table

unset table

Offset(i,axis) = real(word($Data[i],axis))

set view 65,124

splot $Data u 1:2:3 w lp pt 7 lw 2 lc rgb "red", \

for [i=1:|$Data|] $Circle u ($1+Offset(i,1)):($2+Offset(i,2)):(Offset(i,3)) w l notitle

### end of code

结果：

添加：

这里是一个稍微修改的版本(也许有一种更简单的实现方法)，您在其中创建可以用表面绘制的数据块$Tube。圆仍平行于xy平面。虽然，我怀疑您实际上可能想使圆与输入数据路径的方向正交。

代码：### circle surface along datapoints

reset session

# create some test data

set samples 50

set table $Data

plot [0:1.5] '+' u (cos(2*pi*$1)):(sin(2*pi*$1)):($1*10) w table

unset table

# define the circle

Radius = 0.1

set samples 24

set table $Circle

plot [0:1] '+' u (cos(2*pi*$1)):(sin(2*pi*$1)) w table

unset table

D(i,axis) = real(word($Data[i],axis))

C(i,axis) = real(word($Circle[i],axis))

# generate "tube" datapoints

set print $Tube

do for [i=1:|$Circle|] {

do for [j=1:|$Data|] {

print sprintf("%.3f %.3f %.3f", C(i,1)+D(j,1), C(i,2)+D(j,2), D(j,3))

}

print "" # empty line

}

set print

set pm3d depthorder noborder

set pm3d lighting specular 0.5

set view 65,124

splot $Data u 1:2:3 w lp pt 7 lw 2 lc rgb "red", \

$Tube u 1:2:3 w pm3d notitle

### end of code

结果：