Delphi的学习笔记七——格式化输出函数（总结的很全面）

第一部分：

1. var  
2.   s: string;  
3. begin  
4.   //指令类型 type  
5.   
6.   s := Format('最大整数是: %d; 最小整数是: %d',[MaxInt,Low(Integer)]);  
7.   //返回: 最大整数是: 2147483647; 最小整数是: -2147483648  
8.   { 提示: 格式指令必须以 % 开始, 不区分大小写, %d 代表一个整数; 第二个参数是一个变体数组 }  
9.   
10.   s := Format('最大的无负号整数是: %u',[High(Cardinal)]);  
11.   //返回: 最大的无负号整数是: 4294967295  
12.   { %u表示一个无负号整数 }  
13.   
14.   s := Format('输入-2的结果是: %u',[-2]);  
15.   //返回: 输入-2的结果是: 4294967294  
16.   { 如果对应 %u 的是个负数, 则返回: 无负号整数最大值 - 这个数的绝对值 + 1 }  
17.   
18.   s := Format('%s! %s',['你好','我是万一']);  
19.   //返回: 你好! 我是万一  
20.   { %s 表示字符串 }  
21.   
22.   s := Format('%f',[Pi]);  
23.   //返回: Pi的值是: 3.14  
24.   { %f 表示浮点数, 保留或凑够两位小数点 }  
25.   
26.   s := Format('%g',[01.2345000]);  
27.   //返回: 1.2345  
28.   { %g 表示浮点数, 会去掉多余的 0 }  
29.   
30.   s := Format('%n',[12345.6789]);  
31.   //返回: 12,345.68  
32.   { %n 表示浮点数, 整数部分使用千位分隔符, 保留两位小数点 }  
33.   
34.   s := Format('%m',[12345.6789]);  
35.   //返回: ￥12,345.68  
36.   { %m 表示浮点数, 加货币记号, 转换结果取决于系统的地域设置 }  
37.   
38.   s := Format('%e',[12345.6789]);  
39.   //返回: 1.23456789000000E+004  
40.   { %e 用科学计数法表示整数或浮点数 }  
41.   
42.   s := Format('%p',[@Self]);  
43.   //返回: 0012F5BC  
44.   { %p 表示指针地址, 用十六进制表示 }  
45.   
46.   s := Format('%x',[255]);  
47.   //返回: FF  
48.   { %x 用十六进制表示一个整数 }  
49.   
50.   
51.   //Index  
52.   
53.   s := Format('%s%s',['万','一']);  
54.   s := Format('%0:s%1:s',['万','一']);  
55.   //返回: 万一  
56.   { 上面两行的结果是一样的, 0: 对应数组中的第一个值; 1: 对应数组中的第二个值 }  
57.   
58.   s := Format('%1:s%0:s',['万','一']);  
59.   //返回: 一万  
60.   { 翻转了一下顺序 }  
61.   
62.   s := Format('%1:s%0:s%0:s%1:s',['万','一']);  
63.   //返回: 一万万一  
64.   { 反复使用 }  
65.   
66.   
67.   //Width 与对齐方式  
68.   
69.   s := Format('%d,%8d,%d',[1,2,3]);  
70.   //返回: 1,       2,3  
71.   { 给第二个值指定了8个字符的宽度, 缺少的用空格填充; 如果指定少了则无效 }  
72.   
73.   s := Format('%d,%-8d,%d',[1,2,3]);  
74.   //返回: 1,2       ,3  
75.   { - 表示左对齐, 默认是右对齐的; - 符号在 Width 前面、Index 后面 }  
76.   
77.   
78.   //指定精度 prec  
79.   
80.   s := Format('%.9f',[Pi]);  
81.   //返回: 3.141592654  
82.   { 指定小数点的位数, 取值范围1-9, 输入0也当1用 }  
83.   
84.   s := Format('%.5d',[12]);  
85.   //返回: 00012  
86.   { 这是给整数指定位数, 如果小了则无效 }  
87.   
88.   s := Format('%.3s',['Format']);  
89.   //返回: For  
90.   { 给字符串指定位数, 如果大了则无效 }  
91.   
92.   s := Format('%.3e',[123.456]);  
93.   //返回: 1.23E+002  
94.   { 给科学计数法指定位数 }  
95.   
96.   
97.   //指令顺序:  
98.   
99.   { "%" [index ":"] ["-"] [width] ["." prec] type }  
100.   
101.   ShowMessage(s);  
102. end;  

第二部分（FomatDateTime）：

