为mit scheme添加for循环语句

Mit-Scheme不支持syntax-case, 只能用它的er-macro-transformer来编写。Mit-Scheme的宏系统比较低级，不支持模式匹配和literal。

使用pmatch能得到一个可用的模式匹配，为了简洁这里使用了pmatch，没有pmatch也可以编写同样的宏，但啰嗦一点。没有literal就导致代码里面满是反引号和逗号。完成的代码看起来很啰嗦，但编写时却比较简单，先写一个与使用syntax-case时相同的transformer，然后再重命名。

宏不会对参数求值。编写正确宏的一个要点就是搞清楚哪个参数在哪个时候求值。最初编写这个宏时就因为没注意参数求值的时机出了一个bug，下面的代码应该是合法的，但最初的版本却不能得到想要的结果。

(define i 1)
(for i from i to (* i 100)
  (if (> i 10) (break #f))
  (display i)
  (display " "))
from后面的i应该一开始就求值与for后面的i和for语句内第二行以后的i无关。

 

(define-syntax for
  (er-macro-transformer
   (lambda (x r c)
     (pmatch x
       (`(for ,i in ,l . ,body)
        (guard (identifier? i))
        `(,(r 'call-with-current-continuation)
          (,(r 'lambda) (break)
           (,(r 'do) ((,(r 'ns) ,l (,(r 'cdr) ,(r 'ns))))
            ((,(r  'null?) ,(r 'ns)) #f)
            (,(r  'let) ((,i (,(r 'car) ,(r 'ns))))
             (,(r 'call-with-current-continuation)
              (,(r 'lambda) (continue)
               (,(r 'begin)
                ,@body))))))))
       (`(for ,i from ,a to ,z . ,body)
        (guard (identifier? i))
        `(,(r 'let) ((,(r 'a) ,a)
                     (,(r 'z) ,z))
          (,(r 'call/cc)
           (,(r 'lambda) (break)
            (,(r 'do) ((,i ,(r 'a) (+ ,i 1)))
             ((,(r '>) ,i ,(r ' z)) #f)
             (,(r 'call/cc)
              (,(r 'lambda) (continue)
               (,(r 'begin)
                ,@body))))))))
       (`(for ,i from ,a ,b to ,z . ,body)
        (guard (identifier? i))
        `(,(r 'let*) ((,(r 'a) ,a)
                      (,(r 'b) ,b)
                      (,(r 'z) ,z)
                      (,(r 's) (,(r '-) ,(r 'b) ,(r 'a)))
                      (,(r 'p) (,(r 'if) (,(r '>) ,(r 'b) ,(r 'a))
                                ,(r '>) ,(r '<))))
          (,(r 'call/cc)
           (,(r 'lambda) (break)
            (,(r 'do) ((,i ,(r 'a) (,(r '+) ,i ,(r 's))))
             ((,(r 'p) ,i ,(r 'z)) #f)
             (,(r 'call/cc)
              (,(r 'lambda) (continue)
               (,(r 'begin)
                ,@body))))))))
       (else (error 'bad-syntax x))))))

转载于:https://www.cnblogs.com/billythekid/p/4014296.html