交互式RDP服务启停及修改端口的bat脚本

1、执行效果

2、脚本代码

@echo off
chcp 65001

REM 检查是否有管理员权限
net session >nul 2>&1
if %errorlevel% neq 0 (
    echo 请右键【以管理员身份运行】此脚本。
    pause
    exit /b
)

REM 提示是否开启或关闭RDP服务
set /p enable_disable=是否开启或关闭RDP远程桌面服务？（1关闭，0开启）：

REM 如果用户选择关闭RDP服务
if "%enable_disable%"=="1" (
    echo 正在关闭RDP远程桌面服务
    reg add "HKLM\SYSTEM\CurrentControlSet\Control\Terminal Server" /v fDenyTSConnections /t REG_DWORD /d 1 /f
    echo RDP远程桌面服务已关闭
    exit /b
)

REM 如果用户选择开启RDP服务
if "%enable_disable%"=="0" (
    echo 正在开启RDP远程桌面服务
    reg add "HKLM\SYSTEM\CurrentControlSet\Control\Terminal Server" /v fDenyTSConnections /t REG_DWORD /d 0 /f
    echo RDP远程桌面服务已开启
)

REM 提示用户选择RDP端口
set /p new_port=请输入新的RDP服务端口（默认3389）：

REM 修改注册表中的RDP端口号
reg add "HKLM\SYSTEM\CurrentControlSet\Control\Terminal Server\Wds\rdpwd\Tds\tcp" /v PortNumber /t REG_DWORD /d %new_port% /f
reg add "HKLM\SYSTEM\CurrentControlSet\Control\Terminal Server\WinStations\RDP-Tcp" /v PortNumber /t REG_DWORD /d %new_port% /f


REM 重启远程桌面服务
echo 即将重启RDP远程桌面服务，输入Y执行
net stop termservice
net start termservice

echo RDP端口已成功修改为 %new_port%

netstat -ano |findstr 0.0.0.0:%new_port%

pause

3、使用方式

新建txt文件，复制并粘贴代码，保存后修改文件后缀为.bat，然后右键管理员执行即可。