快速结束WMWare运行的Ubuntu18.04线程的批处理程序

提示：文章写完后，目录可以自动生成，如何生成可参考右边的帮助文档

---

1 问题描述

笔者在Windows中安装了WMWare运行Ubuntu18.04，在使用过程中发现，Ubuntu18.04总会发生死机现象。

按照网络上提供的方法结束Ubuntu18.04进程：找到Ubuntu18.04目录下的wmware.log文件，查找运行进程的PID；进入任务管理器–>性能—>性能监视器—>结束对应PID的进程。

笔者很长一段时间，采用这种方法解决死机都得到了顺利解决，但是该操作十分的麻烦。某一天笔者实在是受不了，编写了一个批处理程序快速结束WMware线程。

2 问题解决

笔者在Windows下，编辑了一个批处理程序，用于快速结束死机的Ubuntu18.04进程。总体思路：将wmware.log中Ubuntu18.04进程的pid提取处理，然后用命令结束。代码如下：

@echo off
echo =============Force stop vmware thread=============

REM 获取管理员权限, 代码来自网络
if exist "%SystemRoot%\SysWOW64" path %path%;%windir%\SysNative;%SystemRoot%\SysWOW64;%~dp0
bcdedit >nul
if '%errorlevel%' NEQ '0' (goto UACPrompt) else (goto UACAdmin)
:UACPrompt
%1 start "" mshta vbscript:createobject("shell.application").shellexecute("""%~0""","::",,"runas",1)(window.close)&exit
exit /B
:UACAdmin
cd /d "%~dp0"

echo.
echo 1.Has get administrator authority.

REM 显示当前工作目录,批处理程序所在目录
echo.
set work_dir=%~dp0
echo 2.Work dir is: %work_dir%

REM 显示wmware.log所在路径，这里需要替换成自己的路劲
echo.
set vmware_log_file=C:\ubuntu18.04\vmware.log
echo 3.Vmware log file is: %vmware_log_file%

REM 复制wmware.log到工作目录
echo.
echo 4.Copy the log file to work dir.
copy %vmware_log_file% /A "%work_dir%" /A

REM 查找PID并显示
set file=%work_dir%vmware.log
REM find the vmware pid
for /f "tokens=8 delims= " %%a in (%file%) do (	
	set pid_str=%%a	
	goto label_1
)
:label_1
set pid=%pid_str:~4,20%	
echo.
echo 5.Find the pid is:%pid%

REM 杀死线程
echo.
echo 6.Kill the pid %pid%
taskkill /F /PID %pid% 

REM 删除临时文件
echo.
echo 7.Delete temp file %file%.
del %file% 

echo.
pause

上述代码在使用过程中，需要将C:\ubuntu18.04\vmware.log更换为你自己的Ubuntu18.04目录。批处理程序所在的目录最好不要有中文字符，因为可能会出现运行不成功。
运行该批处理会有一个闪现，这是正常现象，因为获取了管理员权限。

运行结果如下：

=============Force stop vmware thread=============

1.Has get administrator authority.

2.Work dir is: C:\kill_vmware\

3.Vmware log file is: C:\ubuntu18.04\vmware.log

4.Copy the log file to work dir.
已复制         1 个文件。

5.Find the pid is:20092

6.Kill the pid 20092
成功: 已终止 PID 为 20092 的进程。

7.Delete temp file C:\kill_vmware\vmware.log.

请按任意键继续. . .