汇编实验15+16

实验15

assume cs:code

stack segment
    db 128 dup(0)
stack ends

code segment
start:  mov ax,stack
        mov ss,ax
        mov sp,128

        push cs
        pop ds

        mov ax,0
        mov es,ax
        
        mov si,offset int9;安装int9程序
        mov di,204H
        mov cx,offset int9end-offset int9
        cld
        rep movsb

        cli
        push es:[9*4];保存原int 9地址
        pop es:[200H]
        push es:[9*4+2]
        pop es:[202H]

        mov word ptr es:[9*4],204H;将新的int 9地址写入
        mov word ptr es:[9*4+2],0
        sti

        mov ax,4c00H
        int 21H


int9:
    push ax
    push bx
    push cx
    push es

    in al,60H
    
    pushf ;模拟int9中断
    call dword ptr cs:[200H]

    cmp al,9EH;9E A的断码，当检测到A的断码时，开始显示A在屏幕上
    jne int9ret

    mov ax,0B800H
    mov es,ax
    mov cx,2000;160*25/2
    mov bx,0

    mov al,'A'
    mov ah,1CH
s:  mov es:[bx],ax
    add bx,2
    loop s


int9ret:
    pop es
    pop cx
    pop bx
    pop ax
    iret

int9end:nop

code ends
end start

实验16

assume cs:code

code segment
start:
    mov ax,cs
    mov ds,ax
    mov si,offset setscreen
    mov ax,0
    mov es,ax
    mov di,200h
    cld
    mov cx,offset setscreenends-offset setscreen
    rep movsb

    cli 
    mov word ptr es:[7ch*4],200h
    mov word ptr es:[7ch*4+2],0
    sti

    mov ax,4c00h
    int 21h


setscreen:	jmp short set
       table	dw offset sub1 - offset setscreen + 200h
				dw offset sub2 - offset setscreen + 200h
				dw offset sub3 - offset setscreen + 200h
				dw offset sub4 - offset setscreen + 200h
		;setscreen在0:200处，通过上式的计算，可以得到子程序sub(i)入口的地址
set:	
	push bx
	
	cmp ah,3
	ja sret
	mov bl,ah
	mov bh,0
	add bx,bx
	call word ptr cs:[bx+202h]

sret:
	pop bx
	iret

sub1:					;1号子程序
	push bx
	push cx
	push es
	mov bx,0b800h
	mov es,bx
	mov bx,0
	mov cx,2000
  sub1s:
	mov byte ptr es:[bx],' '
	add bx,2
	loop sub1s
	pop es
	pop cx
	pop bx
	ret

sub2:					;2号子程序
	push bx
	push cx
	push es
	mov bx,0b800h
	mov es,bx
	mov bx,1
	mov cx,2000
        sub2s:
	and byte ptr es:[bx],11111000b
	or es:[bx],al
	add bx,2
	loop sub2s
	pop es
	pop cx
	pop bx
	ret

sub3:					;3号子程序
	push bx
	push cx
	push es
	mov cl,4
	shl al,cl
	mov bx,0b800h
	mov es,bx
	mov bx,1
	mov cx,2000
        sub3s:
	and byte ptr es:[bx],10001111b
;	shl al,1
;	shl al,1
;	shl al,1
;	shl al,1
	or es:[bx],al
	add bx,2
	loop sub3s
	pop es
	pop cx
	pop bx
	ret

sub4:					;4号子程序
	push cx
	push si
	push di
	push es
	push ds

	mov si,0b800h
	mov es,si
	mov ds,si
	mov si,160
	mov di,0
	cld
	mov cx,24
        sub4s:
	push cx
	mov cx,160
	rep movsb
	pop cx
	loop sub4s

	mov cx,80
	mov si,0
        sub4s1:
	mov byte ptr [160*24+si],' '
	add si,2
	loop sub4s1
	
	pop ds
	pop es
	pop di
	pop si
	pop cx
	ret
setscreenends:
	nop
code ends
end start