进入保护模式

已于 2023-01-06 21:39:51 修改
阅读量877 收藏
点赞数
分类专栏： 操作系统 # 操作系统真象还原 文章标签： java linux 开发语言
于 2023-01-06 21:34:45 首次发布
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/weixin_42888638/article/details/128581501
版权

文章目录

前言

本博客记录《操作系统真象还原》第四章实验操作~

实验环境：ubuntu18.04+VMware ， Bochs下载安装

实验内容：实现从MBR到LOADER，由LOADER实现进入保护模式

实验原理：计算机通电开机后，CPU的cs:ip寄存器,被硬件强制初始化为0xF000:0XFFF0 ，该位置存储着跳转指令，跳转向BIOS。这样首先运行BIOS软件（计算机系统的控制权 [CPU的使用权] 交接的第一棒就是BIOS啦！），BIOS会检查各种设备的情况，并且建立中断向量表。然后MBR找机会想把处理器使用权交出去。下一个接棒选手就是 主引导记录（MBR，Master Boot Record），BIOS知道MBR在0盘0道1扇区，因此它会将0盘0道1扇区中的MBR引导程序加载到物理地址0x7c00，然后继而跳去执行。这样BIOS就将处理器的使用权交给MBR。紧接着，MBR的接力棒就来到了Loader，Loader构建并且初始化GDT，然后用LGDT指令把GDT表的位置放了进去，并且初始化了三个段描述符(段描述符 代码段 数据段) 。从此，从16位实模式到了32位保护模式。

前置知识

前置知识可以食用 全局描述符表

代码说明

include/boot.inc

更新boot.inc文件：关于加载器的配置信息

;-------------	 loader和kernel   ----------

LOADER_BASE_ADDR equ 0x900 
LOADER_START_SECTOR equ 0x2

;--------------   gdt描述符属性  -------------
DESC_G_4K   equ	  1_00000000000000000000000b    ;描述符中G的位次，其中结尾的b表示2机制。
DESC_D_32   equ	   1_0000000000000000000000b
DESC_L	    equ	    0_000000000000000000000b	;  64位代码标记，此处标记为0便可。
DESC_AVL    equ	     0_00000000000000000000b	;  cpu不用此位，暂置为0  
DESC_LIMIT_CODE2  equ 1111_0000000000000000b
DESC_LIMIT_DATA2  equ DESC_LIMIT_CODE2
DESC_LIMIT_VIDEO2  equ 0000_000000000000000b
DESC_P	    equ		  1_000000000000000b
DESC_DPL_0  equ		   00_0000000000000b
DESC_DPL_1  equ		   01_0000000000000b
DESC_DPL_2  equ		   10_0000000000000b
DESC_DPL_3  equ		   11_0000000000000b
DESC_S_CODE equ		     1_000000000000b
DESC_S_DATA equ	  DESC_S_CODE
DESC_S_sys  equ		     0_000000000000b
DESC_TYPE_CODE  equ	      1000_00000000b	;x=1,c=0,r=0,a=0 代码段是可执行的,非依从的,不可读的,已访问位a清0.  
DESC_TYPE_DATA  equ	      0010_00000000b	;x=0,e=0,w=1,a=0 数据段是不可执行的,向上扩展的,可写的,已访问位a清0.

DESC_CODE_HIGH4 equ (0x00 << 24) + DESC_G_4K + DESC_D_32 + DESC_L + DESC_AVL + DESC_LIMIT_CODE2 + DESC_P + DESC_DPL_0 + DESC_S_CODE + DESC_TYPE_CODE + 0x00
DESC_DATA_HIGH4 equ (0x00 << 24) + DESC_G_4K + DESC_D_32 + DESC_L + DESC_AVL + DESC_LIMIT_DATA2 + DESC_P + DESC_DPL_0 + DESC_S_DATA + DESC_TYPE_DATA + 0x00
DESC_VIDEO_HIGH4 equ (0x00 << 24) + DESC_G_4K + DESC_D_32 + DESC_L + DESC_AVL + DESC_LIMIT_VIDEO2 + DESC_P + DESC_DPL_0 + DESC_S_DATA + DESC_TYPE_DATA + 0x0b

