Erlang——OTP

已于 2023-09-18 23:37:52 修改
阅读量159 收藏
点赞数
文章标签： qt 开发语言
于 2023-09-11 22:22:15 首次发布
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/weixin_52671611/article/details/132650991
版权

Erlang——OTP


OTP，应用程序操作系统，用了构造容错系统。

1.服务器进化历程

原始服务器程序

服务器的基本模式（通过回调模块定制）：

-module(server1).
%%最初的服务器程序
-author("").
%%%=======================EXPORT=======================
-export([start/2, rpc/2]).
start(Name, Mod) ->
	register(Name, spawn(fun() ->loop(Name, Mod, Mod:init()) end)).
rpc(Name, Request) ->
	Name ! {self(), Request},
	receive
		{Name, Response} ->Response
	end.

loop(Name, Mod, State) ->
	receive
		{From, Request} ->
			{Response, State1} = Mod:handle(Request, State),
			From ! {Name, Response},
			loop(Name, Mod, State1)
	end.

server1的回调函数：

-module(name_server).
-author("").
%%%=======================EXPORT=======================
-import(server1, [rpc/2]).
%%server1的回调程序
-export([init/0, add/2, whereis/1, handle/2]).
%%远程调用向指定的服务名发送请求
add(Name, Place) ->rpc(name_server, {add, Name, Place}).
whereis(Name)    ->rpc(name_server, {whereis, Name}).
init() ->dict:new().
handle({add, Name, Place}, Dict) ->{ok, dict:store(Name, Place, Dict)};
handle({whereis, Name}, Dict)    ->{dict:find(Name, Dict), Dict}.

他是服务器的回到程序，负责处理框架发过来的调用请求；并且定义了客户端调用的常规接口。
测试结果：

1> server1:start(name_server,name_server).
true
2> name_server:add(harry,"at home").
ok 
3> name_server:whereis(harry).
{ok,"at home"}

支持事务的服务器程序

代码演示：

-module(server2).
-author("").
%%%=======================EXPORT=======================
-export([start/2, rpc/2]).
start(Name, Mod) ->
  register(Name, spawn(fun() -> loop(Name, Mod, Mod:init()) end)).
rpc(Name, Request) ->
  Name ! {self(), Request},
  receive
    {Name, crash} -> exit(rpc);
    {Name, ok, Response} -> Response
  end.

loop(Name, Mod, OldState) ->
  receive
    {From, Request} ->
      try Mod:handle(Request, OldState) of
        {Response, NewState} ->
          From ! {Name, ok, Response},
          loop(Name, Mod, NewState)
      catch
        _:Why ->
          log_the_error(Name, Request, Why),
          From ! {Name, crash},
          loop(Name, Mod, OldState)
      end
  end.
log_the_error(Name, Request, Why) ->
  io:format("Server ~p request ~p ~n"
  "caused exception ~p ~n",
    [Name, Request, Why]).

在请求导致服务器程序出现异常时，会让客户端代码异常退出。
这个版本的服务器提供了一种事务机制，如果在handler函数中发生了异常，他会用之前的状态进行循环，只有当handler函数正常返回时，才会用handler函数返回的新状态进行循环。之所以要保留前一个状态，是当handler函数失效时，发起调用的客户端会收到一个让他立刻退出的消息。因为请求导致了handler函数失败，所以客户端的调用是无法成功的，但受到影响的也只有这一个客户端而已，连到同一服务器上，其他客户端不会受到任何影响。另外，当handler函数中发生错误时，服务器的状态也没有因此而发生任何改变。
相较上个版本回调模块，没有任何改动（只需要改下导入的模块名，改成了server2即可），只是改变了服务器代码本身，我们可以独立的对非功能的行为部分进行更改，功能性的部分不受影响。

支持热代码替换的服务器程序

-module(server3).
-author("").
-export([start/2, rpc/2, swap_code/2]).
start(Name, Mod) ->
  register(Name, spawn(fun() -> loop(Name, Mod, Mod:init()) end)).
swap_code(Name, Mod) -> rpc(Name, {swap_code, Mod}).
rpc(Name, Request) ->
  Name ! {self(), Request},
  receive
    {Name, Response} -> Response
  end.

