部分代码理解
//下面是s3c2440部分汇编代码
.text/*.text是对应的代码段,一个汇编语言的开始一定有代码段*/
.global _start/*.global是定义一个全局函数_start,start也是代码段函数的缺省入口,汇编语言从start开始执行*/
_start:
b reset /* vector 0 : reset */
ldr pc, und_addr /* vector 4 : und */
ldr pc, swi_addr /* vector 8 : swi *//*
整个汇编程序的入口是start,先跳转到reset处执行程序,ldr pc, und_addr是未定义中断,在执行reset过程中出现的未定义和软中断。如果在执行reset过程中出现了未定义中断和swi中断则跳转到und_addr地址或者swi_addr地址执行中断。*/
und_addr:/*未定义中断函数,gnu汇编函数的格式 “函数名:”*/
.word do_und/*.Word插入一个32位的数据队列,用.Word把标识符作为常量使用*/
do_und:/*未定义指令的程序*/
/* 执行到这里之前:
* 1. lr_und保存有被中断模式中的下一条即将执行的指令的地址
* 2. SPSR_und保存有被中断模式的CPSR
* 3. CPSR中的M4-M0被设置为11011, 进入到und模式
* 4. 跳到0x4的地方执行程序
*/
/* sp_und未设置, 先设置它 */
ldr sp, =0x34000000/*设置stack point
堆栈指针起始地址0x34000000*/
/* 在und异常处理函数中有可能会修改r0-r12, 所以先保存 */
/* lr是异常处理完后的返回地址, 也要保存 */
stmdb sp!, {r0-r12, lr} /*STore Multiple data stmdb先减后存,
递减入栈参数的顺序是从右向左,lr r12 r11 等。因为sp!,最后的递减完后的栈指针存储在sp。保存现场*/
/* 保存现场 */
/* 处理und异常 */
mrs r0, cpsr
ldr r1, =und_string/*这时的作用是伪指令,执行und_string*/
bl printException
/* 恢复现场 */
ldmia sp!, {r0-r12, pc}^ /* ^会把spsr的值恢复到cpsr里
恢复现场,先出后增。参数的顺序是从左到右。*/
und_string:
.string "undefined instruction exception"
swi_addr:/*同上*/
.word do_swi
do_swi:
/* 执行到这里之前:
* 1. lr_swi保存有被中断模式中的下一条即将执行的指令的地址
* 2. SPSR_swi保存有被中断模式的CPSR
* 3. CPSR中的M4-M0被设置为10011, 进入到und模式
* 4. 跳到0x8的地方执行程序
*/
/* sp_und未设置, 先设置它 */
ldr sp, =0x33e000000
/* 在und异常处理函数中有可能会修改r0-r12, 所以先保存 */
/* lr是异常处理完后的返回地址, 也要保存 */
stmdb sp!, {r0-r12, lr}
/* 保存现场 */
/* 处理und异常 */
mrs r0, cpsr
ldr r1, =swi_string
bl printException
/* 恢复现场 */
ldmia sp!, {r0-r12, pc}^ /* ^会把spsr的值恢复到cpsr里 */
swi_string:
.string "undefined instruction exception"
.align 4 /*四字节对齐*/
reset:
/* 关闭看门狗 */
ldr r0, =0x53000000
ldr r1, =0
str r1, [r0]
/* 设置MPLL, FCLK : HCLK : PCLK = 400m : 100m : 50m */
/* LOCKTIME(0x4C000000) = 0xFFFFFFFF */
ldr r0, =0x4C000000
ldr r1, =0xFFFFFFFF
str r1, [r0]
/* CLKDIVN(0x4C000014) = 0X5, tFCLK:tHCLK:tPCLK = 1:4:8 */
ldr r0, =0x4C000014
ldr r1, =0x5
str r1, [r0]
/* 设置CPU工作于异步模式 */
mrc p15,0,r0,c1,c0,0
orr r0,r0,#0xc0000000 //R1_nF:OR:R1_iA
mcr p15,0,r0,c1,c0,0
/* 设置MPLLCON(0x4C000004) = (92<<12)|(1<<4)|(1<<0)
* m = MDIV+8 = 92+8=100
* p = PDIV+2 = 1+2 = 3
* s = SDIV = 1
* FCLK = 2*m*Fin/(p*2^s) = 2*100*12/(3*2^1)=400M
*/
ldr r0, =0x4C000004
ldr r1, =(92<<12)|(1<<4)|(1<<0)
str r1, [r0]
/* 一旦设置PLL, 就会锁定lock time直到PLL输出稳定
* 然后CPU工作于新的频率FCLK
*/
/* 设置内存: sp 栈 */
/* 分辨是nor/nand启动
* 写0到0地址, 再读出来
* 如果得到0, 表示0地址上的内容被修改了, 它对应ram, 这就是nand启动
* 否则就是nor启动
*/
mov r1, #0
ldr r0, [r1] /* 读出原来的值备份 */
str r1, [r1] /* 0->[0] */
ldr r2, [r1] /* r2=[0] */
cmp r1, r2 /* r1==r2? 如果相等表示是NAND启动 */
ldr sp, =0x40000000+4096 /* 先假设是nor启动 */
moveq sp, #4096 /* nand启动 */
streq r0, [r1] /* 恢复原来的值 */
bl sdram_init/*跳转到sdram执行,并且把子程序的返回地址保存在lr
寄存器中*/
//bl sdram_init2 /* 用到有初始值的数组, 不是位置无关码 */
/* 重定位text, rodata, data段整个程序 */
bl copy2sdram
/* 清除BSS段 */
bl clean_bss
/* 复位以后CPU处于svc模式
现在切换到usr模式*/
msr r0,cpsr
bic r0,r0, #0xf
msr cpsr,r0
/*设置sp_usr*/
ldr sp, =0x33f00000
ldr pc, =sdram
sdram:
bl uart0_init
bl print1
/* 故意加入一条未定义指令 */
und_code:
.word 0xdeadc0de /* 未定义指令 */
bl print2
swi 0x123 /*出发swi异常会进入0x8执行*/
//bl main /* 使用BL命令相对跳转, 程序仍然在NOR/sram执行 */
ldr pc, =main /* 绝对跳转, 跳到SDRAM */
halt:
b halt