;--------------   选择子属性  ---------------
RPL0  equ   00b
RPL1  equ   01b
RPL2  equ   10b
RPL3  equ   11b
TI_GDT	 equ   000b
TI_LDT	 equ   100b

代码说明

第 6 ~ 27 行是定义段描述符的属性。

第 29 ~ 35 行是定义选择子属性。

loader.S

   %include "boot.inc"
   section loader vstart=LOADER_BASE_ADDR
   LOADER_STACK_TOP equ LOADER_BASE_ADDR
   jmp loader_start					; 此处的物理地址是:
   
;构建gdt及其内部的描述符
   GDT_BASE:   dd    0x00000000 
	       dd    0x00000000

   CODE_DESC:  dd    0x0000FFFF 
	       dd    DESC_CODE_HIGH4

   DATA_STACK_DESC:  dd    0x0000FFFF
		     dd    DESC_DATA_HIGH4

   VIDEO_DESC: dd    0x80000007	       ;limit=(0xbffff-0xb8000)/4k=0x7
	       dd    DESC_VIDEO_HIGH4  ; 此时dpl已改为0

   GDT_SIZE   equ   $ - GDT_BASE
   GDT_LIMIT   equ   GDT_SIZE -	1 
   times 60 dq 0					 ; 此处预留60个描述符的slot
   SELECTOR_CODE equ (0x0001<<3) + TI_GDT + RPL0         ; 相当于(CODE_DESC - GDT_BASE)/8 + TI_GDT + RPL0
   SELECTOR_DATA equ (0x0002<<3) + TI_GDT + RPL0	 ; 同上
   SELECTOR_VIDEO equ (0x0003<<3) + TI_GDT + RPL0	 ; 同上 

   ;以下是定义gdt的指针，前2字节是gdt界限，后4字节是gdt起始地址

   gdt_ptr  dw  GDT_LIMIT 
	    dd  GDT_BASE
   loadermsg db '2 loader in real.'

   loader_start:

;打印字符，"2 LOADER"说明loader已经成功加载
; 输出背景色绿色，前景色红色，并且跳动的字符串"1 MBR"
mov byte [gs:160],'2'
mov byte [gs:161],0xA4     ; A表示绿色背景闪烁，4表示前景色为红色

mov byte [gs:162],' '
mov byte [gs:163],0xA4

mov byte [gs:164],'L'
mov byte [gs:165],0xA4   

mov byte [gs:166],'O'
mov byte [gs:167],0xA4

mov byte [gs:168],'A'
mov byte [gs:169],0xA4

mov byte [gs:170],'D'
mov byte [gs:171],0xA4

mov byte [gs:172],'E'
mov byte [gs:173],0xA4

mov byte [gs:174],'R'
mov byte [gs:175],0xA4




;------------------------------------------------------------
;INT 0x10    功能号:0x13    功能描述:打印字符串
;------------------------------------------------------------
;输入:
;AH 子功能号=13H
;BH = 页码
;BL = 属性(若AL=00H或01H)
;CX＝字符串长度
;(DH、DL)＝坐标(行、列)
;ES:BP＝字符串地址 
;AL＝显示输出方式
;   0——字符串中只含显示字符，其显示属性在BL中。显示后，光标位置不变
;   1——字符串中只含显示字符，其显示属性在BL中。显示后，光标位置改变
;   2——字符串中含显示字符和显示属性。显示后，光标位置不变
;   3——字符串中含显示字符和显示属性。显示后，光标位置改变
;无返回值
   mov	 sp, LOADER_BASE_ADDR
   mov	 bp, loadermsg           ; ES:BP = 字符串地址
   mov	 cx, 17			 ; CX = 字符串长度
   mov	 ax, 0x1301		 ; AH = 13,  AL = 01h
   mov	 bx, 0x001f		 ; 页号为0(BH = 0) 蓝底粉红字(BL = 1fh)
   mov	 dx, 0x1800		 ;
   int	 0x10                    ; 10h 号中断