loop(Name, Mod, OldState) ->
  receive
    {From, {swap_code, NewCallBackMod}} ->
      From ! {Name, ack},
      loop(Name, NewCallBackMod, OldState);
    {From, Request} ->
      {Response, NewState} = Mod:handle(Request, OldState),

      From ! {Name, Response},
      loop(Name, Mod, NewState)
  end.

他硬编码了服务器的名字，做一个新的name_server1

-module(name_server1).
-author("").
-import(server3, [rpc/2]).
-export([init/0, add/2, whereis/1, handle/2]).
add(Name, Place) ->rpc(name_server, {add, Name, Place}).
whereis(Name)    ->rpc(name_server, {whereis, Name}).
init() ->dict:new().
handle({add, Name, Place}, Dict) ->{ok, dict:store(Name, Place, Dict)};
handle({whereis, Name}, Dict)    ->{dict:find(Name, Dict), Dict}.

用name_server1启动server3：

1> server3:start(name_server,name_server1).
true
2> name_server:add(harry,"at home").
ok 
3> name_server:add(moka,"at work").
ok

可成功存入

同时支持事务和热代码替换的服务器程序

-module(server4).
-author("").
%%%=======================EXPORT=======================
-export([start/2, rpc/2, swap_code/2]).
start(Name, Mod) ->
  register(Name, spawn(fun() -> loop(Name, Mod, Mod:init()) end)).
swap_code(Name, Mod) -> rpc(Name, {swap_code, Mod}).
rpc(Name, Request) ->
  Name ! {self(), Request},
  receive
    {Name, crash} -> exit(rpc);
    {Name, Response} -> Response
  end.

loop(Name, Mod, OldState) ->
  receive
    {From, {swap_code, NewCallBackMod}} ->
      From ! {Name, ok, ack},
      loop(Name, NewCallBackMod, OldState);
    {From, Request} ->
      try Mod:handle(Request, OldState) of
        {Response, NewState} ->
          From ! {Name, ok, Response},
          loop(Name, Mod, NewState)
      catch
        _:Why ->
          log_the_error(Name, Request, Why),
          From ! {Name, crash},
          loop(Name, Mod, OldState)
      end
  end.
log_the_error(Name, Request, Why) ->
  io:format("Server ~p request ~p ~n"
  "caused exception ~p ~n",
    [Name, Request, Why]).

可以同时支持事务机制和热代码替换

支持热代码替换的服务器程序

不提供服务，直至接收到指令：

-module(server5).
-author("").
-export([start/0, rpc/2]).
start() ->
  spawn(fun() -> wait() end).
rpc(Pid, Q) ->
  Pid ! {self(), Q},
  receive
    {Pid, Reply} -> Reply
  end.
wait() ->
  receive
    {become, F} ->
      F()
  end.

定义服务器函数：

-module(my_fac_server).
-author("").
%%%=======================EXPORT=======================
-export([loop/0]).
loop() ->
  receive
    {From, {fac, N}} ->
      From ! {self(), fac(N)},
      loop();
    {become,Something} ->
      Something()
  end.
fac(0)->1;
fac(N)->N*fac(N-1).

发送可实现阶乘运算：

1> c(my_fac_server).
{ok,my_fac_server}
2> Pid=server5:start().
<0.84.0>
3> Pid!{become,fun my_fac_server:loop/0}.
{become,fun my_fac_server:loop/0}
4> server5:rpc(Pid,{fac,30}).    
265252859812191058636308480000000

2.gen_server

模块

以一个简单的支付系统为例（my_bank）

-module(my_bank).
-author("wangjiaqi").
-export([start/0,stop/0,new_account/1,deposit/2,withdraw/2]).
start()-> %  打开银行
  gen_server:start_link({local,?MODULE},?MODULE,[],[]).
stop()-> %  关闭银行
  gen_server:call(?MODULE,stop).
new_account(Who)-> %  开一个新账户
  gen_server:call(?MODULE, {new,Who}).
deposit(Who,Amount)-> %  存钱
  gen_server:call(?MODULE, {add,Who,Amount}).
withdraw(Who,Amount)-> %  取钱（判断余额是否够用）
  gen_server:call(?MODULE, {remove,Who,Amount}).

