FLEX提高篇--------ShareObject对象详解

最新推荐文章于 2023-03-28 18:45:11 发布

游鱼_

最新推荐文章于 2023-03-28 18:45:11 发布

阅读量94

点赞数

本文链接：https://blog.csdn.net/wwj256/article/details/84665131

版权

转自：http://chuiwenchiu.spaces.live.com/blog/cns!ca5d9227df9e78e8!1025.entry

測試環境：
1. Windows XP Pro
2. Flex Builder 2.0.1

ShareObject 類別允許你將小量資料儲存在用戶端電腦。ShareObject 有點類似瀏覽器的 Cookie。應用程式只能存取屬於自己的資料，且應用程式必須和資料同屬於同一個網域(Domain)。但是這個資料並不能傳送到伺服器端。

ShareObject 提供下面的方法

`clear()`	從 ShareObject 中清空所有的資料，並從檔案磁碟刪除 ShareObject 檔案。
`flush()`	將 ShareObject 直接寫入用戶端的檔案
`getLocal()`	回傳 ShareObject 所在的 Domain。假如不存在，這個方法會在用戶端建立一個新的 ShareObject
`getSize()`	Gets the size of the SharedObject file, in bytes. The default size limit is 100 KB, although it can be larger if the client allows it.

屬性：

`data`	(唯讀)儲存在 ShareObject 中的資料
`onStatus`	當 ShareObject 發生警告、錯誤或其他訊息時會觸發這個事件

建立 ShareObject 的語法如下：

SharedObject.getLocal("objectName" [, pathname]): SharedObject

下面是簡單的範例：

public var mySO:SharedObject;
mySO = SharedObject.getLocal("preferences");

上述如果在 local 端執行，Flash Player 會產生 preferences.sol 到下面路徑

c:/Documents and Settings/username/Application Data/Macromedia/Flash Player/#SharedObjects/一串數字/localhost/應用程式路徑/SWF 檔名/

以我的情況來說，我的帳號是 Administrator，SWF 放在 "C:\Documents and Settings\Administrator.MYCHAT-1A793BE7\My Documents\Flex Builder 2\Example\bin"，preferences.sol 會存放到下面路徑
C:\Documents and Settings\Administrator.MYCHAT-1A793BE7\Application Data\Macromedia\Flash Player\#SharedObjects\96FX85HW\localhost\Documents and Settings\Administrator.MYCHAT-1A793BE7\My Documents\Flex Builder 2\Example\bin\Example.swf\
註：上述路徑和文件所述有出入，不知道是否為文件錯誤。
註：如果你只有執行上述的 getLocal 並不會立即產生 *.sol，你可以在後面加上一行 mySO.flush() 利即將資料寫入檔案。
註：如果程式是在網路上執行，則路徑結構會變為

c:/Documents and Settings/username/Application Data/Macromedia/Flash Player/#SharedObjects/一串數字/web_domain/應用程式路徑/SWF 檔名/

如：
C:\Documents and Settings\Administrator.MYCHAT-1A793BE7\Application Data\Macromedia\Flash Player\#SharedObjects\96FX85HW\www.box.net\static\flash\box_explorer.swf\
註：假如 getLocal 沒有提供 sol 名稱，則會使用 undefined.sol
註：預設情況 ShareObject 在每個網域只能儲存 100KB，如果超過時，Flash Player 會要求使用者允許儲存超過 100KB 的資料
註：也可以使用 getLocal 的第二個參數來指定儲存位置，但必須是目前網域的子目錄
註：可以一次建立多個 ShareOjbect

存取 ShareObject 資料的方法很簡單，只要透過 data 屬性，後面接需要儲存的變數名稱，如下：
// 寫入資料
mySO.data.name = "Chui-Wen Chiu";
mySO.data.age = 27;

// 讀取資料
trace( mySO.data.name )

SharedObject 範例：紀錄登出時間

點一下 Log out 在重新載入 Flash 會看到上次登入時間

<?xml version="1.0"?>
<!-- lsos/WelcomeMessage.mxml -->
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" initialize="initApp()">
  <mx:Script><![CDATA[
public var mySO:SharedObject;
  [Bindable]
  public var welcomeMessage:String;

  public function initApp():void {
mySO = SharedObject.getLocal("mydata");
     if (mySO.data.visitDate==null) {
        welcomeMessage = "Hello first-timer!"
     } else {
        welcomeMessage = "Welcome back. You last visited on " +
           getVisitDate();
     }
  }

  private function getVisitDate():Date {
     return mySO.data.visitDate;
  }

  private function storeDate():void {
mySO.data.visitDate = new Date();
mySO.flush();
  }

  private function deleteLSO():void {
     // Deletes the SharedObject from the client machine.
     // Next time they log in, they will be a 'first-timer'.
mySO.clear();
  }

  ]]></mx:Script>
  <mx:Label id="label1" text="{welcomeMessage}"/>
  <mx:Button label="Log Out" click="storeDate()"/>
  <mx:Button label="Delete LSO" click="deleteLSO()"/>
</mx:Application>

