silvaco——GaN HEMT探索

找到了一个相关代码，尝试分析学习一下，初步判断这应该是P-GaN增强型器件，本次仿真所使用的仿真器为atlas，先来复习atlas的仿真流程。先给出完整代码，然后再进行逐行分析。

完整代码：

go atlas 

mesh width=1000

x.mesh location=-2   spacing=0.5
x.mesh location=-1   spacing=0.5
x.mesh location=0    spacing=0.1
x.mesh location=0.7  spacing=0.2
x.mesh location=1.4  spacing=0.1
x.mesh location=4  spacing=0.5
x.mesh location=7.4  spacing=0.1
x.mesh location=8.4  spacing=0.1

y.mesh location=-0.31  spacing=0.05
y.mesh location=-0.21  spacing=0.05
y.mesh location=-0.11  spacing=0.05
y.mesh location=0      spacing=0.001
y.mesh location=0.0075 spacing=0.002
y.mesh location=0.015  spacing=0.0001
y.mesh location=0.0325 spacing=0.005 
y.mesh location=0.05   spacing=0.001
y.mesh location=2.05   spacing=1

region number=1 material=AlGaN x.comp=0.05 y.min=0.05  
region number=2 material=GaN y.min=0.015 y.max=0.05 substrate
region number=3 material=AlGaN x.comp=0.23 y.min=0 y.max=0.015 
region number=4 material=nitride y.max=0
region number=5 material=GaN x.min=0 x.max=1.4 y.min=-0.11 y.max=0 

electrode name=source x.min=-2 x.max=-1 y.min=-0.11 y.max=0.0
electrode name=gate x.min=0 x.max=1.4 y.min=-0.21 y.max=-0.11
electrode name=drain x.min=7.4 x.max=8.4 y.min=-0.11 y.max=0.0
electrode name=substrate bottom

doping region=5 concentration=3e17 p.type uniform

models consrh auger fermi print temp=300
mobility GaNsat.n 
models lat.temp ni.fermi
mobility albrct.n bn.albrct=3e-05 an.albrct=3e-05
mobility region=5 albrct.p bp.albrct=1e04 ap.albrct=1e04 
model POLARIZATION psp.scale=0.67 piezo.scale=0.67 calc.strain 
model region=5 pch.ins

contact name=source workfunc=4.04
contact name=drain  workfunc=4.04

trap region=2 donor e.level=3.2 density=1.27e18 sign=1e-15 sigp=1e-15 degen=2
trap region=2 acceptor e.level=0.36 density=7e17 sign=1e-15 sigp=1e-15 degen=4


thermcontact num=1 name=substrate alpha=2500

method newton climit=1e-4 maxtraps=10 itlimit=30  

output band.param con.band val.band charge polar.charge qss

solve init
solve previous
save outfile=ganfetex07_0.str

solve vdrain=0.1
solve vdrain=0.5 vstep=0.5 vfinal=15 name=drain
solve vgate=-0.1
solve vgate=-0.5 vstep=-0.5 vfinal=-2 name=gate
log outfile=ganfetex07_0.log
solve previous
solve vstep=0.1 vfinal=7 name=gate

extract init inf="ganfetex07_0.log"
extract name="Vt" x.val from curve(abs(v."gate"),abs(i."drain")) where y.val=1e-03
extract name="IdVg0V" y.val from curve(abs(v."gate"),abs(i."drain")) where x.val=0.01
extract name="IgVg5V" y.val from curve(abs(v."gate"),abs(i."gate")) where x.val=5


log off

solve init
solve previous

solve vgate=0.5 
solve vgate=1 outf=ganfetex07_vg1v
solve vgate=2 
solve vgate=3 outf=ganfetex07_vg3v
solve vgate=4 
solve vgate=5 outf=ganfetex07_vg5v

solve init
load inf=ganfetex07_vg1v
log outf=ganfetex07_1.log
solve vdrain=0.1
solve vdrain=0.5
solve vstep=0.5 vfinal=20 name=drain

solve init
load inf=ganfetex07_vg3v
log outf=ganfetex07_2.log
solve vdrain=0.5
solve vstep=0.5 vfinal=20 name=drain

solve init
load inf=ganfetex07_vg5v
log outf=ganfetex07_3.log
solve vdrain=0.001
solve vdrain=0.5
solve vstep=0.5 vfinal=20 name=drain

extract name="idsmax" max(abs(i."drain"))

一、结构描述

1.MESH 网格划分

go atlas 