?MODULE宏展开时会对应模块名称即my_bank
gen_server:start_link启动一个本地服务器
gen_server:call函数用于发起对服务器的远程调用

回调函数

-export([start_link/0,init/1,handle_call/3,handle_cast/2,handle_info/2,terminate/2,code_change/3]).
start_link()->gen_server:start_link({local,?MODULE},?MODULE,[],[]).
init([])->{ok,ets:new(?MODULE,[])}.
handle_call({new,Who},_From,Tab)->
  Reply=case ets:lookup(Tab,Who) of
          []->
            ets:insert(Tab, {Who,0}),
            {welcome,Who};
          [_]->
            {Who,you_already_are_a_customer}
        end,
  {reply,Reply,Tab};
handle_call({add,Who,X},_From,Tab)->
  Reply=case ets:lookup(Tab,Who) of
          []->
            not_a_customer;
          [{Who,Balance}]->
            NewBalance=Balance+X,
            ets:insert(Tab, {Who,NewBalance}),
            {thanks,Who,your_balance_is,NewBalance}
        end,
  {reply,Reply,Tab};
handle_call({remove,Who,X},_From,Tab)->
  Reply=case ets:lookup(Tab,Who) of
          []->
            not_a_customer;
          [{Who,Balance}] when X=<Balance->
            NewBalance=Balance-X,
            ets:insert(Tab, {Who,NewBalance}),
            {thanks,Who,your_balance_is,NewBalance};
          [{Who,Balance}] ->
            {sorry,Who,your_only_have,Balance,in_the_bank}
        end,
  {reply,Reply,Tab};
handle_call(stop,_From,Tab)->
  {stop,normal,stopped,Tab}.
handle_cast(_Msg,State)->{noreply,State}.
handle_info(_Info,State)->{noreply,State}.
terminate(_Request,_State)->ok.
code_change(_OldVsn,State,Extra)->{ok,State}.

通过gen_server:start_link调用启动服务器程序，回调模块的第一个被调用的函数是init，他返回{ok,State}.State值会作为handle_call函数的第三个参数再次出现.
handle_call(stop,_From,Tab)终止服务器程序,返回{stop,normal,stopped,Tab},是终止服务器的方法。normal作为terminate的参数，stopped会成为my_rank:stop()的返回值。
整合代码：

-module(my_bank).
%%%=======================EXPORT=======================
-export([start/0,stop/0,new_account/1,deposit/2,withdraw/2]).
-export([init/1, handle_call/3, handle_cast/2, handle_info/2,
  terminate/2, code_change/3]).
-define(SERVER, ?MODULE).
%%%=======================INCLUDE======================
%%%=======================RECORD=======================
%%%=======================DEFINE=======================
%%%=======================TYPE=========================
%%%=================EXPORTED FUNCTIONS=================
%% ----------------------------------------------------
%% Description:
%% ----------------------------------------------------
start()-> %  打开银行
  gen_server:start_link({local,?MODULE},?MODULE,[],[]).
stop()-> %  关闭银行
  gen_server:call(?MODULE,stop).
new_account(Who)-> %  开一个新账户
  gen_server:call(?MODULE, {new,Who}).
deposit(Who,Amount)-> %  存钱
  gen_server:call(?MODULE, {add,Who,Amount}).
withdraw(Who,Amount)-> %  取钱（判断余额是否够用）
  gen_server:call(?MODULE, {remove,Who,Amount}).
start_link() ->
  gen_server:start_link({local, ?SERVER}, ?MODULE, [], []).

init([])->{ok,ets:new(?MODULE,[])}.
handle_call({new,Who},_From,Tab)->
  Reply=case ets:lookup(Tab,Who) of
          []->
            ets:insert(Tab, {Who,0}),
            {welcome,Who};
          [_]->
            {Who,you_already_are_a_customer}
        end,
  {reply,Reply,Tab};
handle_call({add,Who,X},_From,Tab)->
  Reply=case ets:lookup(Tab,Who) of
          []->
            not_a_customer;
          [{Who,Balance}]->
            NewBalance=Balance+X,
            ets:insert(Tab, {Who,NewBalance}),
            {thanks,Who,your_balance_is,NewBalance}
        end,
  {reply,Reply,Tab};
