X86汇编语言：从实模式到保护模式（代码+注释）--c6

X86汇编语言：从实模式到保护模式（代码+注释）–c6

1. 标志寄存器FLAGS：
   

   • 6th：ZF位（Zero Flag）：零标志，执行算数或者逻辑运算之后，会将该位置位。
   • 10th：DF位（Direction Flag）：方向标志，将其清零或者置1就能够控制movsb和movsw的传送方向。0代表正方向，1代表反方向。使用cld命令可以将该位清零。
   • 奇偶标志位PF：计算的结果第八位中，偶数个数个1则，PF=1，否则PF=0
   • 进位标志CF：借位情况发生则CF=1，否则CF=0
   • 溢出标志OF：假定进行的是有符号运算，如果结果超出了范围，则OF=1，否则OF=0
   • 符号位SF：计算结果的最高位是比特0的话，就将其置零，否则置1

2. 能够提供偏移地址的只能为BX（Base Address Register）、SI（Source Index）、DI（Destination Index）、BP寄存器。AX（Accumulateor）、CX（Counter）、DX（Data）。

         ;代码清单6-1
         ;文件名：c06_mbr.asm
         ;文件说明：硬盘主引导扇区代码
         ;创建日期：2011-4-12 22:12 
      
         jmp near start
         
  mytext db 'L',0x07,'a',0x07,'b',0x07,'e',0x07,'l',0x07,' ',0x07,'o',0x07,\
            'f',0x07,'f',0x07,'s',0x07,'e',0x07,'t',0x07,':',0x07	;\为续行符
  number db 0,0,0,0,0
  
  start:
         mov ax,0x7c0                  ;设置数据段基地址 
         mov ds,ax
         
         mov ax,0xb800                 ;设置附加段基地址 
         mov es,ax
         
         cld						   ;清除标志寄存器FLAGS的df位，即方向位
         mov si,mytext				   ;设置数据源地址 （DS：SI），源基地址由DS指定段地址，SI指定偏移地址               
         mov di,0					   ;设置目的地址的偏移量（ES：DI），目的基地址由ES指定段地址，DI指定偏移地址
         mov cx,(number-mytext)/2      ;实际上等于 13，CX指定了movs(x)的可执行次数，x可以为b、w
         rep movsw					   ;movsw指令的操作码是0xA5，该整个指令的操作码为：0xF3 0xA5
     
         ;得到标号所代表的偏移地址
         mov ax,number
         
         ;计算各个数位
         mov bx,ax
         mov cx,5                      ;设置循环次数 
         mov si,10                     ;除数 
  digit: 
         xor dx,dx
         div si						   ;使用DX:AX中的内容作为被除数，SI作为除数，商存放在AX中，余数存放在DX中
         mov [bx],dl                   ;因为余数小于10，所以只需要取dl即可，保存数位
         inc bx						   ;增加地址的位置
         loop digit					   ;loop也会使用CX计数器中的内容
         
         ;显示各个数位
         mov bx,number				   ;使用number开始的存储的字符
         mov si,4					   ;取出字符的个数      
   show:
         mov al,[bx+si]
         add al,0x30
         mov ah,0x04
         mov [es:di],ax
         add di,2
         dec si
         jns show
         
         mov word [es:di],0x0744

         jmp near $						;$代表由NASM提供的标记，可以看作隐藏在当前行的标号，该语句也就是对这一行的语句进行循环

  times 510-($-$$) db 0					;$$是NASM汇编器提供的标记，代表当前汇编节的其实汇编地址
                   db 0x55,0xaa