《汇编语言》第十三章 int指令

13.1 int 指令

int指令的格式为：int n
n为中断类型码，它的功能是引发中断过程，执行过程如下：
1，取中断类型码 n
2，标志寄存器入栈，IF=0,TF=0
3，CS，IP入栈
4，(IP)=(n乘4)，(CS)=(n乘4+2)
从此处转去执行n号中断的中断处理程序

可以在程序中使用int指令调用任何一个中断的中断处理程序

assume cs:code

code segement

	start:mov ax,0b800h
		  mov es,ax
		  mov byte ptr es:[12*160+40*2],'!'
		  int 0
		  
code ends
end start
		

这段程序执行后，将在屏幕中间显示一个 ！，然后显示 drive overflow，后返回到系统中，！是我们编程显示的，而 drive overflow是使用int 0指令，引发中断过程，执行0号中断处理程序，而系统设置的0号中断处理程序的功能是显示 drive overflow，然后返回到系统

可见，int指令的最终功能和call指令类似，都是调用一段程序

一般情况下，系统将一些具有一定功能的子程序，以中断处理程序的方式提供给应用程序调用，在编程时，也可以使用int指令调用这些子程序，以后将中断处理程序简称为 中断例程

13.2 编写供应用程序调用的中断例程

考虑：编写，安装中断 7ch的中断例程
功能：求一word型数据的平方
参数：(ax) = 要计算的数据
返回值：dx，ax中存放结果的高16位和低16位
示例：求 2*3456^2

assume cs:code

code segement

	start:mov ax,3456 ;(ax)=3456
		  int 7ch 	  ;调用中断7ch的中断例程，计算ax中数据的平方
		  add ax,ax
		  adc dx,dx   ;dx：ax存放结果，将结果乘2
		  
		  mov ax,4c00h
		  int 21h
		  
code ends
end start
		

分析:
1，编写实现求平方功能的程序
2，安装程序，将其安装在0：200处
3，设置中断向量表，将程序的入口地址保存在7ch表项中，使其成为中断7ch的中断例程

安装程序：

assume cs:code

code segement

	start:mov ax,cs
		  mov ds,ax
		  mov si,offset sqr ;设置ds：si指向源地址
		  mov ax,0 
		  mov es,ax
		  mov di,200h ;设置es：di指向目的地址
		  mov cx,offset sqrend - offset sqr ;设置cx为传输长度
		  cld ;传输方向为正
		  rep movsb
		  
		  mov ax,0
		  mov es,ax
		  mov word ptr es:[7ch*4],200h
		  mov word ptr es:[7ch*4+2],0
		  
		  mov ax,4c00h
		  int 21h
		  
	sqr:mul ax
		iret
		
sqrend nop
		  
code ends
end start
		

注意，在中断例程sqr的最后，要使用iret指令，CP执行int 7ch指令进入中断例程之前，标志寄存器，当前CS和IP被入栈，在执行完中断例程后，应该用iret指令恢复int 7ch执行前的标志寄存器和CS，IP的值，从而接着执行应用程序

int指令和iret指令的配合使用与call指令和ret指令的配合有相似的思路

13.3 对int，iret 和栈的深入理解

考虑：用7ch中断例程完成loop指令的功能
应用：在屏幕中间显示80个 ！
loop s的执行需要两个信息，循环次数和到s的位移，用cx存放循环次数，用bx存放位移

assume cs:code

code segement
	
	start:mov ax,0b800h
		  mov es,ax
		  mov di,160*12
		  
		  mov bx,offset s - offset se ;设置从标号se到标号s的转移位移
		  mov cx,80
		  
		s:mov byte ptr es:[di],'!'
		  add di,2
		  int 7ch  ;如果(cx)不等于0，转移到标号s处
		  
	   se:nop

		  mov ax,4c00h
		  int 21h
		  
code ends
end start

为了模拟loop指令，7ch中断例程应具备下面的功能：
1， dec cx ，dec作用是使寄存器内值减一
2，如果(cx)不等于0，则转移到标号s，否则向下执行