handle_call({remove,Who,X},_From,Tab)->
  Reply=case ets:lookup(Tab,Who) of
          []->
            not_a_customer;
          [{Who,Balance}] when X=<Balance->
            NewBalance=Balance-X,
            ets:insert(Tab, {Who,NewBalance}),
            {thanks,Who,your_balance_is,NewBalance};
          [{Who,Balance}] ->
            {sorry,Who,your_only_have,Balance,in_the_bank}
        end,
  {reply,Reply,Tab};
handle_call(stop,_From,Tab)->
  {stop,normal,stopped,Tab}.

handle_cast(_Msg, State) ->
  {noreply, State}.

handle_info(_Info, State) ->
  {noreply, State}.

terminate(_Reason, _State) ->
  ok.

code_change(_OldVsn, State, Extra) ->
  {ok, State}.

运行结果：

1> c(my_bank).                    
my_bank.erl:34: Warning: function start_link/0 is unused
my_bank.erl:81: Warning: variable 'Extra' is unused
{ok,my_bank}
2> my_bank:start().
{ok,<0.84.0>}
3> my_bank:deposit("harry",100).
not_a_customer
4> my_bank:new_account("harry").
{welcome,"harry"}
5> my_bank:deposit("harry",100).
{thanks,"harry",your_balance_is,100}
6> my_bank:deposit("harry",121).
{thanks,"harry",your_balance_is,221}
7> my_bank:withdraw("harry",10).
{thanks,"harry",your_balance_is,211}
8> my_bank:withdraw("harry",300).
{sorry,"harry",your_only_have,211,in_the_bank}

输入为非数字型会报错，所有数据丢失
改进（加输入容错）：

-module(my_bank).
%% API
-export([start/0, stop/0, new_account/1, deposit/2, withdraw/2]).
-export([init/1, handle_call/3, handle_cast/2, handle_info/2,
  terminate/2, code_change/3]).
-define(SERVER, ?MODULE).
-define(DATA_FILE, "bank_data.txt").
-define(DATA_PATH, "./").

start() -> gen_server:start_link({local, ?SERVER}, ?MODULE, [], []).
stop()  -> gen_server:call(?MODULE, stop).

new_account(Who)      -> gen_server:call(?MODULE, {new, Who}).
deposit(Who, Amount)  -> gen_server:call(?MODULE, {add, Who, Amount}).
withdraw(Who, Amount) -> gen_server:call(?MODULE, {remove, Who, Amount}).

init([]) ->
  case filelib:find_file(?DATA_FILE, ?DATA_PATH) of
    {ok, _} -> %% 文件存在，加载数据
      ets:file2tab(?DATA_PATH ++ ?DATA_FILE); %% {ok, Tab}
    {error, not_found} -> %% 文件不存在，新建文件
      {ok, ets:new(?MODULE, [named_table])}
  end.

handle_call({new, Who}, _From, Tab) ->
  Reply = case ets:lookup(Tab, Who) of
            []  ->
              ets:insert(Tab, {Who, 0}),
              {welcome};
            [_] ->
              {you_already_are_a_customer}
          end,
  {reply, Reply, Tab};

handle_call({add, Who, Amount}, _From, Tab) when Amount > 0 ->
  Reply = case ets:lookup(Tab, Who) of
            []  ->
              {not_a_customer};
            [{Who, Balance}] ->
              NewBalance = Balance + Amount,
              ets:insert(Tab, {Who, NewBalance}),
              {success, now_balance_is, NewBalance}
          end,
  {reply, Reply, Tab};
handle_call({add, _, _}, _, Tab) ->
  {reply, {error}, Tab};

handle_call({remove, Who, Amount}, _From, Tab) when Amount > 0 ->
  Reply = case ets:lookup(Tab, Who) of
            []  ->
              {not_a_customer};
            [{Who,Balance}] when Amount =< Balance ->
              NewBalance = Balance - Amount,
              ets:insert(Tab, {Who, NewBalance}),
              {success, now_balance_is, NewBalance};
            [{Who,Balance}] ->
              {error, you_only_have, Balance}
          end,
  {reply, Reply, Tab};
handle_call({remove, _, _}, _, Tab) ->
  {reply, {error}, Tab};