1. var  
2.   s: string;  
3. begin  
4.   //FormatDateTime 的参数1是 String 格式指令, 参数2是 TDateTime 类型的时间  
5.   
6.   s := FormatDateTime('c', Now); {返回: 2007-12-18 23:56:05}  
7.   {指令 c 表示用短格式显示日期与时间}  
8.   
9.   s := FormatDateTime('d', Now); {返回: 19}  
10.   
11.   s := FormatDateTime('d', StrToDateTime('2008-1-1')); {返回: 1}  
12.   {d 表示日期}  
13.   
14.   s := FormatDateTime('dd', Now); {返回: 19}  
15.   
16.   s := FormatDateTime('dd', StrToDateTime('2008-1-1')); {返回: 01}  
17.   {dd 表示双位日期}  
18.   
19.   s := FormatDateTime('ddd', Now); {返回: 星期三}  
20.   
21.   s := FormatDateTime('dddd', Now); {返回: 星期三}  
22.   {ddd 与 dddd 表示星期; 可能对不同的语种会有区别}  
23.   
24.   s := FormatDateTime('ddddd', Now); {返回: 2007-12-19}  
25.   {ddddd 五个 d 表示短格式日期}  
26.   
27.   s := FormatDateTime('dddddd', Now); {返回: 2007年12月19日}  
28.   {dddddd 六个 d 表示长格式日期}  
29.   
30.   s := FormatDateTime('e', Now); {返回: 7}  
31.   {e 表示年, 1位}  
32.   
33.   s := FormatDateTime('ee', Now); {返回: 07}  
34.   {ee 表示年, 2位}  
35.   
36.   s := FormatDateTime('eee', Now); {返回: 2007}  
37.   
38.   s := FormatDateTime('eeee', Now); {返回: 2007}  
39.   {eee 与 eeee 返回4位数年}  
40.   
41.   s := FormatDateTime('m', Now); {返回: 12}  
42.   {m 表示月, 1位}  
43.   
44.   s := FormatDateTime('mm', StrToDateTime('2008-1-1')); {返回: 01}  
45.   {mm 表示月, 2位}  
46.   
47.   s := FormatDateTime('mmm', Now); {返回: 十二月}  
48.   
49.   s := FormatDateTime('mmmm', Now); {返回: 十二月}  
50.   {mmm 与 mmmm 表示长格式月}  
51.   
52.   s := FormatDateTime('y', Now); {返回: 07}  
53.   
54.   s := FormatDateTime('yy', Now); {返回: 07}  
55.   
56.   s := FormatDateTime('yyy', Now); {返回: 2007}  
57.   
58.   s := FormatDateTime('yyyy', Now); {返回: 2007}  
59.   {y yy yyy yyyy 表示年; 和 e 略有不同}  
60.   
61.   s := FormatDateTime('t', Now); {返回: 0:21}  
62.   
63.   s := FormatDateTime('tt', Now); {返回: 0:22:13}  
64.   {t tt 表示时间}  
65.   
66.   s := FormatDateTime('ampm', Now); {返回:  上午}  
67.   
68.   s := FormatDateTime('tampm', Now); {返回: 0:24 上午}  
69.   {ampm 表示上午、下午}  
70.   
71.   s := FormatDateTime('h', StrToDateTime('2007-12-30 9:58:06')); {返回: 9}  
72.   
73.   s := FormatDateTime('hh', StrToDateTime('2007-12-30 9:58:06')); {返回: 09}  
74.   {h hh 表示时}  
75.   
76.   s := FormatDateTime('n', StrToDateTime('2007-12-30 9:58:06')); {返回: 58}  
77.   
78.   s := FormatDateTime('nn', StrToDateTime('2007-12-30 9:58:06')); {返回: 58}  
79.   {n nn 表示分}  
80.   
81.   s := FormatDateTime('s', StrToDateTime('2007-12-30 9:58:06')); {返回: 6}  
82.   
83.   s := FormatDateTime('ss', StrToDateTime('2007-12-30 9:58:06')); {返回: 06}  
84.   {s ss 表示秒}  
85.   
86.   s := FormatDateTime('z', Now); {返回: 24}  
87.   
88.   s := FormatDateTime('zz', Now); {返回: 524}  
89.   
90.   s := FormatDateTime('zzz', Now); {返回: 524}  
91.   {z zz zzz 表示毫秒}  
92.   
93.   s := FormatDateTime('yy\mm\dd', Now); {返回: 07\12\19}  
94.   
95.   s := FormatDateTime('yy/mm/dd', Now); {返回: 07-12-19}  
96.   
97.   s := FormatDateTime('yy-mm-dd', Now); {返回: 07-12-19}  
98.   
99.   s := FormatDateTime('yy*mm*dd', Now); {返回: 07*12*19}  
100.   {使用分隔符, - 是默认的, / 是与 - 等效的, 假如我非要用 / 显示呢?}  
101.   
102.   s := FormatDateTime('yy"/"mm"/"dd', Now); {返回: 07/12/19}  
103.   
104.   s := FormatDateTime('"当前时间是: "yyyy-m-d h:n:s:zz', Now);   
105.   {返回: 当前时间是: 2007-12-19 0:47:16:576}  
106.   {混入的字符串要包含在双引号中}  
107.   
108.   ShowMessage(s);  
109. end; 

第三部分（FormatFloat）：

1. var  
2.   s: string;  
3. begin  
4.   //FormatFloat 的参数1是 String 格式指令, 参数2是实数类型 Extended  
5.   
6.   s := FormatFloat('###.###',12.3456);  
7.   //返回: 12.346  
8.   s := FormatFloat('000.000',12.3456);  
9.   //返回: 012.346  
10.   s := FormatFloat('#.###',12.3);  
11.   //返回: 12.3  
12.   s := FormatFloat('0.000',12.3);  
13.   //返回: 12.300  
14.   s := FormatFloat('#,#.#',1234567);  
15.   //返回: 1,234,567  
16.   s := FormatFloat('0,0.0',1234567);  
17.   //返回: 1,234,567.0  
18.   s := FormatFloat('0.00E+0',1234567);  
19.   //返回: 1.23E+6  
20.   s := FormatFloat('0.00E+00',1234567);  
21.   //返回: 1.23E+06  
22.   //在科学计数法中使用 # 好像不合适?  
23.   ShowMessage(s);  
24. end;