Qt工程文件(一)--常用模板

GUI程序模板

#模板
TEMPLATE = app
#名称
TARGET = myAction

#qt模块
QT      += core gui network
greaterThan(QT_MAJOR_VERSION, 4): QT += widgets 

#编译选项
CONFIG  += c++11

#预处理宏
DEFINES += QT_DEPRECATED_WARNINGS

---

控制台程序模板

#模板
TEMPLATE = app
#名称
TARGET = myAction

#qt模块
QT -= gui
QT += core

#编译选项
CONFIG -= app_bundle
CONFIG += c++11 console

#预处理宏
DEFINES += QT_DEPRECATED_WARNINGS

---

平台区分

#生成动态库
TEMPLATE = lib
#静态库添加
#CONFIG += staticlib

头文件
INCLUDEPATH += $$PWD/../myBin/inc
DEPENDPATH += $$PWD/../myBin/inc



#DEFINES += HISI_WINXP
#DEFINES += HISI_ARM

win32{
    if(contains(DEFINES,HISI_WINXP)){
        message(" platform winxp")
        TARGET = culoptions
        DESTDIR =$$PWD/../myBin/xp/release

        LIBS += -L$$PWD/../myBin/xp/ -llibcurl_imp
        INCLUDEPATH += $$PWD/../myBin/xp
        DEPENDPATH += $$PWD/../myBin/xp
    }else{

        CONFIG(release, debug|release){
        TARGET = culoptions

        contains(QT_ARCH, i386){
            message(" platform win32 release win32")
            DESTDIR =$$PWD/../myBin/Win32/release
            LIBS += -L$$PWD/../myBin/Win32/release -llibcurl_imp
        } else {
            message(" platform win32 release x64")
            DESTDIR =$$PWD/../myBin/X64/release
            LIBS += -L$$PWD/../myBin/X64/release -llibcurl_imp
        }
    } else {
        TARGET = culoptions-d
        contains(QT_ARCH, i386){
            message(" platform win32 debug win32")
            DESTDIR =$$PWD/../myBin/Win32/debug
            LIBS += -L$$PWD/../myBin/Win32/debug -llibcurl-d_imp
        } else {
            message(" platform win32 debug x64")
            DESTDIR =$$PWD/../myBin/X64/debug
            LIBS += -L$$PWD/../myBin/X64/debug -llibcurl-d_imp
            }
        }
    }
}

unix:!macx{
    target.path = /usr/lib
    INSTALLS += target

    if(contains(DEFINES,HISI_ARM)){
        message(" platform linux arm")
        TARGET = culoptions
        DESTDIR =$$PWD/../myBin/tk1
        unix:!macx: LIBS += -L$$PWD/../myBin/tk1/ -lcurl

        INCLUDEPATH += $$PWD/../myBin/tk1
        DEPENDPATH += $$PWD/../myBin/tk1
    }else{
        message(" platform linux x86")
        TARGET = culoptions
        DESTDIR =$$PWD/../myBin/ubuntu
        unix:!macx: LIBS += -L$$PWD/../myBin/ubuntu/ -lcurl

        INCLUDEPATH += $$PWD/../myBin/ubuntu
        DEPENDPATH += $$PWD/../myBin/ubuntu
    }
}