handle_call(stop, _From, Tab) ->
  {stop, normal, stopped, Tab}.
handle_cast(_Msg, State) -> {noreply, State}.
handle_info(_Info, State) -> {noreply, State}.
terminate(_Reason, _State) ->
  Result = ets:tab2file(?MODULE, ?DATA_PATH ++ ?DATA_FILE),
  io:format("~p~n", [Result]),
  ok.
code_change(_OldVsn, State, _Extra) -> {ok, State}.

执行结果：

1> c(my_bank).
{ok,my_bank}
2> my_bank:start().
{ok,<0.84.0>}
3> my_bank:new_account(harry).
{welcome}
4> my_bank:deposit(harry,100).
{success,now_balance_is,100}
5> my_bank:withdraw(harry,25). 
{success,now_balance_is,75}
6> my_bank:deposit(harry,x). 
ok                                                                           
=ERROR REPORT==== 18-Sep-2023::23:33:15.983000 ===
** Generic server my_bank terminating
** Last message in was {add,harry,x}
** When Server state == my_bank
** Reason for termination ==
** {badarith,[{erlang,'+',[75,x],[]},
              {my_bank,handle_call,3,[{file,"my_bank.erl"},{line,200}]},     
              {gen_server,try_handle_call,4,
                          [{file,"gen_server.erl"},{line,661}]},
              {gen_server,handle_msg,6,[{file,"gen_server.erl"},{line,690}]},
              {proc_lib,init_p_do_apply,3,
                        [{file,"proc_lib.erl"},{line,249}]}]}
** Client <0.77.0> stacktrace
** [{gen,do_call,4,[{file,"gen.erl"},{line,167}]},
    {gen_server,call,2,[{file,"gen_server.erl"},{line,211}]},
    {erl_eval,do_apply,6,[{file,"erl_eval.erl"},{line,684}]},
    {shell,exprs,7,[{file,"shell.erl"},{line,686}]},
    {shell,eval_exprs,7,[{file,"shell.erl"},{line,642}]},
    {shell,eval_loop,3,[{file,"shell.erl"},{line,627}]}]

=CRASH REPORT==== 18-Sep-2023::23:33:15.983000 ===
  crasher:
    initial call: my_bank:init/1
    pid: <0.84.0>
    registered_name: my_bank
    exception error: an error occurred when evaluating an arithmetic expression
      in operator  +/2
         called as 75 + x
      in call from my_bank:handle_call/3 (my_bank.erl, line 200)
      in call from gen_server:try_handle_call/4 (gen_server.erl, line 661)
      in call from gen_server:handle_msg/6 (gen_server.erl, line 690)
    ancestors: [<0.77.0>]
    message_queue_len: 0
    messages: []
    links: [<0.77.0>]
    dictionary: []
    trap_exit: false
    status: running
    heap_size: 2586
    stack_size: 27
    reductions: 10198
  neighbours:
    neighbour:
      pid: <0.77.0>
      registered_name: []
      initial_call: {erlang,apply,2}
      current_function: {gen,do_call,4}
      ancestors: []
      message_queue_len: 0
      links: [<0.64.0>,<0.84.0>]
      trap_exit: false
      status: waiting
      heap_size: 987
      stack_size: 33
      reductions: 7427
      current_stacktrace: [{gen,do_call,4,[{file,"gen.erl"},{line,167}]},
                  {gen_server,call,2,[{file,"gen_server.erl"},{line,211}]},
                  {erl_eval,do_apply,6,[{file,"erl_eval.erl"},{line,684}]},
                  {shell,exprs,7,[{file,"shell.erl"},{line,686}]},
                  {shell,eval_exprs,7,[{file,"shell.erl"},{line,642}]},
                  {shell,eval_loop,3,[{file,"shell.erl"},{line,627}]}]
** exception exit: badarith
     in operator  +/2
        called as 75 + x
     in call from my_bank:handle_call/3 (my_bank.erl, line 200)
     in call from gen_server:try_handle_call/4 (gen_server.erl, line 661)
     in call from gen_server:handle_msg/6 (gen_server.erl, line 690)
     in call from proc_lib:init_p_do_apply/3 (proc_lib.erl, line 249)