;----------------------------------------   准备进入保护模式   ------------------------------------------
									;1 打开A20
									;2 加载gdt
									;3 将cr0的pe位置1


   ;-----------------  打开A20  ----------------
   in al,0x92
   or al,0000_0010B
   out 0x92,al

   ;-----------------  加载GDT  ----------------
   lgdt [gdt_ptr]


   ;-----------------  cr0第0位置1  ----------------
   mov eax, cr0
   or eax, 0x00000001
   mov cr0, eax

   ;jmp dword SELECTOR_CODE:p_mode_start	     ; 刷新流水线，避免分支预测的影响,这种cpu优化策略，最怕jmp跳转，
   jmp  SELECTOR_CODE:p_mode_start	     ; 刷新流水线，避免分支预测的影响,这种cpu优化策略，最怕jmp跳转，
					     ; 这将导致之前做的预测失效，从而起到了刷新的作用。

[bits 32]
p_mode_start:
   mov ax, SELECTOR_DATA
   mov ds, ax
   mov es, ax
   mov ss, ax
   mov esp,LOADER_STACK_TOP
   mov ax, SELECTOR_VIDEO
   mov gs, ax

   mov byte [gs:320], 'P'

   jmp $

【这部分详细解读请看原书】

mbr.S

/boot/mbr.S

由于 loader.bin 超过了 512 字节，所以我们要把 mbr.S 中加载 loader.bin 的读入扇区数增大

在这里插入图片描述

实验操作

创建相应文件

(base) user@ubuntu:/home/cooiboi/bochs/include$ sudo vim boot.inc
(base) user@ubuntu:/home/cooiboi/bochs/boot$ sudo vim mbr.S
(base) user@ubuntu:/home/cooiboi/bochs/boot$ sudo vim loader.S

编译mbr.S和loader.S

sudo nasm -I include/ -o boot/mbr.bin boot/mbr.S
sudo nasm -I include/ -o boot/loader.bin boot/loader.S

(base) user@ubuntu:/home/cooiboi/bochs$ sudo nasm -I include/ -o boot/mbr.bin boot/mbr.S
(base) user@ubuntu:/home/cooiboi/bochs$ sudo nasm -I include/ -o boot/loader.bin boot/loader.S

将mbr和load分别写入磁盘中

sudo dd if=/home/cooiboi/bochs/boot/mbr.bin of=/home/cooiboi/bochs/boot/hd60M.img bs=512 count=1 conv=notrunc
sudo dd if=/home/cooiboi/bochs/boot/loader.bin of=/home/cooiboi/bochs/boot/hd60M.img bs=512 count=2 seek=2 conv=notrunc

(base) user@ubuntu:/home/cooiboi/bochs/boot$ sudo dd if=/home/cooiboi/bochs/boot/mbr.bin of=/home/cooiboi/bochs/boot/hd60M.img bs=512 count=1 conv=notrunc
1+0 records in
1+0 records out
512 bytes copied, 0.000242967 s, 2.1 MB/s
(base) user@ubuntu:/home/cooiboi/bochs/boot$ sudo dd if=/home/cooiboi/bochs/boot/loader.bin of=/home/cooiboi/bochs/boot/hd60M.img bs=512 count=2 seek=2 conv=notrunc
1+1 records in
1+1 records out
711 bytes copied, 0.000136065 s, 5.2 MB/s

启动Bochs

(base) user@ubuntu:/home/cooiboi/bochs$ sudo bin/bochs -f boot/bochsrc.disk

输出结果如下，左下角的字符串“2 loader in real”是在实模式下用 BIOS 中断 0x10 打印的。左上角第 3行的字符’P’，这是咱们在保护模式下输出的。一个程序历经两种模式，各模式下都打印了字符，为了区别实模式下的打印，所以字符串中含有“ inreal ” 。

在这里插入图片描述
在这里插入图片描述

这篇的文件目录与之前的博客再次改进MBR（从磁盘读入Loader加载器）一致。

参考资料

pengege666
关注
  • 0
    点赞
  • 踩
  • 0
    收藏
    觉得还不错? 一键收藏
  • 0
    评论
