ARM体系结构与接口技术-2

最新推荐文章于 2022-12-13 11:12:19 发布
最新推荐文章于 2022-12-13 11:12:19 发布
阅读量352 收藏 1
点赞数 1
分类专栏： 嵌入式软件 文章标签： arm 嵌入式硬件 单片机
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/weixin_51645274/article/details/121765793
版权

跳转与储存器访问指令

汇编中的符号

1.指令： 能够编译生成一条32位的机器码，且能被CPU识别和执行
2.伪指令：本身不是指令，编译器可以将其替换成若干条等效指令
3.伪操作：不会生成代码，只是在编译之前告诉编译器怎么编译

ARM指令

1.数据处理指令： 数学运算、逻辑运算
2.跳转指令： 实现程序的跳转，本质就是修改了PC寄存器
3.Load/Srore指令： 访问（读写）内存
4.状态寄存器传送指令：访问（读写）CPSR寄存器
5.软中断指令： 触发软中断异常
6.协处理器指令： 操控协处理器的指令

1. 指令

指令是什么？

能够编译成一条32bit机器码，并且能被CPU识别和执行

1.1 数据处理指令: 数学运算、逻辑运算

.text				@表示当前段为代码段
.global _start		@声明_start为全局符号
_start:				@汇编程序的入口

        @ 数据搬移指令
        @ MOV R1,#1
        @ R1 = 1
        @ MOV R2,R1
        @ R2 = R1	
        
        @ MVN R0, #0xFF
        @ R0 = ~0xFF   
        
        @ 立即数  
        @ 立即数的本质是包含在指令当中的数，属于指令的一部分
        @
        @ 优点：
        @ 		取指的时候就可以将其读取到CPU，不用单独去内存取，速度快
        @ 缺点：
        @		不能是任意的32位的数字，由局限性 
        @
        @ MOV R0, #0x12345678 (一个数值应该只占指令的一部分，而这里的数值是32bit，不是立即数)
        @ MOV R0, #0x12
        
        @ MOV R0, #0xFFFFFFFF (算是一个伪指令，编译器会把这个编译成CPU认识的，并且是等效效果)
		
		
		@ 编译器替换
		@ MOV R0, #0xFFFFFFFF
		
		@ 数据运算指令基本格式
		@	《操作码》《目标寄存器》《第一操作寄存器》《第二操作数》
		@		操作码			指示执行哪种运算
		@		目标寄存器：	存储运算结果
		@		第一操作寄存器：第一个参与运算的数据（只能是寄存器）
		@		第二操作数：	第二个参与运算的数据（可以是寄存器或立?词?
		
		@ 加法指令
		@ MOV R2, #5
		@ MOV R3, #3
		@ ADD R1, R2, R3
		@ R1 = R2 + R3
		@ ADD R1, R2, #5
		@ R1 = R2 + 5
		
		@ 减法指令
		@ SUB R1, R2, R3
		@ R1 = R2 - R3
		@ SUB R1, R2, #3
		@ R1 = R2 - 3
		
		@ 逆向减法指令
		@ RSB R1, R2, #3
		@ R1 = 3 - R2
		
		@ 乘法指令
		@ MUL R1, R2, R3
		@ R1 = R2 * R3
		@ 乘法指令只能是两个寄存器相乘
		
		@ 按位与指令
		@ AND R1, R2, R3
		@ R1 = R2 & R3
		
		@ 按位或指令
		@ ORR R1, R2, R3
		@ R1 = R2 | R3
		
		@ 按位异或指令（相同为0，相异为1）
		@ EOR R1, R2, R3
		@ R1 = R2 ^ R3
		
		@ 左移指令
		@ MOV R2, #0xF0
		@ MOV R3, #0x2
		@ LSL R1, R2, R3
		@ R1 = (R2 << R3) 
		
		@ 右移指令
		@ LSR R1, R2, R3
		@ R1 = (R2 >> R3)
		
		@ 位清零指令
		@ MOV R2, #0xFF
		@ BIC R1, R2, #0x0F
		@ 第二操作数中的哪一位为1，就将第一操作寄存器的中哪一位清零，然后将结果写入目标寄存器
		
		@ 格式扩展
		@ MOV R2, #3
		@ MOV R1, R2, LSL #1
		@ R1 = (R2 << 1)
		
		@ 数据运算指令对条件位（N、Z、C、V）的影响
		@ 默认情况下数据运算不会对条件位产生影响，在指令后加后缀”S“才可以影响!!!!!!!
		
		@ MOV R2, #3
		@ SUBS R1, R2, #5
		
		@ MOV R2, #0xFFFFFFFF
		@ ADDS R1, R2, #3
		
		@ MOV R2, #0x7FFFFFFF
		@ ADDS R1, R2, #1
		
		@ 带进位的加法指令
		@ 两个64位的数据做加法运算
		@ 第一个数的低32位放在R1
		@ 第一个数的高32位放在R2
		@ 第二个数的低32位放在R3
		@ 第二个数的高32位放在R4
		@ 运算结果的低32位放在R5
		@ 运算结果的高32位放在R6
		
		@ 第一个数
		@ 0x00000001 FFFFFFFF
		@ 第二个数
		@ 0x00000002 00000005
		
		@ MOV R1, #0xFFFFFFFF
		@ MOV R2, #0x00000001
		@ MOV R3, #0x00000005
		@ MOV R4, #0x00000002
		@ ADDS R5, R1, R3
		@ ADC  R6, R2, R4
		@ 本质：R6 = R2 + R4 + 'C' 
		
		@ 带借位的减法指令
		
		@ 第一个数
		@ 0x00000002 00000001
		@ 第二个数
		@ 0x00000001 00000005
		
		@ MOV R1, #0x00000001
		@ MOV R2, #0x00000002
		@ MOV R3, #0x00000005
		@ MOV R4, #0x00000001
		@ SUBS R5, R1, R3
		@ SBC  R6, R2, R4
		@ 本质：R6 = R2 - R4 - '!C'