7> my_bank:start().
{ok,<0.95.0>}
8> my_bank:deposit(harry,100).
{success,now_balance_is,175}

可见尽管输入字母会报错，但重新开启后数据仍存在。

weixin_52671611
关注
  • 0
    点赞
  • 踩
  • 0
    收藏
    觉得还不错? 一键收藏
  • 0
    评论
erlang22最新下载包
11-01
erlang22最新下载包 erlang22.1.tar.gz erlang22最新下载包 erlang22最新下载包
Erlang-otp_win64_23.0.zip
06-07
rabbitmq安装前的环境安装，Erlang23.0 Windows64安装包，官网下载了几个小时
javasnmp源码-docker-erlang-otp:DockerHub上的官方ErlangOTP镜像
06-04
java snmp源码官方 Erlang OTP 镜像 这用作 Erlang OTP 的 docker 基础镜像。 目标是为一些最新的 erlang 版本（当前 24 / 23 / 22 / 21 / 20 / 19 / 18）提供图像，接近全功能 Erlang OTP，以及相对纤薄的图像。 此 repo 中尽最大努力提供对 17、R16 和 R15 的支持，而不是 docker-library/official-images#1075 中官方镜像工作的一部分。 使用 Erlang 23 这里提供最新的 Erlang 23 镜像； 您可以从官方镜像中提取或在本地构建它： $ docker build -t erlang:23.0 ./23 [...] ➸ docker run -it --rm erlang:23.0 Erlang/OTP 23 [erts-11.0.3] [source] [64-bit] [smp:8:8] [ds:8:8:10] [async-threads:1] [hipe] Eshell V11.0.3 (abort with ^G) 1> erlang:sy
Window环境RabbitMq搭建部署
07-20 627
Erlang下载安装及配置环境变量下载erlang，原因在于RabbitMQ服务端代码是使用并发式语言Erlang编写的Erlang官网下载： http://www.erlang.org/downloadsErlang国内镜像下载（推荐）： http://erlang.org/download/?
Erlang 入门——从普通tcp到OTP框架通信
夜的瞳
08-14 1920
Erlang使用tcp通信，OTP框架下gen_server的节点通信pingpong实现demo。
RabbitMQ Centos7.4 安装教程
Silent_Night的博客
09-30 901
RabbitMQ Centos7.4 安装教程
Erlang中国镜像 最新erlang下载 Erlang R15B下载地址
gisbbs的专栏
02-22 1万+
有erlang中国的用户向网站反馈，erlang官网的下载地址，下载速度非常的慢，问erlang中国有没有做镜像？ 之前一直没有做过erlang下载的镜像，不过既然有用户需要，我们就去做，于是今天就把erlang最新的R15B下载到了我们的服务器，并正式提供下载地址，方便那些从官网下载很慢的朋友，可以从另一个服务器去下载。 Erlang中国镜像 最新erlang下载  Erlang
Linux系统(Centos)下单机RabbitMQ环境搭建及下载安装
stupid_shhep的博客
12-09 458
Linux系统(Centos)下单机RabbitMQ环境搭建及下载安装 erlang下载：由于国内访问国外网站下载速度的问题，建议使用镜像下载。而安装RabbitMQ需要安装erlang，还有考虑版本适配的问题，因此需要先安装好erlang再考虑安装RabbitMQ的版本(这里这么操作是因为，在安装erlang的时候找到的资源都是确实一大堆依赖，只有以下的安装方法可以使用，因此只能反过来通过erlang确定RabbitMQ版本)。 # 在Linux系统下的cmd窗口调用该命令，将安装包下载到目标文件夹中
Erlang/OTP简介
狼之梦---爱乌及屋
02-23 3957
简单介绍 OTP （Open Telecom Platform） OTP 是包装在Erlang中的一组库程序。OTP构成Erlang的行为机制（behaviours），用于编写服务器、有限状态机、事件管理器。不仅如此，OTP的应用行为（the application behavior）允许程序员把写好的Erlang代码打包成一个单独的应用程序； 监测行为（the supervisor ...
erlang 23.1
09-27
最新 erlang 下载，帮助大家解决下载慢的问题。官网的下载真的很慢很慢很慢，而且文件也很大，为了方便大家的下载，这里提供一份大家可以接受的积分，可以私信。
erlang资源
11-04
erlang资源，非常值得下载，二郎学习
erlang otp25 win安装包
07-19
erlang otp25 win安装包
Erlang / OTP 21.0 版本下载
08-14
官网下载实在是困难，我把当前Erlang / OTP 21.0 版本提交到这里提供给大家和自己下载 原先积分0的现在都这么高了，为了方便大家，放出云盘地址：https://pan.百度.com/s/1hb8vPiMslXxNuJC8PvnKgg提取码wmx8
Erlang/OTP 26.2.1
最新发布
01-10
Erlang/OTP 26.2.1，Erlang，OTP，26.2.1
erlang_otp_win64_25.0
07-07
erlang_otp_win64_25.0
Erlang ／ OTP并发编程实战
04-15
二十多年来，在传统电信领域高并发、高可靠、高容错的严酷环境下，Erlang语言和OTP平台被锻炼得坚如磐石，浓郁的函数式特质更是恰到好处地弥补了传统命令式语言在并发编程上的固有缺陷，大大降低了构筑并发、容错、...
linux CentOS7 安装 RabbitMQ 3.6.3, Erlang 19.0
热门推荐
泽佑兄弟 ZYbros
07-07 1万+
1. 进入官网，按官网手册进行下载安装 http://www.rabbitmq.com/install-rpm.html 我的centos ，如下图选中对应版本下载 wget https://github.com/rabbitmq/rabbitmq-server/releases/download/rabbitmq_v3_6_3/rabbitmq-server-3.6.3-1.noarc
erlang学习笔记之OTP
keyzx的博客
09-11 454
OTP是Open Telecom Platform（开放电信平台）。但是现在OTP比你想的作用更多。它是一个应用程序操作系统，包含了一组库和实现方式，可以构建大规模、容错和分布式的应用程序。标准的Erlang分发套装包含OTP库。OTP包含了许多强大的工具，例如一个完整的Web服务器，一个FTP服务器和一个CORBA ORB等，它们全都是用Erlang编写的。OTP还包含了构建电信应用程序的最先进工具，能够实现 H248、SNMP和ASN.1/Erlang交叉编译器（这些是电信行业里常用的协议）。
Windows 10 子系统 Ubuntu 安装 Erlang
Gelomen的博客
10-16 352
环境 系统：Windows 10 pro ×64 子系统：wsl2+ Ubuntu 18.04 添加镜像 $ sudo vi /etc/apt/sources.list 最后添加清华erlang-solutions源 # qing hua erlang-solutions deb https://mirrors.tuna.tsinghua.edu.cn/erlang-solutions/ubuntu/ bionic contrib 更新 $ sudo apt update 若失败...
erlang/otp26.1.2下载
11-13
要下载Erlang/OTP 26.1.2，你可以按照以下步骤进行操作： 1. 打开电脑上的浏览器，然后在地址栏中输入 "erlang otp 26.1.2 下载"，点击搜索按钮。 2. 在搜索结果中，找到官方网站的链接或可信赖网站上的下载页面。 3. 进入某个可信赖的网站，浏览页面以寻找正确的下载选项。通常，会有多个可供选择的版本和操作系统平台。 4. 确保你选择了适合你的操作系统（如Windows、Mac、Linux等）以及你希望下载的Erlang/OTP版本（这里是26.1.2）。 5. 找到并点击下载链接。 6. 在弹出的保存对话框中，选择你想要保存文件的位置，然后点击"保存"按钮。 7. 下载文件可能需要一些时间，具体取决于你的网络连接速度。 8. 下载完成后，你可以前往下载文件保存的位置，双击打开（如果是压缩文件，需要先解压缩）。 9. 根据所下载的文件类型，按照安装说明进行安装。通常，Erlang/OTP的安装过程会有一系列的向导和选项，你可以根据需要进行配置选择。 10. 完成安装后，你现在可以使用Erlang/OTP 26.1.2了。 注意：在下载和安装软件时，一定要从官方网站或可信赖的来源下载，以确保文件的完整性和安全性。

“相关推荐”对你有帮助么？

  • 非常没帮助
  • 没帮助
  • 一般
  • 有帮助
  • 非常有帮助
提交
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值