ShareObject,顾名思义共享对象,而通常意义上的共享，从B/S结构上来讲,无非是客户端（浏览器端）的共享和服务器端的共享了,不错,ShareObject刚好份演了这两种角色。而且ShareObject也是按此进行了两种分类,一类是LSO——Local Share Object（本地共享对象）其实类似于cookie，而另一种RSO——Remote Share Object(远程共享对象) 我感觉比较类似于JSP中的Application对象，但好象比Application更强大。

下面我分别用实例代码来说两者的用法和用途：

一：LSO（本地共享对象）

LSO的用法比较简单，和我们平常操作Cookie大同小异：

1．得到一个共享对象：

var so:SharedObject=SharedObject.getLocal("mydata","/");

2．往共享对象里存入值：

var user:Object=new Object();

user.userName=userName.text;

user.passWord=passWord.text;

user.isSaveLogin=(remember.selected==true?1:0);

so.data.user=user;

3．清除共享对象里的值：

var so:SharedObject=SharedObject.getLocal("mydata","/");

if(so.data.user!=null){

so.data.user=null;

}

4．读取共享对象里的值：

var so:SharedObject=SharedObject.getLocal("mydata","/");

if(so.data.user!=null){

userName.text=so.data.user.userName;

passWord.text=so.data.user.passWord;

if(so.data.user.isSaveLogin.toString()=="1"){

remember.selected=true;

}

二：RSO（远程共享对象）：

RSO是服务器端的共享对象，服务器端的数据共享可以实现多个客户端数据共享，在这里服务器我采用Flash Media Server3，FMS的使用非常简便，你只要在安装目录下找到Applications目录，并在其下新建一个子目录就可以成为你的工程或项目了。关于FMS的使用大家可以参考相关文章，本文不做介绍：利用FMS和RSO我们可以实现非常多的功能，诸如，聊天室，联机游戏，视频会议，在线视频录制和视频聊天。。。。。。

在这里我用一个简单的聊天室实例为例稍做讲解：

Java代码

<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute" creationComplete="TextSO ();">
<mx:Script>
<![CDATA[
import flash.events.SyncEvent;
import flash.events.NetStatusEvent;
import flash.events.MouseEvent;
import flash.net.SharedObject;
import flash.net.NetConnection;
private var text_so:SharedObject;
private var nc:NetConnection;
private var rtmpGo:String;
private var good:Boolean;
public function TextSO ():void
{
button.label="Send";
button.addEventListener (MouseEvent.CLICK,sendMsg);//为发送按钮添加发送事件
rtmpGo = "rtmp://localhost/basicSO";//这里设置FMS服务器的连接地址,basicSO即为,
//FMS安装目录下Applications下自己手动新建的一个文件夹名称,也是FMS的工程名,就是这么简洁,不可意议
nc = new NetConnection( );//产生一个连接对象
nc.connect (rtmpGo);//连接到上面的地址
nc.addEventListener (NetStatusEvent.NET_STATUS,doSO);//加入连接的监听事件,以便根据连接返回的状态做相应处理
}
private function doSO (e:NetStatusEvent):void
{
good=e.info.code == "NetConnection.Connect.Success";//判断是否为连接成功状态
//连接返回的状态有好几种,大家可以参看FMS的文档,很详尽
if (good)//如果连接成轼,执行如下操作
{
text_so=SharedObject.getRemote("test",nc.uri,false);//得到远程共享对象,false属性是设置共享的数据为非持久化的,
//即重启服务器后,先前的数据不会保存
text_so.connect (nc);
text_so.addEventListener (SyncEvent.SYNC,checkSO);
//为共享对象添加异步事件,这也是服务器同步处理多客户端最关键的地方,
//一个客户端进行了什么操作,其它客户端也会有相应的变化,就是通过此事件来完成的
}
}
private function checkSO (e:SyncEvent):void
{
for (var chng:uint; chng<e.changeList.length; chng++)
{
switch (e.changeList[chng].code)
{
case "clear" :
break;
case "success" :
trace (text_so.data.msg);
break;
case "change" ://一个客户端改变数据会更新所有客户端
textArea.htmlText+=text_so.data.msg + "\n";
break;
}
}
}
private function sendMsg (e:MouseEvent):void
{
text_so.setProperty ("msg",textInput.text);//将新的信息存入共享对象
textArea.htmlText+=text_so.data.msg + "\n";//更新客户端的信息列表
}
]]>
</mx:Script>
<mx:VBox>
<mx:TextArea id="textArea" width="200" height="200"/>//信息列表框
<mx:TextInput id="textInput"/>//消息输入框
<mx:Button id="button" />//发送按钮
</mx:VBox>
</mx:Application>

游鱼_

关注

0
点赞
踩
0

收藏

觉得还不错? 一键收藏
打赏
1
评论
FLEX提高篇--------ShareObject对象详解

转自：http://chuiwenchiu.spaces.live.com/blog/cns!ca5d9227df9e78e8!1025.entry 測試環境：1. Windows XP Pro2. Flex Builder 2.0.1ShareObject 類別允許你將小量資料儲存在用戶端電腦。ShareObject 有點類似瀏覽器的 Cookie。應用程式只能存取屬於自己的資料，且應用程式必...
复制链接

扫一扫