int 7ch引发中断后，进入7ch中断例程，在中断过程中，当前的标志寄存器，CS和IP都要入栈，此时入栈的CS和IP中的内容，分别是调用程序的段地址(标号s的段地址)和int 7ch后一条指令的偏移地址(标号se的偏移地址)

在中断例程中，可以从栈中取得标号s的段地址和标号se的偏移地址，而用标号se的偏移地址加上bx中存放的转移位移就可以得到标号s的偏移地址

7ch中断例程：

assume cs:code

code segement

	lp:push bp
	   mov bp,sp
	   dec cx
	   jcxz lpret
	   add [bp+2],bx
	   
	lpret: pop bp
           iret			
		  
code ends
end start

利用iret指令，将栈中的se的偏移地址加上bx中的转移位移，则栈中的se的偏移地址就变成了s的偏移地址，再使用iret指令，用栈中的内容设置CS，IP从而实现转移到标号s处

13.4 BIOS和DOS所提供的中断例程

在系统板的ROM中存放着一套程序，称为 BIOS(基本输入输出系统)，BIOS主要包含以下几部分内容：
1，硬件系统的检测和初始化程序
2，外部中断和内部中断的中断例程
3，用于对硬件设备进行I/O操作的中断例程
4，其它和硬件系统相关的中断例程

操作系统DOS也提供了中断例程，从操作系统的角度来看，DOS的中断例程就是操作系统向程序员提供的编程资源

BIOS和DOS在所提供的中断例程中包含了许多子程序，这些子程序实现了程序员在编程时经常需要用到的功能，可以用int 指令直接调用BIOS和DOS提供的中断例程，来完成某些工作

和硬件设备相关的DOS中断例程，一般都调用了BIOS的中断例程

13.5 BIOS和DOS中断例程的安装过程

BIOS和DOS提供的中断例程安装过程：
1，开机后，CPU一加电，初始化(CS)=0FFFFH,(IP)=0,自动从FFFF：0单元开始执行程序，FFFF：0处有一条跳转指令，CPU执行该指令后，转去执行BIOS中的硬件系统检测和初始化程序
2，初始化程序将建立BIOS所支持的中断向量，即将BIOS提供的中断例程的入口地址登记在中断向量表中
3，硬件系统检测和初始化完成后，调用int 19h进行操作系统的引导，从此将计算机交由操作系统控制
4，DOS启动后，除了完成其它工作，还将它所提供的中断例程装入内存，并提供相应的中断向量

13.6 BIOS中断例程应用

int 10h 中断例程是BIOS提供的中断例程，其中包含了多个和屏幕输出相关的子程序

一般来说，一个供程序员调用的中断例程中往往包含多个子程序，中断例程内部用传递进来的参数来决定执行哪一个子程序，BIOS和DOS提供的中断例程，都用ah来传递内部子程序的编号

int 10h中断例程的设置光标位置功能：

mov ah,2 ;置光标
mov bh,0 ;第0页
mov dh,5 ;dh中放行号
mov dl,12 ;dl中放页号
int 10h

(ah)=2表示调用第10h号中断例程的2号子程序，功能为设置光标位置，可以提供光标所在的行号，列号和页号作为参数，(bh)=0,(dh)=5,(dl)=12，设置光标到第0页，第5行，第12列

bh中页号的含义：内存地址中，B8000H~BFFFFH共32KB的空间，为80*25彩色字符模式的显示缓冲区，一屏的内容在显示缓冲区中占4000个字节
显示缓冲区分为8页，每页4KB(约4000字节)，也就是说，通常情况下，B8000H~B8F9FH中的4000个字节的内容将出现在显示器上

13.7 DOS中断例程应用

int 21h中断例程是DOS提供的中断例程，其中包含了DOS提供给程序员在编程时调用的子程序

使用int 21h中断例程的4ch号功能，即程序返回功能：

mov ah,4ch ;程序返回
mov al,0 ;返回值
int 21h

(ah) = 4ch表示调用第21h号中断例程的4ch号子程序，功能为程序返回，可以提供返回值作为参数

DOS为程序员提供了许多可以调用的子程序，都包含在int 21h中断例程中