VHD Script
Create
@echo off
set VHD_File=E:\Temp\test.vhd
set VHD_Label=Temp
set VHD_Size=100
REM size = ?m
set VHD_Type=expandable
REM type = fixed | expandable
REM ================
if exist "%VHD_File%" exit
set VHD_Script=%Temp%\VHD_Script%Random%
REM ■■■■■■■■■■■■■■■■ ■■■■■■■■■■■■■■■■
echo [create]
echo create vdisk file="%VHD_File%" maximum=%VHD_Size% type=%VHD_Type% > "%VHD_Script%"
echo select vdisk file="%VHD_File%" >> "%VHD_Script%"
echo attach vdisk >> "%VHD_Script%"
echo create partition primary >> "%VHD_Script%"
echo active >> "%VHD_Script%"
echo format fs=ntfs quick label="%VHD_Label%" >> "%VHD_Script%"
echo detach vdisk >> "%VHD_Script%"
call diskpart /s "%VHD_Script%"
del "%VHD_Script%"
REM ■■■■■■■■■■■■■■■■ ■■■■■■■■■■■■■■■■
Attach & Mount
@echo off
set VHD_File=E:\Temp\test.vhd
set VHD_Path=I:
REM ================
if not exist "%VHD_File%" exit
set VHD_Script=%Temp%\VHD_Script%Random%
REM ■■■■■■■■■■■■■■■■ ■■■■■■■■■■■■■■■■
echo [attach]
echo select vdisk file="%VHD_File%" >"%VHD_Script%"
echo attach vdisk >>"%VHD_Script%"
call diskpart /s "%VHD_Script%"
del "%VHD_Script%"
REM ■■■■■■■■■■■■■■■■ ■■■■■■■■■■■■■■■■
ping -n 2 127.0.0.1>nul
REM ■■■■■■■■■■■■■■■■ ■■■■■■■■■■■■■■■■
echo [mount]
echo select vdisk file="%VHD_File%" >"%VHD_Script%"
echo select partition=1 >>"%VHD_Script%"
echo assign mount="%VHD_Path%" >>"%VHD_Script%"
call diskpart /s "%VHD_Script%"
del "%VHD_Script%"
REM ■■■■■■■■■■■■■■■■ ■■■■■■■■■■■■■■■■
Remove & Detach
@echo off
set VHD_File=E:\Temp\test.vhd
REM ================
if not exist "%VHD_File%" exit
set VHD_Script=%Temp%\VHD_Script%Random%
REM ■■■■■■■■■■■■■■■■ ■■■■■■■■■■■■■■■■
echo [remove]
echo select vdisk file="%VHD_File%" >"%VHD_Script%"
echo select partition=1 >>"%VHD_Script%"
echo remove >>"%VHD_Script%"
call diskpart /s "%VHD_Script%"
del "%VHD_Script%"
REM ■■■■■■■■■■■■■■■■ ■■■■■■■■■■■■■■■■
ping -n 2 127.0.0.1>nul
REM ■■■■■■■■■■■■■■■■ ■■■■■■■■■■■■■■■■
echo [detach]
echo select vdisk file="%VHD_File%" >"%VHD_Script%"
echo detach vdisk >>"%VHD_Script%"
call diskpart /s "%VHD_Script%"
del "%VHD_Script%"
REM ■■■■■■■■■■■■■■■■ ■■■■■■■■■■■■■■■■
Remount
@echo off
set VHD_File=E:\Temp\test.vhd
set VHD_Path=H:
REM ================
if not exist "%VHD_File%" exit
set VHD_Script=%Temp%\VHD_Script%Random%
REM ■■■■■■■■■■■■■■■■ ■■■■■■■■■■■■■■■■
echo [attach]
echo select vdisk file="%VHD_File%" >"%VHD_Script%"
echo attach vdisk >>"%VHD_Script%"
call diskpart /s "%VHD_Script%"
del "%VHD_Script%"
REM ■■■■■■■■■■■■■■■■ ■■■■■■■■■■■■■■■■
ping -n 2 127.0.0.1>nul
REM ■■■■■■■■■■■■■■■■ ■■■■■■■■■■■■■■■■
echo [remove]
echo select vdisk file="%VHD_File%" >"%VHD_Script%"
echo select partition=1 >>"%VHD_Script%"
echo remove >>"%VHD_Script%"
call diskpart /s "%VHD_Script%"
del "%VHD_Script%"
REM ■■■■■■■■■■■■■■■■ ■■■■■■■■■■■■■■■■
ping -n 2 127.0.0.1>nul
REM ■■■■■■■■■■■■■■■■ ■■■■■■■■■■■■■■■■
echo [mount]
echo select vdisk file="%VHD_File%" >"%VHD_Script%"
echo select partition=1 >>"%VHD_Script%"
echo assign mount="%VHD_Path%" >>"%VHD_Script%"
call diskpart /s "%VHD_Script%"
del "%VHD_Script%"
REM ■■■■■■■■■■■■■■■■ ■■■■■■■■■■■■■■■■