Generate POJOs.groovy生成mybatisPojo实体类可自定义

idea连接mysql数据库后一键生成model实体类 可自定义Generate POJOs.groovy文件
1.先根据表找到Generate POJOs.groovy文件

2.编辑该文件粘贴

import com.intellij.database.model.DasTable
import com.intellij.database.model.ObjectKind
import com.intellij.database.util.Case
import com.intellij.database.util.DasUtil

import java.time.LocalDateTime
import java.time.format.DateTimeFormatter

/*
 * Available context bindings:
 *   SELECTION   Iterable<DasObject>
 *   PROJECT     project
 *   FILES       files helper
 *   update by yitianRen 20200324
 */

packageName = ""
typeMapping = [
        (~/(?i)int8/)                     : "Long",
        (~/(?i)int/)                      : "Integer",
        (~/(?i)bool/)                     : "Boolean",
        (~/(?i)float|double|decimal|real/): "Double",
        (~/(?i)jsonb/)                    : "JSONObject",
        (~/(?i)datetime|timestamp/)       : "LocalDateTime",
        (~/(?i)date/)                     : "java.util.Date",
        (~/(?i)time/)                     : "java.util.Time",
        (~/(?i)/)                         : "String"
]

FILES.chooseDirectoryAndSave("Choose directory", "Choose where to store generated files") { dir ->
    SELECTION.filter { it instanceof DasTable }.each { generate(it, dir) }
}
// 获取包所在文件夹路径
def getPackageName(dir) {
    return dir.toString().replaceAll("\\\\", ".").replaceAll("/", ".").replaceAll("^.*src(\\.main\\.java\\.)?", "") + ";"
}
def generate(table, dir) {
    packageName = getPackageName(dir)
    def className = javaName(table.getName(), true)
    def fields = calcFields(table)//更改实体生成规则
    new File(dir, className + ".java").withPrintWriter("utf-8"){ out -> generate(out, className, fields, table) }//输出实体类
}

def generate(out, className, fields, table) {
    out.println "package $packageName"
    out.println ""
    out.println "import lombok.Data;"
    out.println "import com.baomidou.mybatisplus.annotations.TableId;"
    out.println "import com.baomidou.mybatisplus.enums.IdType;"
    out.println "import com.baomidou.mybatisplus.annotations.TableName;"
    out.println "import com.baomidou.mybatisplus.annotations.TableField;"
    out.println "import io.swagger.annotations.ApiModelProperty;"
    out.println "import java.io.Serializable;"

    out.println "import java.time.LocalDateTime;"
    out.println ""
    out.println "/**\n" +
            " * " + LocalDateTime.now().format(DateTimeFormatter.ofPattern("yyyy-MM-dd HH:mm:ss")).toString() + "\n" +
            " * @author zx\n" +
            " */"
    out.println ""
    out.println "@Data"
    out.println "@TableName(value =\"" + table.getName() + "\")"
    out.println "public class $className implements Serializable {"
    out.println "    private static final long serialVersionUID = 1L;"
    fields.each() {
        out.println ""
        // 输出注释  这里和下面的 comm是一一对应的
/*    if (isNotEmpty(it.commoent)) {//定义非空校验，it.commoent ！= ""手写无效
      out.println "// ${it.commoent}"
    }*/
        if (it.name == "id") out.println "    @TableId(value=\"${it.field}\",type = IdType.UUID)"
        else if (it.type == "JSONObject") out.println "    //@TableName(value =\"" + table.getName() + "\", autoResultMap = true)\n    @TableField(value=\"${it.field}\", typeHandler = JacksonTypeHandler.class)"
        else out.println "    @TableField(value=\"${it.field}\")"
        // if (it.annos != "") out.println "  ${it.annos}"
        out.println "    @ApiModelProperty(value=\"${it.commoent}\")"
        if (it.type == "LocalDateTime") out.println "    @JsonSerialize(using = LocalDateTimeSerializer.class)\n    @JsonFormat(shape=JsonFormat.Shape.STRING, pattern=\"yyyy-MM-dd HH:mm:ss\")"
        out.println "    private ${it.type} ${it.name};"
    }
    out.println ""

    out.println "}"
}

def calcFields(table) {
    DasUtil.getColumns(table).reduce([]) { fields, col ->
        def spec = Case.LOWER.apply(col.getDataType().getSpecification())
        def typeStr = typeMapping.find { p, t -> p.matcher(spec).find() }.value
        def comm = [
                field : col.getName(),
                name : javaName(col.getName(), false),
                type : typeStr,
                commoent: col.getComment()
        ]
        //对于表中主键自定义注解
        if ("pk".equals(Case.LOWER.apply(col.getName()))){
            comm.annos = "\t@Id\n"
            //自增主键需要
            comm.annos += "@Column(name = \"" + col.getName() + "\")"
        }
        fields += [comm]//字段对照
    }
}

def javaName(str, capitalize) {
    def s = com.intellij.psi.codeStyle.NameUtil.splitNameIntoWords(str)
            .collect { Case.LOWER.apply(it).capitalize() }
            .join("")
            .replaceAll(/[^\p{javaJavaIdentifierPart}[_]]/, "_")
    capitalize || s.length() == 1? s : Case.LOWER.apply(s[0]) + s[1..-1]
}


def isNotEmpty(content) {
    return content != null && content.toString().trim().length() > 0
}

3.编辑文件后生成model