按键精灵手机助手计算时间差

这两天在用按键精灵手机助手写游戏脚本，需要计算时间差，先要获取两次时间，用系统自带的time()函数可以得到系统时间，不过得到的时间是秒数，需要转化一下

time()函数得到的是从1970年1月1日 8:00:00至今所经过的秒数

 

可以用DateTime.Format函数将Time()转为正常的时间格式

既然很容易就得到秒数，将两个时间相减就可以得到时间差了。

如果按键精灵手机助手每次获取电脑时间都很准确，我今天就不用写这篇文章了。我在运行游戏脚本时总是出错，检查之后才发现原因是获取的时间有问题

我电脑时间明明是16:17，怎么打印出来是9点

我把时间手动改为15:20点，显示还是9点

 由于这个time()函数获取的时间不稳定，所以我决定用GetNetworkTime()函数，获取网络时间，然后计算时差。

获取时间容易，计算时间差难。因为按键精灵手机助手没有类似TimeDiff的函数，这一点希望按键精灵能改一下。于是我自己写代码计算时间差，代码可直接复制去使用。只要输入两个时间就行了，如果手动输入时间，必须为字符串，格式为"yyyy-mm-dd HH:MM:SS"

 有闫年也可以正常计算出来

 把秒换算成时分秒就简单了，这里就不写了

【总结】

1、可以有系统自带的time()函数获取系统时间，然后相减，得到时间差。这个方法时不时会出错

2、用下面我写的代码，可以手动输入时间，也可以获取网络时间，如果是手动输入时间，一定要注意格式

Dim t1,t2
//获取网络时间
//t1 = GetNetworkTime()
//自定义时间必须为字符串，格式为"yyyy-mm-dd HH:MM:SS"
t1 = "2024-02-28 00:00:00"

//Delay 5000
//t2 = GetNetworkTime()//获取网络时间
t2 = "2024-03-01 00:00:00"
TracePrint "时间差为",ShiJianCha(t1,t2),"秒"


Function ShiJianCha(time_1,time_2)
	Dim time_3, year_0, year_1, year_2, mon, mon1, mon2, mon3, day_1, day_2, day_3, yue1, yue2, ri1, ri2
	Dim hour_1, hour_2, hour_3, miniute_1, miniute_2, miniute_3, sec_1, sec_2, sec_3,  TotalDays
	Dim ddd = 0
	
	//提取时间1的年月日时分秒
	TracePrint "time_1 =",time_1
	year_1 = Left(time_1, 4)+0
	mon1 = Mid(time_1, 6, 2)+0
	day_1 = Mid(time_1,  9, 2)+0
	hour_1 = Mid(time_1, 12, 2)+0
	miniute_1 = Mid(time_1, 15, 2)+0
	sec_1 = Mid(time_1, 18, 2)+0
	
	//提取时间2的年月日时分秒
	TracePrint "time_2=",time_2
	year_2 = Left(time_2, 4)+0
	mon2 = Mid(time_2, 6, 2)+0
	day_2 = Mid(time_2, 9, 2)+0
	hour_2 = Mid(time_2, 12, 2)+0
	miniute_2 = Mid(time_2, 15, 2)+0
	sec_2 = Mid(time_2, 18, 2)+0
	
	//计算秒数差
	If sec_2 - sec_1 >= 0 Then 
		sec_3 = sec_2 - sec_1
	Else 
		sec_3 = sec_2 - sec_1 + 60
		miniute_2 = miniute_2 - 1
		If miniute_2 < 0 Then 
			miniute_2 = 59
			hour_2=hour_2-1
		End If 
	End If
	
	//计算分钟数差
	If miniute_2 - miniute_1 >= 0 Then 
		miniute_3 = miniute_2 - miniute_1
	Else 
		miniute_3 = miniute_2 - miniute_1 + 60
		hour_2 = hour_2 - 1
		If hour_2 < 0 Then 
			hour_2 = 23
			day_2 = day_2 - 1		
		End If 
	End If
	
	//计算小时数差
	If hour_2 - hour_1 >= 0 Then 
		hour_3 = hour_2 - hour_1	
	Else 
		hour_3 = hour_2 - hour_1 + 24
		day_2 = day_2 - 1
		If day_2 = 0 Then 
			mon2 = mon2 - 1
			TotalDays = TotalDays - 1		
			If mon2 <>0  Then		 		 	
				day_2 = MeiYueTianShu(mon2,year_2)
			Else 
				mon2 = 12
				day_2 = 31
				year_2 = year_2 - 1
			End If
		End If 
	End If
	
	//计算天数差
	For year_0 = year_1 To year_2	
		If year_0 = year_1 Then 
			yue1 = mon1
			If year_1 = year_2 Then 
				yue2 = mon2				
			Else 
				yue2 = 12				
			End If			
		ElseIf year_0 = year_2			
			If year_1 = year_2 Then 
				yue1 = mon1				
			Else 
				yue1 = 1				
			End If
			yue2 = mon2	
		Else 
			yue1 = 1
			yue2 = 12
		End If
		
		For mon = yue1 To yue2
			If year_0 = year_1 and mon = mon1 Then 
				ri1 = day_1
				If mon1 = mon2 Then 
					ri2 = day_2	
				Else 
					ri2 =MeiYueTianShu(mon,year_0)	
				End If					
			ElseIf year_0  = year_2 And mon = mon2 Then
				If mon1 = mon2 Then 
					ri1 =day_1
				Else 	
					ri1 = 1
				End If
				ri2 = day_2					
			Else 
				ri1 = 1
				ri2 = MeiYueTianShu(mon,year_0)		
			End If
			
			For ri = ri1 To ri2
				ddd = ddd + 1			
			Next	
		Next	
	Next
	TotalDays = ddd - 1
	ShiJianCha = ((TotalDays* 24 + hour_3) * 60 + miniute_3) * 60 + sec_3
End Function

Function MeiYueTianShu(mon,year_0)
	If mon = 4 or mon = 6 or mon = 9 or mon = 11 Then 
		MeiYueTianShu = 30
	ElseIf mon = 2 Then
		If RunNian(year_0) Then 
			MeiYueTianShu = 29
		Else 
			MeiYueTianShu = 28					
		End If
	Else 
		MeiYueTianShu = 31				
	End If
End Function

Function RunNian(yyyy)
	If yyyy Mod 400 = 0 Then 
		RunNian = True		
	Else 
		If yyyy Mod 4 = 0 And yyyy / 100 <> Int(yyyy / 100) Then 
			RunNian = True	
		Else 
			RunNian = False 	
		End If
	End If
End Function

 把附件放在按键精灵手机助手里面的Plugin文件夹里，在使用之前导入一下，格式如下：
Dim t1,t2
Import "SC.lua"
t1 = GetNetworkTime()        //获取网络时间
//自定义时间必须为字符串，格式为"yyyy-mm-dd HH:MM:SS"
t2 = "2024-03-01 02:18:20"
TracePrint SC.ShiJianCha(t1,t2)

 附件下载地址：按键精灵手机助手计算时间差-VB文档类资源-CSDN下载