NOI2001「食物链」

题目描述

动物王国中有三类动物 A,B,C，这三类动物的食物链构成了有趣的环形。A 吃 B，B吃 C，C 吃 A。
现有 N 个动物，以 1 － N 编号。每个动物都是 A,B,C 中的一种，但是我们并不知道它到底是哪一种。
有人用两种说法对这 N 个动物所构成的食物链关系进行描述：
第一种说法是“1 X Y”，表示 X 和 Y 是同类
第二种说法是“2 X Y”，表示 X 吃 Y 。
此人对 N 个动物，用上述两种说法，一句接一句地说出 K 句话，这 K 句话有的是真的，有的是假的。当一句话满足下列三条之一时，这句话就是假话，否则就是真话。
• 当前的话与前面的某些真的话冲突，就是假话
• 当前的话中 X 或 Y 比 N 大，就是假话
• 当前的话表示 X 吃 X，就是假话
你的任务是根据给定的 N 和 K 句话，输出假话的总数。

输入格式

第一行两个整数，N，K，表示有 N 个动物，K 句话。
第二行开始每行一句话（按照题目要求，见样例）

输出格式

一行，一个整数，表示假话的总数。

输入样例

100 7
1 101 1
2 1 2
2 2 3
2 3 3
1 1 3
2 3 1
1 5 5

输出样例

3

说明

1 ≤ N ≤ 5 ∗ 10^4
1 ≤ K ≤ 10^5

思路
切做过的水题以建立自信的我是个鉴（确信）
Q: 看起来似乎与正常的并查集不一样？
A: 因为状态多了。
这道题可以用三个带权并查集解决
设状态 A,B,C 表示同类，捕食，和被捕食关系
这样不用三个并查集也能解决啦 QwQ
Code:

Var n,k,i,d,x,y,t:longint;
    fa,rel:array[1..50005] of longint;

function get_fa(m:longint):longint;
Var mid:longint;
Begin
        if fa[m]=m then exit(m)
        else
        Begin
                mid:=fa[m];
                fa[m]:=get_fa(fa[m]);
                rel[m]:=rel[m]+rel[mid];
                rel[m]:=rel[m] mod 3;
                exit(fa[m]);
        end;
end;

function mesh(a,b,d:longint):boolean;
Begin
        a:=get_fa(a);b:=get_fa(b);
        if a=b then
        Begin
                if d<>((3-rel[x]+rel[y]) mod 3) then
                Begin
                        exit(false);
                end
                else
                Begin
                        exit(true);
                end;
        end;
        fa[b]:=a;
        rel[b]:=(rel[x]+d+3-rel[y]) mod 3;
        exit(true);
end;

Begin
        readln(n,k);
        for i:=1 to n do
        Begin
                fa[i]:=i;
        end;
        
        for i:=1 to k do
        Begin
                readln(d,x,y);
                if (x>n) or (y>n) then inc(t)
                else if (d=2) and (x=y) then inc(t)
                else if not(mesh(x,y,d-1)) then inc(t);
        end;
        
        write(t);
end.