【solidity】函数修饰器（Function Modifiers）

最新推荐文章于 2023-07-12 09:40:49 发布

CamphorBloom

最新推荐文章于 2023-07-12 09:40:49 发布

阅读量8.3k

点赞数

分类专栏：智能合约文章标签： solidity 智能合约

本文链接：https://blog.csdn.net/weixin_45719444/article/details/122782367

版权

智能合约专栏收录该内容

12 篇文章 2 订阅

订阅专栏

本文介绍了如何在Solidity智能合约中使用函数修饰器来实现权限控制和参数验证。通过示例展示了`onlyOwner`和`validAccount`修饰器的用法，以及修饰器的执行顺序和参数传递。修饰器使得代码更简洁且易于维护，对于多条件检查的函数尤其有用。

摘要由CSDN通过智能技术生成

修饰符可用于以声明方式更改函数的行为。例如，您可以使用修饰符在执行函数之前自动检查条件。

检查调用者权限

// SPDX-License-Identifier: GPL-3.0
pragma solidity >=0.7.0 <0.9.0;

contract Owned {
    address public owner;
    uint256 public account;

    constructor() {
        owner = msg.sender;
        account = 0;
    }

    function updateAccount(uint256 _account) public {
        if(msg.sender == owner) {
            account = _account;
        }
    }
}

在Owned合约中，通过构造函数指定了owner为合约调用者地址，同时updateAccount方法中添加了if判断，如果当前合约调用者是部署合约的人地址，则正确修改全局变量account值，如果不是，则不能修改（此过程不会报错）。虽说这种方法可以达到目的，但有多个方法需要的话，代码复用率是非常低的。使用函数修饰器就很方便地解决这个问题，通过关键字modifier定义。

 modifier onlyOwner {
        require(msg.sender == owner, "Only owner can call this function.");
        _;
    }

 function updateAccount(uint256 _account) public onlyOwner {     
            account = _account;
    }

在定义onlyOwner出现的特殊符号 `_`，是使用该修饰器的函数体插入位置。 ‘_’符号可多次出现，替换成对应的函数体即可。

如果owner满足要求，则执行相关函数，若不满足，则抛出错误信息（如下图）。

修饰器传参

假如还有个需求，当我在调用updateAccount方法修改account值时，必须确保修改的值大于1000才行。那么此时我们再添加个修饰器，不过这个有点特殊，它带了参数。

    modifier validAccount(uint256 _account) {
        require(_account > 1000, "Invalid account, should be greater than 1000!");
        _;
    }
    function updateAccount(uint256 _account) public onlyOwner validAccount(_account) {     
            account = _account;
    }

否则报错，提示信息如下：

一个函数可能要做多种检查，多个修饰器以空格分隔来应用于函数，并按呈现的顺序进行检验。

修饰器不能隐式访问或更改它们修改的函数参数和返回值。它们的值只能在调用时显式传递给它们。从修饰器或函数体显式返回仅保留当前修饰符或函数体。返回变量被赋值，控制流在修饰器中的 ‘_’ 之后继续执行。

修饰器执行顺序

最后呢，出个迷惑题给你们解决。

// SPDX-License-Identifier: GPL-3.0
pragma solidity >=0.7.0 <0.9.0;

contract modifierTest {
    address public owner;
    uint256 public a; // （1）最终a的值是多少？？？
    
    constructor() {
        owner = msg.sender;
    }
    
    function test(uint num) public checkPara(num) returns(uint256) {
        a = 10;
        return a; // （2）返回的a是多少？？？
    }
    
    modifier checkPara(uint number) {
        a = 1;
        _;
        a = 100;
    }
}

有兴趣的同学可以尝试编译部署下，看看答案是不是自己心中所想的一样。

参考：Contracts — Solidity 0.8.11 documentation

solidity教材配套视频讲解（里边有迷惑题的详细解答哦！）