mesh width=1000
#确定器件的宽度，器件宽度默认值是1um，这里设置器件的宽度值是1000um
x.mesh location=-2   spacing=0.5
x.mesh location=-1   spacing=0.5
x.mesh location=0    spacing=0.1
x.mesh location=0.7  spacing=0.2
x.mesh location=1.4  spacing=0.1
x.mesh location=4  spacing=0.5
x.mesh location=7.4  spacing=0.1
x.mesh location=8.4  spacing=0.1

y.mesh location=-0.31  spacing=0.05
y.mesh location=-0.21  spacing=0.05
y.mesh location=-0.11  spacing=0.05
y.mesh location=0      spacing=0.001
y.mesh location=0.0075 spacing=0.002
y.mesh location=0.015  spacing=0.0001
y.mesh location=0.0325 spacing=0.005 
y.mesh location=0.05   spacing=0.001
y.mesh location=2.05   spacing=1
#网格划分，可以看到在沟道附近网格最密

2.REGION 区域划分 

region number=1 material=AlGaN x.comp=0.05 y.min=0.05  
#区域指定，区域1，AlGaN材料，在AlXGa(1-X)N中Al的组分为0.05
region number=2 material=GaN y.min=0.015 y.max=0.05 substrate
#区域指定，区域2，GaN材料，y∈（0.015，0.05），区域2作为衬底材料
region number=3 material=AlGaN x.comp=0.23 y.min=0 y.max=0.015
#区域指定，区域3，AlGaN材料，在AlXGa(1-X)N中Al的组分为0.23，y∈（0，0.015）
region number=4 material=nitride y.max=0
#区域指定，区域4，氮化物，钝化层
region number=5 material=GaN x.min=0 x.max=1.4 y.min=-0.11 y.max=0 
#区域指定，区域5，GaN，x∈（0，1.4），y∈（-0.11，0）

3.ELECTRODE 电极定义

electrode name=source x.min=-2 x.max=-1 y.min=-0.11 y.max=0.0
#电极定义，源极，x∈（-2，-1），y∈（-0.11，0）
electrode name=gate x.min=0 x.max=1.4 y.min=-0.21 y.max=-0.11
#电极定义，栅极，x∈（0，1.4），y∈（-0.21，-0.11）
electrode name=drain x.min=7.4 x.max=8.4 y.min=-0.11 y.max=0.0
#电极定义，漏极，x∈（7.4，8.4），y∈（-0.11，0）
electrode name=substrate bottom
#电极定义，衬底

4. DOPING 掺杂

 帽层掺杂p型杂质，均匀掺杂

doping region=5 concentration=3e17 p.type uniform

二、材料模型描述

1.MODELS 模型选择

models consrh auger fermi print temp=300

模型定义，consrh，Shockley-Read-Hall复合模型；auger，俄歇复合模型；fermi，Fermi-Dirac载流子统计模型，Print能够用来反映采用的模型和参数，所以在引入模型的时候最好写上print 

mobility GaNsat.n 

 迁移率模型，GaN高场迁移率模型

models lat.temp ni.fermi

 lat.temp，晶格自热模型；ni.fermi，使用费米-狄拉克统计计算本征载流子浓度ni

mobility albrct.n bn.albrct=3e-05 an.albrct=3e-05

 albrct.n，低场迁移率模型，bn.albrct，an.albrct是albrct模型中的参数，可以由用户自己设定

mobility region=5 albrct.p bp.albrct=1e04 ap.albrct=1e04 

 帽层材料迁移率模型定义，albrct低场迁移率模型，后面两个同样是模型当中的参数

model POLARIZATION psp.scale=0.67 piezo.scale=0.67 calc.strain 

 POLARIZATION，极化模型；psp.scale，polarization scale factors（极化程度因子）用于解释外部应变；piezo.scale是POLAR.SCALE的别名，当通过设置REGION语句的极化参数启用极化时，指定一个常数比例因子乘以计算的自发和压电极化电荷。应该就是和自发极化和压电极化相关的参数；calc.strain，GaN FET常用的模型 

model region=5 pch.ins

 pch.ins，指定极化电荷将包含在绝缘体或外部域的界面上

2.CONTACT 电极接触类型定义

contact name=source workfunc=4.04
contact name=drain  workfunc=4.04

电极的接触类型定义，源/漏极欧姆接触，功函数=4.04

3.INTERFACE 界面特性定义

trap region=2 donor e.level=3.2 density=1.27e18 sign=1e-15 sigp=1e-15 degen=2
trap region=2 acceptor e.level=0.36 density=7e17 sign=1e-15 sigp=1e-15 degen=4