.global STOP	
STOP:	
		B STOP		@死循环，防止程序跑飞	

.end				@汇编程序的结束

1.2 跳转指令:实现程序的跳转，本质就是修改了PC寄存器

.text				@表示当前段为代码段
.global _start		@声明_start为全局符号
_start:				@汇编程序的入口

		@ 方式一:直接修改PC寄存器的值（不建议使用，需要自己计算目标指令的绝对地址）
@ MAIN:
		@ MOV R1, #1
		@ MOV R2, #2
		@ MOV R3, #3
		@ MOV PC, #0x18
		@ MOV R4, #4
		@ MOV R5, #5	
@ FUNC:
		@ MOV R6, #6
		@ MOV R7, #7
		@ MOV R8, #8
	
		@ 方式二:不带返回的跳转指令，本质就是将PC寄存器的值修改成跳转标号下指令的地址
@ MAIN:
		@ MOV R1, #1
		@ MOV R2, #2
		@ MOV R3, #3
		@ B   FUNC
		@ MOV R4, #4
		@ MOV R5, #5	
@ FUNC:
		@ MOV R6, #6
		@ MOV R7, #7
		@ MOV R8, #8
		
		@ 方式三:带返回的跳转指令，本质就是将PC寄存器的值修改成跳转标号下指令的地址，同时将跳转指令下一条指令的地址存储到LR寄存器
@ MAIN:
		@ MOV R1, #1
		@ MOV R2, #2
		@ MOV R3, #3
		@ BL  FUNC   （这里是 BL, B不能让LR保存返回地址）
		@ MOV R4, #4
		@ MOV R5, #5	
@ FUNC:
		@ MOV R6, #6
		@ MOV R7, #7
		@ MOV R8, #8
		@ MOV PC, LR
		@ 程序返回
		
		@ ARM指令的条件码
		
		@ 比较指令
		@ CMP指令的本质就是一条减法指令（SUBS），只是没有将运算结果存入目标寄存器
		@ MOV R1, #1
		@ MOV R2, #2
		@ CMP R1, R2
		@ BEQ FUNC	
		@ 执行逻辑：if(EQ){B FUNC}	本质：if(Z==1){B FUNC}
		@ BNE FUNC	
		@ 执行逻辑：if(NQ){B FUNC}	本质：if(Z==0){B FUNC}
		@ MOV R3, #3
		@ MOV R4, #4
		@ MOV R5, #5
