如何用尽可能少的字节编写一个C64可执行文件？本文的作者通过一个竞赛，详细解读了最佳实践技巧，快来Get吧！
作者 | Janne Hellsten
译者 | 弯月，责编 | 郭芮
出品 | CSDN(ID：CSDNnews)
以下为译文： 这篇文章回顾了我主持Commodore 64编程竞赛时，人们使用的C64编程技巧。竞赛的规则很简单：编写一个C64可执行文件(PRG文件)，画出两条线，组成下面的图形——目标是用尽可能少的字节。
基本知识
C64默认的图形模式为40x25字符模式。RAM中的帧缓冲区分为两个阵列：
$0400(屏幕RAM，40x25字节)
$d800(颜色RAM，40x25字节)
#include
#include
#include
void dump(const uint8_t* screen) {
const uint8_t* s = screen;
for (int y = 0; y 25; y++) {
for (int x = 0; x 40; x++, s++) {
printf("%c", *s == 0xa0 ? '#' : '.');
}
printf("\n");
}
}
void setreg(uintptr_t dst, uint8_t v) {
// *((uint8_t *)dst) = v;
}
int main() {
// uint8_t* screenRAM = (uint_8*)0x0400;
uint8_t* screenRAM = (uint8_t *)calloc(40*25, 0x20);
setreg(0xd020, 0); // Set border color
setreg(0xd021, 0); // Set background color
int yslope = (25<<8)/40;
int yf = yslope/2;
for (int x = 0; x 40; x++) {
int yi = yf >> 8;
// First line
screenRAM[x + yi*40] = 0xa0;
// Second line (X-mirrored)
screenRAM[(39-x) + yi*40] = 0xa0;
yf += yslope;
}
dump(screenRAM);
}
上述画图时使用的字符分别为$20(空白)和$a0(8x8填充方块)。运行后应该能看到下面由两条线组成的ASCII图形：
##....................................##
..#..................................#..
...##..............................##...
.....#............................#.....
......##........................##......
........##....................##........
..........#..................#..........
...........##..............##...........
.............#............#.............
..............##........##..............
................##....##................
..................#..#..................
...................##...................
..................#..#..................
................##....##................
..............##........##..............
.............#............#.............
...........##..............##...........
..........#..................#..........
........##....................##........
......##........................##......
.....#............................#.....
...##..............................##...
..#..................................#..
##....................................##!include "c64.asm"
+c64::basic_start(entry)
entry: {
lda #0 ; black color
sta $d020 ; set border to 0
sta $d021 ; set background to 0
; clear the screen
ldx #0
lda #$20
clrscr:
!for i in [0, $100, $200, $300] {
sta $0400 + i, x
}
inx
bne clrscr
; line drawing, completely unrolled
; with assembly pseudos
lda #$a0
!for i in range(40) {
!let y0 = Math.floor(25/40*(i+0.5))
sta $0400 + y0*40 + i
sta $0400 + (24-y0)*40 + i
}
inf: jmp inf ; halt
} int yslope = (25<<8)/40;int yf = yslope/2;uint8_t* dst = screenRAM;for (int x = 0; x 40; x++) {dst[x] = 0xa0;dst[(39-x)] = 0xa0;yf += yslope;if (yf & 256) { // Carry set?dst += 40;yf &= 255;
}
}!include "c64.asm"
+c64::basic_start(entry)
!let screenptr = $20
!let x0 = $40
!let x1 = $41
!let yf = $60
entry: {
lda #0
sta x0
sta $d020
sta $d021
; kernal clear screen
jsr $e544
; set screenptr = $0400
lda #
sta screenptr+0
lda #>$0400
sta screenptr+1
lda #80
sta yf
lda #39
sta x1
xloop:
lda #$a0
ldy x0
; screenRAM[x] = 0xA0
sta (screenptr), y
ldy x1
; screenRAM[39-x] = 0xA0
sta (screenptr), y
clc
lda #160 ; line slope
adc yf
sta yf
bcc no_add
; advance screen ptr by 40
clc
lda screenptr
adc #40
sta screenptr
lda screenptr+1
adc #0
sta screenptr+1
no_add:
inc x0
dec x1
bpl xloop
inf: jmp inf
} ; set screenptr = $0400
lda #
sta screenptr+0
lda #>$0400
sta screenptr+1给screenptr加40，以前进到下一行：
; advance screen ptr by 40
clc
lda screenptr
adc #40
sta screenptr
lda screenptr+1
adc #0
sta screenptr+1当然，这段代码也可以再小一些，但要是能一开始就不使用16位寻址该多好？我们来看看能否避免16位寻址。
lda #0
sta x0
lda #39
sta x1
xloop:
lda #$a0
ldx x0
; hardcoded absolute address to last screen line
sta $0400 + 24*40, x
ldx x1
sta $0400 + 24*40, x
adc yf
sta yf
bcc no_scroll
; scroll screen up!
jsr $e8ea
no_scroll:
inc x0
dec x1
bpl xloop使用这个技巧后，线的渲染过程如下：
技巧2：自行修改的代码
设置像素值的代码大致如下：
ldx x1
; hardcoded absolute address to last screen line
sta $0400 + 24*40, x
ldx x0
sta $0400 + 24*40, x
inc x0
dec x1
编码后为14字节的序列：
0803: A6 22 LDX $22
0805: 9D C0 07 STA $07C0,X
0808: A6 20 LDX $20
080A: 9D C0 07 STA $07C0,X
080D: E6 22 INC $22
080F: C6 20 DEC $20实际上还可以使用自行修改的代码(self-modifying code，SMC)写得更简洁：
ldx x1
sta $0400 + 24*40, x
addr0: sta $0400 + 24*40
; advance the second x-coord with SMC
inc addr0+1
dec x10803: A6 22 LDX $22
0805: 9D C0 07 STA $07C0,X
0808: 8D C0 07 STA $07C0
080B: EE 09 08 INC $0809
080E: C6 22 DEC $22
技巧3：使用加电状态
这次比赛中允许对环境做出大胆的假设：画线的PRG是C64加电后运行的第一个程序，退出之后也不需要干净地回到BASIC提示符下。所以任何PRG启动后的初始环境中的东西都可以使用。下面是一些PRG启动时“不变”的东西：
A，X，Y寄存器可以假设都为零；
所有CPU标志位均为清除状态；
零页(地址为$00-$ff)内容。
$d5：39/$27 == 线长度 - 1
$22: 64/$40 == 线斜率计数器的初始值
!let x0 = $20
lda #39 ; 0801: A9 27 LDA #$27
sta x0 ; 0803: 85 20 STA $20
xloop:
dec x0 ; 0805: C6 20 DEC $20
bpl xloop ; 0807: 10 FC BPL $0805
由于$d5包含值39，所以你可以将x0计数器指向$d5，这样可以跳过LDA/STA这两条指令：
!let x0 = $d5
; nothing here!
xloop:
dec x0 ; 0801: C6 D5 DEC $D5
bpl xloop ; 0803: 10 FC BPL $0801Philip的优胜作品把这个技巧发挥到了极致。回忆一下最后一个字符行的地址是$07C0(==$0400+24*40)。在初始化时，这个值不在零页中。但是，ROM的“向上卷轴”例程会临时使用零页，其副作用就是函数返回时，$D1-$d2会包含$07C0。所以，设置一个像素不需要做STA $07C0, x，而是可以用间接索引寻址模式STA ($D1), y，可以节省一个字节。
开头2字节：加载地址(通常为$0801)
12字节的BASIC起始序列
0801: 0B 08 0A 00 9E 32 30 36 31 00 00 00
080D: 8D 20 D0 STA $D020
这里不会深入介绍令牌BASIC内存布局(https://www.c64-wiki.com/wiki/BASIC_token)，只需知道这个序列大致相当于“10 SYS 2061”即可。地址2061($080D)是BASIC解释器执行SYS命令时，实际的机器码程序开始运行的地方。
这14字节似乎毫无用处。Philip、Mathlev和Geir用了一些非常巧妙的技巧去掉了BASIC序列。这个技巧要求使用LOAD "*",8,1来加载PRG，因为LOAD "*",8会忽略PRG加载地址(开头两字节)，永远加载到$0801。
栈技巧；
BASIC热重置向量技巧。
* = $01F8
!word scroll - 1 ; overwrite stack
scroll: jsr $E8EA02E6: 20 EA E8 JSR $E8EA
02E9: A4 D5 LDY $D5
02EB: A9 A0 LDA #$A0
02ED: 99 20 D0 STA $D020,Y
02F0: 91 D1 STA ($D1),Y
02F2: 9D B5 07 STA $07B5,X
02F5: E6 D6 INC $D6
02F7: 65 90 ADC $90
02F9: 85 90 STA $90
02FB: C6 D5 DEC $D5
02FD: 30 FE BMI $02FD
02FF: 90 E7 BCC $02E8
0301: 4C E6 02 JMP $02E6注意最后一行(JMP $02E6)。JMP指令从地址$0301开始，跳转目标地址存储在地址$0302-$0303。
当这行代码加载到地址$02E6开始的内存之后，值$02E6被写入地址$0302-$0303。实际上$0302-$0303有特殊含义：它包含指向“BASIC闲置循环”的指针(参见C64内存映射：http://sta.c64.org/cbm64mem.html)。加载PRG会使用$02E6覆盖改地址，所以当BASIC解释器在热重置后试图跳转到闲置循环时，它不会进入闲置循环，而是会进入直线渲染程序！ 其他与BASIC启动有关的技巧 Petri发现了另一个BASIC启动技巧(https://github.com/petrihakkinen/c64-lines/blob/master/main37.asm)可以将自己的常量注入到零页中。在这个方法中，你需要手工编写令牌BASIC启动序列，然后将自己的常量写入BASIC程序的行号中。BASIC行号(即你的常量)会在启动时存储至地址$39-$3A。非常聪明！
技巧5：非常规控制流
下面是个简化版本的x循环，它只画一条线，画完一条线后会停止执行：
lda #39
sta x1
xloop:
lda #$a0
ldx x1
sta $0400 + 24*40, x
adc yf
sta yf
bcc no_scroll
; scroll screen up!
jsr $e8ea
no_scroll:
dec x1
bpl xloop
; intentionally halt at the end
inf: jmp inf
但这段代码有个bug。在画线上的最后一个像素时，不应该再卷轴。因此我们需要在画最后一个像素时编写更多的分支来跳过卷轴：
lda #39
sta x1
xloop:
lda #$a0
ldx x1
sta $0400 + 24*40, x
dec x1
; skip scrolling if last pixel
bmi done
adc yf
sta yf
bcc no_scroll
; scroll screen up!
jsr $e8ea
no_scroll:
jmp xloop
done:
; intentionally halt at the end
inf: jmp inf
这里的控制流看起来很像C编译器编译结构化程序的结果。为了跳过最后一次卷轴，这段代码使用了新的JMP abs指令，占用了3个字节。条件分支只有两个字节，因为它们使用8位相对立即数来表示分支目标。
这个“跳过最后一次卷轴”的JMP指令实际上可以避免，只需将卷轴调用移动到循环的开头，然后稍稍改一下控制流的结构。Philip想出的办法如下： lda #39
sta x1
scroll: jsr $e8ea
xloop:
lda #$a0
ldx x1
sta $0400 + 24*40, x
adc yf
sta yf
dec x1 ; doesn't set carry!
inf: bmi inf ; hang here if last pixel!
bcc xloop ; next pixel if no scroll
bcs scroll ; scroll up and continue
这段代码完全省却了3字节的JMP，还将另一个JMP改成了2字节的条件分支，总共节省了4字节。
int mask = 0xB6; // 10110110
uint8_t* dst = screenRAM;
for (int x = 0; x 40; x++) {
dst[x] = 0xA0;
if (mask & (1 <7))) {
dst += 40; // go down a row
}
}
其汇编代码非常简短。不过，修改后的斜率计数器更精简一些。
ov = $22 ; == $40, initial value for the overflow counter
ct = $D5 ; == $27 / 39, number of passes. Decrementing, finished at -1
lp = $D1 ; == $07C0, pointer to bottom line. Set by the kernal scroller
; Overwrite the return address of the kernal loader on the stack
; with a pointer to our own code
* = $01F8
.word scroll - 1
scroll: jsr $E8EA ; Kernal scroll up, also sets lp pointer to $07C0
loop: ldy ct ; Load the decrementing counter into Y (39 > -1)
lda #$A0 ; Load the PETSCII block / black col / ov step value
sta $D020, y ; On the last two passes, sets the background black
p1: sta $07C0 ; Draw first block (left > right line)
sta (lp), y ; Draw second block (right > left line)
inc p1 + 1 ; Increment pointer for the left > right line
adc ov ; Add step value $A0 to ov
sta ov
dec ct ; Decrement the Y counter
bmi * ; If it goes negative, we're finished
bcc loop ; Repeat. If ov didn't overflow, don't scroll
bcs scroll ; Repeat. If ov overflowed, scroll
但为什么停在了34字节？
比赛结束后，每个人都分享了代码和心得，大家还就如何改进进行了许多讨论。在截止期限之后还出现了一些更小的版本： ●Philip - 33 字节：https://gist.github.com/fsphil/05deaa06804b9b2054260b616cafed4b ●Philip - 32 字节：https://gist.github.com/fsphil/01bda1a9dd58c219002ddd6e18b36c3f ●Petri - 31 字节：https://github.com/petrihakkinen/c64-lines/blob/master/main31.asm ●Philip - 29 字节：https://gist.github.com/fsphil/7655a394ec5f953c910e9d9369dced56 你应该读读这些代码——其中有些非常好的东西。 原文： https://nurpax.github.io/posts/2019-08-18-dirty-tricks-6502-programmers-use.html 本文为CSDN翻译，转载请注明来源出处。【END】
热 文 推 荐
☞三大运营商回复 4G 降速；微信上线语音转文字功能；IntelliJ IDEA 2019.2.1 发布 | 极客头条
☞程序员为什么需要框架?
☞ 细数微软 Teams 的 14 宗“罪”！
☞ 华为暂没有推出鸿蒙手机计划；苹果否认 iPhone 辐射超标；Kotlin 1.3.50 发布 | 极客头条
☞ 我是如何通过开源项目月入 10 万的？
☞ 深度 | 语音识别技术简史：从不温不火到炙手可热 ☞ 意大利黑手党四大家族做了条"犯罪链", 把家族的权利被分的明明白白的…… ☞ Istio 庖丁解牛六：多集群网格应用场景 ☞ 如何写出让同事无法维护的代码？
你点的每个“在看”，我都认真当成了喜欢
扫一扫
1359
被折叠的 条评论
为什么被折叠?
到【灌水乐园】发言
