移动fdd1800频点频率换算_梁上移动载荷的瞬态分析

!梁上移动载荷的瞬态分析
finish
/CLEAR
/CONFIG,NRES,2000 !设置子步结果限值
/PREP7
LB=10
NE=50
NN=NE+1 !梁长度为10m,单元个数为50个,节点个数为ne+1个
P=10000
V=72*1E3/3600 !载荷10kn,移动速度v=72km/h换算成m/s
DELTL=LB/NE   
DELTT=DELTL/V !计算单元长度,并且计算移动一个单元所需时间

EM=2.1E11
AREA=0.18 !0.3*0.6=0.18
IM=0.0054 !设置弹性模量,截面面积,惯性矩

DENG=7800
GRA=9.8   !设置密度7800kg/m^3和重力加速度9.8m/s^2等参数
F1=ACOS(-1)/2/LB/LB*SQRT(EM*IM/(AREA*DENG)) !计算自振频率也可以进行模态分析
ET,1,BEAM3  !定义单元为beam3
MP,EX,1,EM  
MP,NUXY,1,0.2 !定义材料性质
MP,DENS,1,DENG
R,1,AREA,IM,1.0 !定义材料密度与实常数

*DO,I,1,NN
N,I,(I-1)*DELTL
*ENDDO !创建节点
*DO,I,1,NE
E,I,(I-1)
*ENDDO !创建单元
D,1,UX,,,,,UY
D,NN,UY
FINISH !定义约束并退出处理

/SOLU
ANTYPE,TRANS
SSTIF,ON !定义为瞬态动力分析,打开预应力效应
TIMINT,OFF !关闭时间积分效应,进行静力分析
ACEL,,GRA !施加加速度
TIME,1E-5,NSUBST,2
KBC,1
SOLVE  !定义时间,载荷步,载荷作用方式,求解

TIMINT,ON !打开时间积分效应,进行瞬态分析
OUTRES,ALL 
DELTIM,DELTT/10!定义输出控制,时间步长
KBC,1
AUTOTS,ON !定义载荷作用方式,并打开自动时间步
*DO,I,1,NN !循环定义移动载荷位置,并求解
TIME,I*DELTT !定义时间点为I*deltt(与速度有关)
FDELE,ALL,ALL
F,I,FY,-P !先删除以前施加的力然后施加当前的力
SOLVE
*ENDDO

FDELE,ALL,ALL !删除所有施加的力,载荷移除
TIME,LB/V+5/F1
SOLVE !时间在增加五个周期,考察梁的自由振动

/POST26
NC=NODE(LB/2,0,0)!进入时程后处理,获得跨中节点号
NSOL,2,NC,U,Y
PLVAR,2 !定义变量,绘制跨中位移时程曲线

特别注意的是，beam3在ansys12.0之后的版本里面已经被整合取缔，
如果想使用的话只能使用apdl也就是命令流，gui里面已经删除了有关老旧单元的操作
或者选择ansys里面的beam188单元，具体详情ansys帮助文档里面有说明，