u-boot-2010.03分析(二)
因为目的并不是学习uboot,本职工作也不是uboot开发,仅仅是为了了解uboot的启动流程。因此,直接给出操作步骤,这些步骤来源于友善之臂对于2440的支持文档中。
因为懒,不想打字了,而刚好,友善之臂提供了全部文档,我会将其上传,以供交流使用。如果涉及侵权,请及时通知我删除。
完整文档,mini2440对uboot-2010-10.03的移植
接下来依据已经移植好的uboot源码,简略分析,uboot的启动流程。
查找开始位置
从min2440的datasheet中可以知道,芯片从0x0处开始执行,当使用nandflash时,执行流程如下:
- 将nand flash的前面4k内存拷贝到一个被称为Steppingstone的内部存储中。它是一个SRAM buffer
- 然后代码从Steppingstone处开始执行。从datasheet可以知道,steppingstone的起始地址就是0x0
接下来,查找u-boot.lds看看谁的执行地址是0x0。
OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
OUTPUT_ARCH(arm)
ENTRY(_start)
SECTIONS
{
. = 0x00000000;
. = ALIGN(4);
.text :
{
cpu/arm920t/start.o (.text)
board/embedclub/smdk2440a/lowlevel_init.o (.text)
board/embedclub/smdk2440a/nand_read.o (.text)
*(.text)
}
. = ALIGN(4);
.rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) }
. = ALIGN(4);
.data : { *(.data) }
. = ALIGN(4);
.got : { *(.got) }
. = .;
__u_boot_cmd_start = .;
.u_boot_cmd : { *(.u_boot_cmd) }
__u_boot_cmd_end = .;
. = ALIGN(4);
__bss_start = .;
.bss (NOLOAD) : { *(.bss) . = ALIGN(4); }
_end = .;
}
上面ld脚本的语法和指令,可参考前面系列文章,《ld链接脚本》
可以看出,cpu/arm920t/start.o为整个uboot的起始位置。而程序的入口点为_start符号指定的指令。接下来看这个入口点。
开始执行咯
start.S的_start代码段如下
.globl _start
_start: b start_code
ldr pc, _undefined_instruction
ldr pc, _software_interrupt
ldr pc, _prefetch_abort
ldr pc, _data_abort
ldr pc, _not_used
ldr pc, _irq
ldr pc, _fiq
可以看见,_start为一个全局符号,他对应的指令,也是start.o的第一条指令,是一个跳转指令,跳转到start_code符号对应的指令中。
根据datasheet,可知,后面跟着的是异常向量表。异常向量表就不再展开了,直接进入start_code 的内容
start_code
start_code:
/*
* 进入SVC32模式,即Supervisor mode
*/
mrs r0, cpsr
bic r0, r0, #0x1f
orr r0, r0, #0xd3
msr cpsr, r0
start_code 首先进入supervisor 模式,该模式,是mini2440支持的7中模式之一,它的详细介绍,见前面的《arm汇编》系列文章
接下来,因为代码有点长,为了节约篇幅,直接给出关键部分
/* FCLK:HCLK:PCLK = 1:4:8 */
ldr r0, =CLKDIVN
mov r1, #5
str r1, [r0]
mrc p15, 0, r1, c1, c0, 0
orr r1, r1, #0xc0000000
mcr p15, 0, r1, c1, c0, 0
mov r1, #CLK_CTL_BASE
mov r2, #MDIV_405
add r2, r2, #PSDIV_405
str r2, [r1, #0x04] /* MPLLCON tekkaman */
如果有配置CONFIG_S3C2440变量,则执行上面的代码,上面的代码用于设置时钟分频。
接下来,要跳到另外一处执行,因此总结一下上面的步骤就只有两个:1.进入supervisor模式;2.设置时钟分频器
/*
* we do sys-critical inits only at reboot,
* not when booting from ram!
*/
#ifndef CONFIG_SKIP_LOWLEVEL_INIT
bl cpu_init_crit
#endif
进入cpu_init_crit,代码如下:
cpu_init_crit:
/*
* flush v4 I/D caches
*/
mov r0, #0
mcr p15, 0, r0, c7, c7, 0 /* flush v3/v4 cache */
mcr p15, 0, r0, c8, c7, 0 /* flush v4 TLB */
/*
* disable MMU stuff and caches
*/
mrc p15, 0, r0, c1, c0, 0
bic r0, r0, #0x00002300 @ clear bits 13, 9:8 (--V- --RS)
bic r0, r0, #0x00000087 @ clear bits 7, 2:0 (B--- -CAM)
orr r0, r0, #0x00000002 @ set bit 2 (A) Align
orr r0, r0, #0x00001000 @ set bit 12 (I) I-Cache
mcr p15, 0, r0, c1, c0, 0
/*
* before relocating, we have to setup RAM timing
* because memory timing is board-dependend, you will
* find a lowlevel_init.S in your board directory.
*/
mov ip, lr
bl lowlevel_init
mov lr, ip
mov pc, lr
mini2440,带有16kb的I-cache(指令缓存) 和16kb的D-cache(数据缓存)。启动时,将该部分缓存清空,mcr指令,将cpu的寄存器移动到协处理器中。
接下来,禁用MMU和相应的缓存。mrc指令,将协处理器的数据移动到cpu寄存器中。
然后,调用lowlevel_init,它在lowlevel_init.S中,如下:
.globl lowlevel_init
lowlevel_init:
/* memory control configuration */
/* make r0 relative the current location so that it */
/* reads SMRDATA out of FLASH rather than memory ! */
ldr r0, =SMRDATA
ldr r1, _TEXT_BASE
sub r0, r0, r1
ldr r1, =BWSCON /* Bus Width Status Controller */
add r2, r0, #13*4
0:
ldr r3, [r0], #4
str r3, [r1], #4
cmp r2, r0
bne 0b
/* everything is fine now */
mov pc, lr
.ltorg
/* the literal pools origin */
SMRDATA:
.word (0+(B1_BWSCON<<4)+(B2_BWSCON<<8)+(B3_BWSCON<<12)+(B4_BWSCON<<16)+(B5_BWSCON<<20)+(B6_BWSCON<<24)+(B7_BWSCON<<28))
.word ((B0_Tacs<<13)+(B0_Tcos<<11)+(B0_Tacc<<8)+(B0_Tcoh<<6)+(B0_Tah<<4)+(B0_Tacp<<2)+(B0_PMC))
.word ((B1_Tacs<<13)+(B1_Tcos<<11)+(B1_Tacc<<8)+(B1_Tcoh<<6)+(B1_Tah<<4)+(B1_Tacp<<2)+(B1_PMC))
.word ((B2_Tacs<<13)+(B2_Tcos<<11)+(B2_Tacc<<8)+(B2_Tcoh<<6)+(B2_Tah<<4)+(B2_Tacp<<2)+(B2_PMC))
.word ((B3_Tacs<<13)+(B3_Tcos<<11)+(B3_Tacc<<8)+(B3_Tcoh<<6)+(B3_Tah<<4)+(B3_Tacp<<2)+(B3_PMC))
.word ((B4_Tacs<<13)+(B4_Tcos<<11)+(B4_Tacc<<8)+(B4_Tcoh<<6)+(B4_Tah<<4)+(B4_Tacp<<2)+(B4_PMC))
.word ((B5_Tacs<<13)+(B5_Tcos<<11)+(B5_Tacc<<8)+(B5_Tcoh<<6)+(B5_Tah<<4)+(B5_Tacp<<2)+(B5_PMC))
.word ((B6_MT<<15)+(B6_Trcd<<2)+(B6_SCAN))
.word ((B7_MT<<15)+(B7_Trcd<<2)+(B7_SCAN))
.word ((REFEN<<23)+(TREFMD<<22)+(Trp<<20)+(Trc<<18)+(Tchr<<16)+REFCNT)
.word 0xb2
.word 0x30
.word 0x30
它使用SMRDATA定义好的数据,填充内存相关的寄存。即初始化内存
综上cpu_init_crit,完成的主要功能为:1. 清缓存;2. 禁用MMU;3. 配置内存
接着,回到start_code 的位置。下面的代码如下:
/***************** CHECK_CODE_POSITION ******************************************/
adr r0, _start /* r0 <- current position of code */
ldr r1, _TEXT_BASE /* test if we run from flash or RAM */
cmp r0, r1 /* don't reloc during debug */
beq stack_setup
/***************** CHECK_CODE_POSITION ******************************************/
TEXT_BASE的地址,通过board\embedclub\smdk2440a\config.mk设置。因为内核希望从3000’8000地址开始,同时内核的ramdisk还希望从3080’0000地址开始。为了在uboot搬运kernel时,好处理,就将uboot放在TEXT_BASE指定的地方,这个地址为0x33F80000。即uboot希望在0x33F80000这个地址
接下来就是判断,uboot是不是在这个地方,_start地址,表示的是当前uboot的地址。
比较_start的地址和_TEXT_BASE,如果不相等,则进入下面的代码,因为第一次启动时这部分代码是自动装载到stepping stone的,所以_start为0x00,此时,不相等。进入下面的代码。
ldr r1, =( (4<<28)|(3<<4)|(3<<2) ) /* address of Internal SRAM 0x4000003C*/
mov r0, #0 /* r0 = 0 */
str r0, [r1] /*0x4000003C 地址的值为0*/
mov r1, #0x3c /* address of men 0x0000003C*/
ldr r0, [r1] /*从0x0000003C取值到r0*/
cmp r0, #0
bne relocate
上面的代码用于判断,是nand flash启动,还是nor flash启动。
先将0x4000003C处的数据清零,再读出0x0000003C处地址的数据,如果为0就意味着,这个地址是同时映射在0x4000003C处和0x0000003C处即为nandflash启动,不相等则为norflash启动。
这边以nandflash启动为主,因此,不会跳转到relocate,继续下面的代码
/* recovery */
ldr r0, =(0xdeadbeef)
ldr r1, =( (4<<28)|(3<<4)|(3<<2) )
str r0, [r1]
#define LENGTH_UBOOT 0x60000
#define NAND_CTL_BASE 0x4E000000
#ifdef CONFIG_S3C2440
/* Offset */
#define oNFCONF 0x00
#define oNFCONT 0x04
#define oNFCMD 0x08
#define oNFSTAT 0x20
@ reset NAND
mov r1, #NAND_CTL_BASE
ldr r2, =( (7<<12)|(7<<8)|(7<<4)|(0<<0) )
str r2, [r1, #oNFCONF]
ldr r2, [r1, #oNFCONF]
ldr r2, =( (1<<4)|(0<<1)|(1<<0) ) @ Active low CE Control
str r2, [r1, #oNFCONT]
ldr r2, [r1, #oNFCONT]
ldr r2, =(0x6) @ RnB Clear
str r2, [r1, #oNFSTAT]
ldr r2, [r1, #oNFSTAT]
mov r2, #0xff @ RESET command
strb r2, [r1, #oNFCMD]
mov r3, #0 @ wait
nand1:
add r3, r3, #0x1
cmp r3, #0xa
blt nand1
nand2:
ldr r2, [r1, #oNFSTAT] @ wait ready
tst r2, #0x4
beq nand2
ldr r2, [r1, #oNFCONT]
orr r2, r2, #0x2 @ Flash Memory Chip Disable
str r2, [r1, #oNFCONT]
@ get read to call C functions (for nand_read())
ldr sp, DW_STACK_START @ setup stack pointer
mov fp, #0 @ no previous frame, so fp=0
@ copy U-Boot to RAM
ldr r0, =TEXT_BASE
mov r1, #0x0
mov r2, #LENGTH_UBOOT
bl nand_read_ll
tst r0, #0x0
beq ok_nand_read
bad_nand_read:
loop2:
b loop2 @ infinite loop
ok_nand_read:
@ verify
mov r0, #0
ldr r1, =TEXT_BASE
mov r2, #0x400 @ 4 bytes * 1024 = 4K-bytes
go_next:
ldr r3, [r0], #4
ldr r4, [r1], #4
teq r3, r4
bne notmatch
subs r2, r2, #4
beq stack_setup
bne go_next
notmatch:
loop3:
b loop3 @ infinite loop
#endif
首先,恢复0x0000003C处的数据0xdeadbeef。
接着进行nand flash的配置,然后将uboot拷贝到SDRAM的0x33F80000,接着跳到stack_setup中运行。
stack_setup
stack_setup:
ldr r0, _TEXT_BASE /* upper 128 KiB: relocated uboot */
sub r0, r0, #CONFIG_SYS_MALLOC_LEN /* malloc area */
sub r0, r0, #CONFIG_SYS_GBL_DATA_SIZE /* bdinfo */
#ifdef CONFIG_USE_IRQ
sub r0, r0, #(CONFIG_STACKSIZE_IRQ+CONFIG_STACKSIZE_FIQ)
#endif
sub sp, r0, #12 /* leave 3 words for abort-stack */
clear_bss:
ldr r0, _bss_start /* find start of bss segment */
ldr r1, _bss_end /* stop here */
mov r2, #0x00000000 /* clear */
clbss_l:str r2, [r0] /* clear loop... */
add r0, r0, #4
cmp r0, r1
ble clbss_l
ldr pc, _start_armboot
首先计算,堆栈指针的值,根据TEXT_BASE的值,往下减CONFIG_SYS_MALLOC_LEN(堆的大小),再减CONFIG_SYS_GBL_DATA_SIZE(用于存储uboot需要的全局数据),再为abort-stack预留3个word。计算得到的指针,就是堆栈指针。
注意:CONFIG_SYS_GBL_DATA_SIZE用于存放uboot启动期间的全局数据,在后续的c语言里面将会使用,它使用一个struct global_data来表示。
然后,为bss段,清零。
最后,跳到_start_armboot,即lib_arm/board.c的start_arm函数中运行。
剩下的就是c代码中运行了。
综上,可以总结如下的步骤:
- 进入supervisor模式;
- 设置时钟分频器
- 清空I/D缓存
- 禁用MMU单元
- 配置内存
- 根据启动类型(nandflash或者norflash)将uboot拷贝SDRAM的TEXT_BASE地址处
- 设置堆栈指针
- 清空BSS段
- 进入start_armboot
下一篇就以start_armboot开始