专栏目录
自己写操作系统2??进入保护模式
01-09
设置cr0的pe为1，这个表明已经进入了保护模式中。 ; ;protect.ASM ; ; ; SECTION ALIGN=16 VSTART=0x7E00 MOV AX ， [cs:SS_BASE] MOV SS ， AX XOR SP ...
第一篇章 BIOS（下）
fenfen4705的博客
09-20 421
Linux 单片机 ARM intel 中断体系
第4章 保护模式入门
weixin_43917399的博客
04-04 213
实模式下操作系统和用户程序属于同意特权级，平起平坐，没有区别对待；用户程序所引用的地址都是指向真实的物理地址，也就是说逻辑地址等于物理地址，试试在在的指哪打哪；用户程序可以自由修改段基址，可以不亦乐乎地访问所有内存，没人拦得住；访问超过64KB的内存区域是要切换段基址，转来转去容易晕呼；一次只能运行一个程序，无法充分利用计算机资源；共20条地址线，最大可用内存为1MB，这即使在20年前也不够用。注：实模式的CPU运行环境是16位，保护模式的运行环境是32位。
卓一笔记---用bochs调试实模式到保护模式转换程序
qinjiliaoqinmu的专栏
07-14 674
古人诚不欺余,书读百遍其义自见.研究了5天,终于把于渊同志所写的实模式到保护模式的跳转的初级操作系统程序看懂了.文章虽艰涩难懂,但收获亦颇丰. Intel8086系统的实模式是16位寻址,往后的80386是32位寻址.在保护模式下是32位寻址,Intel8086从实模式跳转到保护模式需要将寻址格式进行切换由16位物理寻址变成16位线性寻址.下面这段程序演示了如何从实模式跳转到保护...
22、进入保护模式
张登雨的博客
12-14 1677
01、保护模式要保护的是什么 02、全局描述符表GDT及其寄存器GDTR 03、创建全局描述符表 04、描述符分类 05、段描述符--段的类型和基地址 06、段界限及访问控制位 07、安装存储器的段描述符 08、加载全局描述符表寄存器GDTR 09、开启处理器的第21根地址线 10、设置寄存器CR0的PE位进入保护模式 11、描述符高速缓存器和保护模式下的内存访问 12、调试器中观察实模式和保护模式的内存访问
C307变速器进入保护模式.pptx
最新发布
10-14
C307变速器进入保护模式.pptx
进入你的保护模式 1
08-03
进入你的保护模式 1
aram:引导程序，进入保护模式并加载C代码
04-01
阿拉姆 引导程序，进入保护模式并加载C代码
进入保护模式（实现）
weixin_44918105的博客
03-22 150
主要新增段描述符的属性及选择子，都是以宏的方式实现。这个文件就是用来定义各种寄存器里的值的，立即数。
23.Ubuntu磁盘挂载常用命令
其木王·王子的博客
11-26 9245
磁盘挂载常用命令
Bochs源码分析 - 20: 开启保护模式
WriteAnything_的博客
08-01 459
前言 在邓志老师的《x86/x64体系探索及编程》中讲述了开启保护模式的顺序，我尝试着翻阅intel手册，但很遗憾似乎自己没有找到对此的描述（应该是有的，但是自己没找到，日后找到了会补充上）。 ---> 补充：在intel卷三 9.8 9.9 对保护模式初始化有讲述，查找cr0寄存器时从手册上看到的。 我们这篇文章来分析其如何初始化保护模式，着重来分析代码，可能不会来分析bochs源码。 开启保护模式 在开启保护模式之前，必须建立一个完整的保...
bochs调试方法
AlexSmoker的博客
01-29 2894
bochs一般用法 bochs是一个开源x86虚拟机软件。在他的实现中定义了各种数据结构来模拟硬件，用软件模拟硬件速度慢。 bochs的硬件调试体现在： 1）可以查看页表、gdt、idt等数据结构 2）可以查看栈中数据 3）可以反汇编任意内存 4）实模式、保护模式互相变换时提醒 5）中断发生时提醒 bochs中x和xp命令都是用来查看内存的，它们两个的区别在于x命令用于查看线性地址，而xp用来查看...
【ubuntu系统别乱关机-会黑屏无法开机】
weixin_39157614的博客
09-02 3455
关于ubuntu18.04+win11双系统，进入ubuntu黑屏无法进入
进入保护模式-汇编学习之路
qq_26585931的博客
02-14 2417
在实模式下由于对内存的保护不是特别的完善，一个段可以任意访问访问不是该段范围内的内存。例如以下一个小例子 mov cx,0x8000 push ds mov ds,cx mov [0x05],dx pop ds 这个例子就说明了先保存当前的数据段地址之后在修改其他段的内存，之后再返回当前的数据段。也就说明一个问题在实模式下可以任意对内存进行访问这样做是很危险的例如写一个程序从而达到修改
Ubuntu进入（安全模式）修改用户密码
DBaiYun的博客
07-14 5896
Ubuntu安全模式重置密码
操作系统编写 -- 进入保护模式
twxwjh的博客
02-09 602
操作系统编写 – 进入保护模式 进入保护模式，是操作系统必行的一关，今天抽出一点时间，将这个巨大的bug给大家揪出来。 话说我在进入保护模式的时候碰到了一堆bug，调试了几天几夜也没有成果，几乎被气坏了，我写操作系统是跟着一本书学的，结果我几乎不照着书上的代码写，自己写了一通，完全达不到效果。于是我把书上的代码复制了下来，一试居然书上的代码大错特错，完全没有达到效果，一闪一闪的，退回了BIOS界面。 为了解决这个问题，我翻了好多资料，终于找到方法了，现在跟大家讲一讲怎么进入保护模式。 具体代码 MBR bo
linux的汇编学习（3）---进入保护模式
linzhanglong的博客
12-03 1679
现在我们完成我们第一个主要的功能：引导Linux内核。      首先我们要准备一个Linux内核文件 bzImag。如何引导Linux内核呢？需要做几件事情：      1. 如何把内核加载到内存去执行；      2. 进入保护模式，保护模式带来的好处有很多，例如访问4G内存范围，以及访问内存权限设置；      3. 开启A20地址线（原因：http://blog.csdn.net/
帮我写一个可以进入保护模式的MBR代码
06-08
为了编写一个可以进入保护模式的MBR代码，您需要了解一些底层编程知识。下面是一个简单的MBR代码示例，可以在启动时进入保护模式： ``` BITS 16 ORG 0x7C00 start: mov ax, 0x9000 ; 设置堆栈指针 mov ss, ax mov sp, 0xFFFF cli ; 关闭中断 mov ax, cs mov ds, ax mov es, ax mov si, msg call print_string ; 输出信息 mov ax, 0x01 ; 设置CR0寄存器PE位 lgdt [gdtr] ; 加载全局描述符表 mov eax, cr0 or eax, ax mov cr0, eax jmp CODE_SEG:start_pm msg db "Entering Protected Mode...", 0 gdtr: dw 0xFFFF ; 全局描述符表限制 dd 0x00000000 ; 全局描述符表基地址 CODE_SEG equ 0x8 start_pm: mov ax, CODE_SEG mov ds, ax mov es, ax mov ss, ax mov sp, 0x90000 mov ebp, 0x90000 call pm_main ; 进入保护模式后的代码 jmp $ ; 无限循环 print_string: lodsb ; 加载字符 or al, al ; 判断是否结束 jz .done mov ah, 0x0E ; BIOS中断输出字符 int 0x10 jmp print_string .done: ret times 510-($-$$) db 0 dw 0xAA55 ``` 这段代码包含了以下主要步骤： 1. 设置堆栈指针和关闭中断。 2. 输出信息。 3. 设置CR0寄存器PE位并加载全局描述符表。 4. 跳转到保护模式下的代码。 请注意，此示例代码仅供参考，并且可能需要根据您的需求进行修改。在编写MBR代码时，务必小心谨慎，因为错误的代码可能会导致系统无法启动。

“相关推荐”对你有帮助么？

  • 非常没帮助
  • 没帮助
  • 一般
  • 有帮助
  • 非常有帮助
提交
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值