GaN中陷阱，施主/受主；e.level，电离能。对于受主，E.LEVEL相对于导带边缘，对于施主，相对于价带边缘。density，设置陷阱的最大密度；sign/sigp，捕获参数，应该使用横截面或寿命参数来定义捕获参数。sign，指定电子阱的捕获横截面，sigp，指定捕获空穴的陷阱的横截面；degen，简并度 

thermcontact num=1 name=substrate alpha=2500

 

THERMCONTACT指定热触点的位置和属性。name，指定热接触电极名称；alpha，热阻的倒数(a=1/RTH) 

三、数值计算方法

method newton climit=1e-4 maxtraps=10 itlimit=30 

数值计算方法，newton，指定牛顿方法将在后续的SOLVE语句中用作解方法，除非另有说明，某些模型和边界条件的设置要求使用牛顿法。如果没有指定解决方法，则默认使用NEWTON；climit，浓度归一化因子；itlimit，迭代的次数上限；maxtraps，步长折回次数

output band.param con.band val.band charge polar.charge qss

output，把指定的参数保存在标准结构格式文件中；band.param，能带参数，Specifies that the band parameters (Eg, ni, Nc, Nv, and 亲和能？) are included in the standard structure file；con.band，导带位置；val.band，价带位置；charge，净电荷量；polar.charge，极化电荷；qss，表面电荷

四、求解描述

1.SOLVE 求解描述

solve init
#求解初始化
solve previous
#求解之前的
save outfile=ganfetex07_0.str
#保存结构文件

solve vdrain=0.1
#漏极电压=0.1V
solve vdrain=0.5 vstep=0.5 vfinal=15 name=drain
#扫描漏极电压，初始值=0.5V，步长=0.5V，终值=15V
solve vgate=-0.1
#栅极电压=-0.1V
solve vgate=-0.5 vstep=-0.5 vfinal=-2 name=gate
#扫描栅极电压，初始值=-0.5V，步长=-0.5V，终值=-2V
log outfile=ganfetex07_0.log
#需要先设置数据保存的日志文件，才可以用Tonyplot显示出来 

solve previous
#求解之前的
solve vstep=0.1 vfinal=7 name=gate
#扫描栅极电压，初始值=0.1，终值=7V

extract init inf="ganfetex07_0.log"
#提取初始的日志文件
extract name="Vt" x.val from curve(abs(v."gate"),abs(i."drain")) where y.val=1e-03
#从转移特性曲线上提取阈值电压，y.val=1e-03，当y值为1e-03时；x.val，x轴的值就是阈值电压
extract name="IdVg0V" y.val from curve(abs(v."gate"),abs(i."drain")) where x.val=0.01
#从转移特性曲线上提取栅压为0v时的漏电流
extract name="IgVg5V" y.val from curve(abs(v."gate"),abs(i."gate")) where x.val=5
#从转移特性曲线上提取栅压为5v时的漏电流

log off
#提取完毕

上图为栅极漏电流曲线和转移特性曲线以及其提取的参数，可以看到阈值电压为=1.30249V，当栅压为0v时，Id=8.01032e-006，当栅压为5V时，Ig=3.11627e-006

solve init
#求解初始化
solve previous
#求解之前的
solve vgate=0.5 
#栅极电压=0.5V
solve vgate=1 outf=ganfetex07_vg1v
solve vgate=2 
solve vgate=3 outf=ganfetex07_vg3v
solve vgate=4 
solve vgate=5 outf=ganfetex07_vg5v
#施加不同的栅压，并保存文件

solve init
load inf=ganfetex07_vg1v
#载入栅压为1v的文件
log outf=ganfetex07_1.log
#设置数据保存的日志文件
solve vdrain=0.1
solve vdrain=0.5
solve vstep=0.5 vfinal=20 name=drain
#扫描漏极电压，生成输出特性曲线

solve init
load inf=ganfetex07_vg3v
log outf=ganfetex07_2.log
solve vdrain=0.5
solve vstep=0.5 vfinal=20 name=drain

solve init
load inf=ganfetex07_vg5v
log outf=ganfetex07_3.log
solve vdrain=0.001
solve vdrain=0.5
solve vstep=0.5 vfinal=20 name=drain

extract name="idsmax" max(abs(i."drain"))
#提取漏极电流的最大值

上图为输出特性曲线 ，分别是在栅压为1v、3v、5v的情况下，可以看出在1v时器件处于截止状态，只有非常小近似于0的电流通过，随着栅压逐渐增大，沟道开启，产生漏极电流。提取出栅压为5V时最大的漏极电流为0.524922 A/um。至于输出特性曲线为什么会下移，还需要进一步调研学习。我只记得mos上翘是因为沟道长度调制效应。