汇编语言-王爽 第12章 内中断-笔记

编写处理0号中断
问题：重新编写一个0号中断处理程序do0，它的功能是在屏幕中间显示"overflow!"后，然后返回到操作系统。
要做以下几件事情：
（1）编写可以显示“overflow！”的中断处理程序do0
（2）将do0送入内存0000:0200处
（3）将do0的入口地址0000:0200存储到中断向量表0号表项中

程序的框架：

 assume cs:code
 
 code segment

 start: do0安装程序
          设置中断向量表
	      mov ax，4c00h
	      int 21h
	      
 do0: 显示字符串”overflow“
	     mov ax，4c00h
	     int 21h
	     
 code ends
 end start

具体程序如下：

assume cs:code

code segment

	start:	;do0安装程序
			mov ax, cs			;设置ds:si指向源地址
			mov ds, ax
			mov si, offset do0
			
			mov ax, 0			;设置es:di指向目的地址
			mov es, ax
			mov di, 200h
			
			mov cx, offset do0end - offset do0 ;设置cx为传送长度
			;"-"是编译器识别的运算符号，编译器可以用它来进行两个常数的减法。
			
			cld					;设置传输方向为正
			
			rep movsb
			
			;设置中断向量表
			mov ax, 0
			mov es, ax
			mov word ptr es:[0*4], 200h
			mov word ptr es:[0*4+2], 0
			
			
			mov ax, 4c00h
			int 21h


			;显示字符串"overflow!"
	do0:	jmp short do0start				;这条指令占2个字节
			db "overflow!"
			
	do0start:	mov ax, cs
				mov ds, ax
				mov si, 202h				;设置ds:si指向字符串
				
				mov ax, 0b800h				;设置es:di指向显存空间的中间位置
				mov es, ax
				mov di, 12*160+36*2
				
				mov cx, 9					;设置cx为字符串长度
			s:	mov al, [si]
				mov es:[di], al
				inc si
				add di, 2
				loop s
				
				mov ax, 4c00h
				int 21h

	do0end:	nop

code ends

end start