@ FUNC:
		@ MOV R6, #6
		@ MOV R7, #7

		@ ARM指令集中大多数指令都可以带条件码后缀
		@ MOV R1, #1
		@ MOV R2, #2
		@ CMP R1, R2
		@ MOVGT R3, #3
		
		@ 练习：用汇编语言实现以下逻辑
			@ int R1 = 9;
			@ int R2 = 15;
		@ START:
			@ if(R1 == R2)
			@ {
			@ 	STOP();
			@ }
			@ else if(R1 > R2)
			@ {			
			@ 	R1 = R1 - R2;
			@ 	goto START;
			@ }
			@ else
			@ {
			@ 	R2 = R2 - R1;
			@	goto START;	
			@ }
		
		@ 练习答案
		@ MOV R1, #9
		@ MOV R2, #15
@ START:
		@ CMP R1,R2
		@ BEQ STOP
		@ SUBGT R1, R1, R2
		@ SUBLT R2, R2, R1
		@ B START
@ STOP:				
		@ B STOP
	
	
.global STOP	
STOP:	
		B STOP		@死循环，防止程序跑飞	

.end				@汇编程序的结束

在这里插入图片描述

1.3 Load/Store指令:访问（读写）内存

.text				@表示当前段为代码段
.global _start		@声明_start为全局符号
_start:				@汇编程序的入口

		@ 写内存
		@ MOV R1, #0xFF000000
		@ MOV R2, #0x40000000
		@ STR R1, [R2] 
		@ 将R1寄存器中的数据写入到R2指向的内存空间
		
		@ 读内存
		@ LDR R3, [R2]
		@ 将R2指向的内存空间中的数据读取到R3寄存器
		
		@ 读/写指定的数据类型
		@ MOV R1, #0xFFFFFFFF
		@ MOV R2, #0x40000000
		@ STRB R1, [R2]
		@ 将R1寄存器中的数据的Bit[7:0]写入到R2指向的内存空间
		@ STRH R1, [R2] 	
		@ 将R1寄存器中的数据的Bit[15:0]写入到R2指向的内存空间
		@ STR  R1, [R2] 	
		@ 将R1寄存器中的数据的Bit[31:0]写入到R2指向的内存空间
		
		@ LDR指令同样支持以上后缀
		
		@ 寻址方式就是CPU去寻找操作数的方式
		
		@ 立即寻址
		@ MOV R1, #1      @ 1是立即数
		@ ADD R1, R2, #1  @ 算加法时会用到1，而1被放在了机器码里，CPU就会去机器码里把1取出来
		
		@ 寄存器寻址
		@ ADD R1, R2, R3
		
		@ 寄存器移位寻址
		@ MOV R1, R2, LSL #1
		
		@ 寄存器间接寻址
		@ STR R1, [R2] 
		
		@ ...
		
		@ 基址加变址寻址
		@ MOV R1, #0xFFFFFFFF
		@ MOV R2, #0x40000000
		@ MOV R3, #4
		@ STR R1, [R2,R3]
		@ 将R1寄存器中的数据写入到R2+R3指向的内存空间
		@ STR R1, [R2,R3,LSL #1]
		@ 将R1寄存器中的数据写入到R2+(R3<<1)指向的内存空间
		
		@ 基址加变址寻址的索引方式
		
		@ 前索引
		@ MOV R1, #0xFFFFFFFF
		@ MOV R2, #0x40000000
		@ STR R1, [R2,#8]
		@ 将R1寄存器中的数据写入到R2+8指向的内存空间
		
		@ 后索引
		@ MOV R1, #0xFFFFFFFF
		@ MOV R2, #0x40000000
		@ STR R1, [R2],#8
		@ 将R1寄存器中的数据写入到R2指向的内存空间，然后R2自增8
		
		@ 自动索引
		@ MOV R1, #0xFFFFFFFF
		@ MOV R2, #0x40000000
		@ STR R1, [R2,#8]!
		@ 将R1寄存器中的数据写入到R2+8指向的内存空间，然后R2自增8
		
		@ 以上寻址方式和索引方式同样适用于LDR

		@ 多寄存器内存访问指令
		@ MOV R1, #1
		@ MOV R2, #2
		@ MOV R3, #3
		@ MOV R4, #4
		@ MOV R11,#0x40000020
		@ STM R11,{R1-R4}
		@ 将R1-R4寄存器中的数据写入到以R11为起始地址的内存空间中
		@ LDM R11,{R6-R9}
		@ 将以R11为起始地址的内存空间中的数据读取到R6-R9寄存器中
		
		@ 当寄存器编号不连续时，使用逗号分隔
		@ STM R11,{R1,R2,R4}
		@ 不管寄存器列表中的顺序如何，存取时永远是低地址对应小编号的寄存器
		@ STM R11,{R3,R1,R4,R2} 
		@ 自动索引照样适用于多寄存器内存访问指令
		 STM R11!,{R1-R4}
		
		@ 多寄存器内存访问指令的寻址方式
		@ MOV R1, #1
		@ MOV R2, #2
		@ MOV R3, #3
		@ MOV R4, #4
		@ MOV R11,#0x40000020
		@ STMIA R11!,{R1-R4}
		@ 先存储数据，后增长地址 Increase After
		@ STMIB R11!,{R1-R4}
		@ 先增长地址，后存储数据 Increase Before
		@ STMDA R11!,{R1-R4}
		@ 先存储数据，后递减地址 Decrease After
		@ STMDB R11!,{R1-R4}
		@ 先递减地址，后存储数据 Decrease Before
		

.global STOP	
STOP:	
		B STOP		@死循环，防止程序跑飞	

.end				@汇编程序的结束
栈
.text				@表示当前段为代码段
.global _start		@声明_start为全局符号
_start:				@汇编程序的入口

		@ 栈的种类与使用
		@ MOV R1, #1
		@ MOV R2, #2
		@ MOV R3, #3
		@ MOV R4, #4
		@ MOV R11,#0x40000020
		@ STMFD R11!,{R1-R4}
		@ LDMFD R11!,{R6-R9}  
		
		@ 栈的应用举例
		
		@ 1.叶子函数的调用过程举例
		
		@ 初始化栈指针
		@ MOV SP, #0x40000020
@ MIAN:
		@ MOV R1, #3
		@ MOV R2, #5
		@ BL  FUNC
		@ ADD R3, R1, R2
		@ B STOP
		
@ FUNC:
		@ 压栈保护现场
		@ STMFD SP!, {R1,R2}
		@ MOV R1, #10
		@ MOV R2, #20
		@ SUB R3, R2, R1
		@ 出栈恢复现场
		@ LDMFD SP!, {R1,R2}
		@ MOV PC, LR    
		
		@ 2.非叶子函数的调用过程举例

		@ MOV SP, #0x40000020
@ MIAN:
		@ MOV R1, #3
		@ MOV R2, #5
		@ BL  FUNC1
		@ ADD R3, R1, R2
		@ B STOP		
@ FUNC1:
		@ STMFD SP!, {R1,R2,LR}
		@ MOV R1, #10
		@ MOV R2, #20
		@ BL  FUNC2
		@ SUB R3, R2, R1
		@ LDMFD SP!, {R1,R2,LR}
		@ MOV PC, LR
@ FUNC2:
		@ STMFD SP!, {R1,R2}
		@ MOV R1, #7
		@ MOV R2, #8
		@ MUL R3, R1, R2
		@ LDMFD SP!, {R1,R2}
		@ MOV PC, LR
		
		@ 执行叶子函数时不需要对LR压栈保护，执行非叶子函数时需要对LR压栈保护


.global STOP	
STOP:	
		B STOP		@死循环，防止程序跑飞	

.end				@汇编程序的结束

为什么C中用局部变量时要先初始化？

局部变量在调用的时候临时在栈里分配空间（比如：int a ）,栈指针指到那儿，a的空间就分配到那儿，但是这些空间之前可能就已经存有数据，如果不初始化，a的值就是之前的这些数据

为什么C中全局变量不用初始化就是0？

如果全局变量没有初始化，编译器编译时，会把它放在BSS段 ，而操作系统在调用程序前会执行一段代码，这段代码会把BSS段清零

1.4 状态寄存器传送指令:访问（读写）CPSR寄存器

.text				@表示当前段为代码段
.global _start		@声明_start为全局符号
_start:				@汇编程序的入口

	@ 1.4 状态寄存器传送指令:访问（读写）CPSR寄存器
	
		@ 读CPSR
		@ MRS R1, CPSR
		@ R1 = CPSR
		
		@ 写CPSR
		@ MSR CPSR, #0x10
		@ CPSR = 0x10
		
		@ 在USER模式下不能随意修改CPSR，因为USER模式属于非特权模式
		@ MSR CPSR, #0xD3
	

.global STOP	
STOP:	
		B STOP		@死循环，防止程序跑飞	

.end				@汇编程序的结束

1.5 软中断指令:触发软中断

在这里插入图片描述

  • 当复位或者软中断时，CPU进入SVC模式
  • CPU刚上电时，默认是ARM状态
  • CPU在刚上电时，会进行一些核心的初始化工作，在执行这些程序时不希望被外界（比如网卡，键盘等）的影响；当操作系统启动完成以后，应用程序能够运行时，CPU才会对外围的硬件的一些信号做出响应；
    故，刚上电时FIQ和IRQ禁止
.text				@表示当前段为代码段
.global _start		@声明_start为全局符号
_start:				@汇编程序的入口


		@ 异常向量表
		@ B MAIN
		@ B .
		@ B SWI_HANDLER
		@ B .
		@ B .
		@ B .
		@ B .
		@ B .
		
		@ 应用程序
@ MAIN:
		@ MOV SP, #0x40000020        
		@ 初始化SVC模式下的栈指针（不同模式的R13(SP)寄存器都不一样）！！！！！！
		@ MSR CPSR, #0x10
		@ 切换成USER模式，开启FIQ、IRQ
		@ MOV R1, #1
		@ MOV R2, #2
		@ SWI #1
		@ 触发软中断异常
		@ ADD R3, R2, R1
		@ B STOP
		
		@ 异常处理程序
@ SWI_HANDLER:
		@ STMFD SP!,{R1,R2,LR}
		@ 压栈保护现场
		@ MOV R1, #10
		@ MOV R2, #20
		@ SUB R3, R2, R1
		@ LDMFD SP!,{R1,R2,PC}^
		@ 出栈恢复现场
		@ 将压入到栈中的LR（返回地址）出栈给PC，实现程序的返回
		@ ‘^’表示出栈的同时将SPSR的值传递给CPSR，实现CPU状态的恢复


.global STOP	
STOP:	
		B STOP		@死循环，防止程序跑飞	

.end				@汇编程序的结束

1.6 协处理器指令:操控协处理器的指令

	@ 1.协处理器数据运算指令
	@	CDP
	@ 2.协处理器存储器访问指令
	@	STC	将协处理器中的数据写入到存储器
	@	LDC	将存储器中的数据读取到协处理器
	@ 3.协处理器寄存器传送指令
	@	MRC	将协处理器中寄存器中的数据传送到ARM处理器中的寄存器
	@	MCR	将ARM处理器中寄存器中的数据传送到协处理器中的寄存器

2.伪指令

伪指令是什么？

本身不是指令，编译器可以将其替换成若干条等效指令

	@ 空指令
	@ NOP
	
	@ 指令
	@ LDR R1, [R2]
	@ 将R2指向的内存空间中的数据读取到R1寄存器
	
	@ 伪指令
	@ LDR R1, =0x12345678
	@ R1 = 0x12345678	
	@ LDR伪指令可以将任意一个32位的数据放到一个寄存器
	
	@ LDR R1, =STOP
	@ 将STOP表示的地址写入R1寄存器
	
	@ LDR R1, STOP
	@ 将STOP地址中的内容写入R1寄存器

3.伪操作

伪操作是什么？

不会生成代码，只是在编译之前告诉编译器怎么编译

	@ GNU的伪操作一般都以‘.’开头
	
	@ .global symbol
	@ 将symbol声明成全局符号
	
	@ .local symbol
	@ 将symbol声明成局部符号
	
	@ .equ DATA, 0xFF
	@ MOV R1, #DATA
	
	@ .macro FUNC
	@	MOV R1, #1
	@	MOV R2, #2
	@ .endm
	@ FUNC
	
	@ .if 0
	@	MOV R1, #1
	@	MOV R2, #2
	@ .endif

	@.rept 3
	@ 	MOV R1, #1
	@ 	MOV R2, #2
	@.endr
	
	@ .weak symbol
	@ 弱化一个符号，即告诉编译器即便没有这个符号也不要报错
	@ .weak func
	@ B func
	
	@ .word VALUE
	@ 在当前地址申请一个字的空间并将其初始化为VALUE
	@ MOV R1, #1
	@ .word 0xFFFFFFFF
	@ MOV R2, #2
	
	@ .byte VALUE	
	@ 在当前地址申请一个字节的空间并将其初始化为VALUE
	@ MOV R1, #1
	@ .byte 0xFF
	
	@ .align N
	@ 告诉编译器后续的代码2的N次方对其
	@ .align 4
	@ MOV R2, #2
	
	@ .arm
	@ 告诉编译器后续的代码是ARM指令
	
	@ .thumb
	@ 告诉编译器后续的代码是Thumb指令
	
	@ .text				
	@ 定义一个代码段
	
	@ .data				
	@ 定义一个数据段
	
	@ .space N, VALUE
	@ 在当前地址申请N个字节的空间并将其初始化为VALUE
	@ MOV R1, #1
	@ .space 12, 0x12
	@ MOV R2, #2
	
	@ 不同的编译器伪操作的语法不同

C和汇编的混合编程

C和汇编的混合编程原则：在哪种语言环境下符合哪种语言的语法规则

1）在汇编中将C中的函数当做标号处理
2）在C中将汇编中的标号当做函数处理
3）在C中内联的汇编当做C的语句来处理

arm-asm.s

 1. 方式一：汇编语言调用（跳转）C语言

			@ MOV R1, #1
			@ MOV R2, #2
			@ BL  func_c		@结束后自动跳到下一条指令，因为c语言编译后最后是一个语句是跳转
			@ MOV R3, #3
		
2. 方式二：C语言调用（跳转）汇编语言

@ .global FUNC_ASM
@ FUNC_ASM:
			@ MOV R4, #4
			@ MOV R5, #5
			
3. C内联（内嵌）汇编 （往下看）

main.c

void func_c(void)
{
	int a;
	a ++;
	//C内联（内嵌）汇编
	asm
	(
		"MOV R6, #6\n"
		"MOV R7, #7\n"
	);
	//C语言调用（跳转）汇编语言
	FUNC_ASM();
	a --;
}

ATPCS协议(ARM-THUMB Procedure Call Standard)

@ ATPCS协议主要内容 

	@ 1.栈的种类
	@ 	1.1 使用满减栈

	@ 2.寄存器的使用
	@	2.1 R15用作程序计数器，不能作其他用途	
	@ 	2.2 R14用作链接寄存器，不能作其他用途
	@	2.3 R13用作栈指针，不能作其他用途
	@	2.4 当函数的参数不多于4个时使用R0-R3传递，当函数的参数多于4个时，多出的部分用栈传递
	@	2.5	函数的返回值使用R0传递
	@ 	2.6 其它寄存器主要用于存储局部变量
【arm体系结构与编程】1.概述及其基本编程模型（一）
xxf102601的博客
09-28 904
1.版本及其命名方法 ARMv+[版本号]+[变种的字符]+[字符x+排除某种功能的字符] 1.1 ARM体系的变种 ①Thumb指令集（T变种） 与ARM指令集的32位长度对应，Thumb指令集的长度仅为16位。其与ARM指令集相比有如下局限性：完成形同的指令需要更多的指令，也就是说耗时更长；没有     包含进行异常处理的一些指令。 ②长乘法指令（M变种） 共两条指令：【32位整数
ARM协处理器
yongan1006的专栏
11-24 692
ARM920T协处理器接口 ARM920T处理器通过一个外部协处理器接口来支持连接片上协处理器。ARM处理器支持所有的协处理器指令。 ARM920T协处理器接口允许你附加一个专门设计的协处理器到ARM920T。包括： 1.附加一个加速器：用于浮点运算，DSP，3-D图形，加密解密。 2.ARM指令集可支持连接多达16个协处理器到ARM处理器，编号为0~15 内部协处理
ARM体系结构及接口技术-01ARM基础（ARM基本概念，工作模式，寄存器功能）
Clear Code
05-28 1861
文章目录认识ARM嵌入式产品ARM公司ARM 全球分布ARM 产品线授权的厂商ARM 体系架构ARM系统硬件组成和运行原理数据和指令类型程序计数器PC (r15)字节顺序ARM的工作模式及寄存器ARM主要有7个基本工作模式ARM 有37个寄存器ARM 工作模式及寄存器框图CPSR 寄存器测验1) ARM有哪些工作模式？2) ARM核有多少个寄存器？3) PC和LR寄存器的别名？4) R13别名是什...
物联网之ARM体系结构及接口技术一（ARM基础）
许新天的博客
09-07 1978
ARM基础 认识ARM ARM 产品线： ARM 体系架构：不同ARM体系采用不同的指令集，哈弗结构是数据和指令分开存储并行（现在都是基于这种结构），早期的冯诺依曼（普林斯顿）结构是混合存储的 ARM系统硬件组成和运行原理： 手机程序存储在FLASH中，板子上电之后CPU会将程序搬到内存中进行执行（提高执行速率） 控制器找到FLASH程序的地址，然后把指令取出来 运算器用于指令的...
ARM体系结构及接口技术(部分理论知识）
weixin_38717634的博客
02-18 4018
一、ARM相关的概念 1.1ARM的发展历史 1978年，CPU公司 Cambridge processing Unit 1979年 Acorn 1985年， 32位，8MHz， 使用的精简指令集RISC 芯片的名字ARM ----> Acorn RISC machine 1990年，转折点 iphone 150万英镑 VLSI: 25万英镑 ARM公司12工程师+技术专利：150万英镑 ARM公司-> Advanced RISC Machine ARM公司不生产芯片，做技术的授权，提供
嵌入式学习LV9-ARM体系结构与接口技术- D9. 专用指令作业
07-31
在嵌入式系统的学习中，ARM（Advanced RISC Machines）架构是极其重要的一环，尤其在LV9级别的学习中，深入理解ARM体系结构及其接口技术是必不可少的。本主题聚焦于ARM处理器的工作模式管理和中断处理机制，特别是...
ARM嵌入式体系结构与接口技术（Cortex-A53版）（微课版）-源代码.zip
06-29
《ARM嵌入式体系结构与接口技术（Cortex-A53版）（微课版）-源代码》这个压缩包文件包含的是与ARM Cortex-A53处理器相关的嵌入式系统开发源代码，这对于理解该处理器的工作原理以及进行相关应用开发至关重要。...
ARM体系结构与编程---第一章.ppt
最新发布
07-18
根据提供的文件信息，我们可以深入探讨《ARM体系结构与编程》这一课程所涵盖的关键知识点，尤其聚焦于嵌入式系统的基础概念及其在ARM架构中的具体应用。 ### 一、ARM架构概述 #### ARM简介 - **ARM公司**：ARM是...
ARM体系结构与接口技术.pdf
06-20
《ARM体系结构与接口技术》一书主要涵盖了嵌入式领域中ARM处理器的基本知识、系统构建以及实际应用，特别关注了Cortex-A9处理器的架构和技术。ARM处理器，全称Advanced RISC Machines，是由英国Acorn公司设计的一种...
ARM体系结构与编程ARM-TDMI(与“指令”有关文档共89张).pptx
11-14
ARM体系结构与编程主要涉及的是ARM处理器的设计理念和编程模型，特别是ARM-TDMI（Thumb Data Movement Instruction）这一特定指令集。ARM处理器是基于RISC（精简指令集计算机）架构的，与传统的CISC（复杂指令集...
ARM硬件完美解读——协处理器
Jaguar.Yuan技术专区——专注嵌入式
11-06 1960
1、协处理器是哪位大神 协处理器（coprocessor），一种芯片，用于减轻系统微处理器的特定处理任务。例如，数学协处理器可以控制数字处理；图形协处理器可以处理视频绘制。例如，intel pentium 微处理器就包括内置的数学协处理器。协处理器可以附属于ARM处理器。一个协处理器通过扩展指令集或提供配置寄存器来扩展内核处理功能。一个或多个协处理器可以通过协处理器接口与ARM内核相连。协处理器
ARM开发（5）ARM的接口技术（串行通信与并行通信，同步串行通信与异步串行通信，波特率，串行通信术语，uart，i2c，spi三种协议简单引入）
fuyuyf的博客
08-11 1294
ARM的接口技术（串行通信与并行通信，同步串行通信与异步串行通信，波特率，串行通信术语，uart，i2c，spi三种协议简单引入）
lv9-ARM体系结构与接口技术(5-10) ARM指令
weixin_44967337的博客
12-09 787
.
ARM V8A体系结构-第九章 ARM64平台的ABI（Application Binary Interface ）
u010681589的博客
01-11 2452
概述 ARM体系结构的应用程序二进制接口（ABI）指定了所有可执行本机代码模块必须遵守的基本规则，以便它们能够正确地协同工作。这些基本规则由特定编程语言（例如C++）的附加规则补充。单个操作系统或执行环境（例如Linux）可能会指定附加规则以满足其自身的特定需求，而不是ARM ABI指定的规则。 AArch64体系结构的ABI有许多组件： 可执行和可链接格式（ELF）：ARM 64位体系结构（AArch64）的ELF指定对象和可执行格式。 程序调用标准（PCS）：ARM 64位体系结构（AArch64）A
【汇编语言】ARM汇编三：数据处理指令
LynnZhang的博客
07-07 1669
二、示例：编程实现使用32bit的ARM处理器实现两个128位的数据的加法运算
嵌入式：ARM存储器组织、协处理器及片上总线
timerring的博客
12-13 1052
寄存器组 : 存储器层次的顶层，典型为32个32位寄存器，访问时间为几个ns片上RAM ：和片上寄存器组具有同级的读写速度。成本较高。片上Cache ：容量为8~32KB，访问时间大概为10ns。主存储器 ：可能在几兆到1G的动态存储器。访问时间大约50ns。硬盘：后援存储器，容量从几百兆到几十GB，访问时间为几十ms。嵌入式系统通常没有硬盘，因此也不采用页方式，但是许多嵌入式系统采用cache，ARM CPU采用了多种Cache结构。
ARM协处理器介绍
倚楼听风雨的博客
11-15 1万+
什么是协处理器　　协处理器是一种芯片，用于减轻系统微处理器的特定处理任务。例如，数学协处理器可以控制数字处理；图形协处理器可以处理视频绘制。例如，intel pentium微处理器就包括内置的数学协处理器。 　　协处理器可以附属于ARM处理器。一个协处理器通过扩展指令集或提供配置寄存器来扩展内核处理功能。一个或多个协处理器可以通过协处理器接口与ARM内核相连。 　　协处理器可以通过一组专门的、提
ARM调试原理【调试接口框图】【SWD时序】【SWD主机】
热门推荐
挖到尽头
04-10 2万+
调试接口框图      ARM-M0《ARM Cortex-M0.pdf》手册上提到的调试框图如下：     《debug_interface_v6_0_architecture_specification_IHI0074A.pd》提到的调试框图如下：       由此可知DAP中分为了AP和DP     再看m3内核框图：      从这里可以看到AP是在芯片中的，而...
操作符指令 - ARM汇编指令（二）
生活需要深度
03-04 2116
加减乘除基本计算指令
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值