;优龙2410的板子,然后实验室自己又按照此精简了许多自己做了内部学习板,以下是注解,可能格式有较多错误,请自行保留原稿!!
;==================================================================================================================
;2410Init.s包括了板子上电后的初始话,具体有几个步骤:
;讲述S3C2410启动程序设计
;1. 屏蔽所有中断,关看门狗。
;2. 根据工作频率设置PLL寄存器
;3. 初始化存储控制相关寄存器
;4. 初始化各模式下的栈指针
;5. 设置缺省中断处理函数
;6. 将数据段拷贝到RAM中,将零初始化数据段清零
;7. 跳转到C语言Main入口函数中
;==================================================================================================================
==================================================================================================================
ARM汇编指令部分说明:
1、(这里先明确一下,在ADS下的bootloader代码常看到
[
|
]
他们其实就相当于c语言里面的
Ifdef
Else
Endif)
2、STR R0,[R1],#8 ;将 R0 中的字数据写入以 R1 为地址的存储器中,并将新地址 R1+8 写入 R1。
3、LDR R0,[R1,#8] ;将存储器地址为 R1+8 的字数据读入寄存器 R0。
4、STMFD R13!,{R0,R4-R12,LR} ;将寄存器列表中的寄存器(R0,R4 到R12,LR)存入堆栈。
LDMFD R13!,{R0,R4-R12,PC} ;将堆栈内容恢复到寄存器(R0,R4 到R12,LR)。
{!}为可选后缀,若选用该后缀,则当数据传送完毕之后,将最后的地址写入基址寄存器,否则基址寄存器的内容不改变。
5、DCD(或 DCDU)伪指令用于分配一片连续的字存储单元并用伪指令中指定的表达式初始化。
6、MACRO、MEND 伪指令可以将一段代码定义为一个整体,称为宏指令
7、IMPORT 伪指令用于通知编译器要使用的标号在其他的源文件中定义,
8、bne %B0 %B代表向前搜索,%F代表向后搜索,"0""1"只是标号而已。也就是不等于则向前后者向后跳转到标号0或者标号1的位置。
;==================================================================================================================
;=========================================
; NAME: 2410INIT.S
; DESC: C start up codes
; Configure memory, ISR ,stacks
; Initialize C-variables
; HISTORY:
; 2002.02.25:kwtark: ver 0.0
; 2002.03.20:purnnamu: Add some functions for testing STOP,POWER_OFF mode
;=========================================
GET option.inc ;汇编不能使用include包含头文件,所以用Get
GET memcfg.inc ;汇编也不认识*.h 文件,所有只能用*.inc
GET 2410addr.inc ; 相当于C中的include '2410addr.h'
;=======================================================================================
;下面是对arm处理器模式寄存器对应值的常数定义,arm处理器中有一个CPSR程序状态寄存器
;它的后五位决定目前的处理器模式
;Pre-defined constants ;处理器模式常量: CPSR寄存器的后5位决定目前处理器模式 M[4:0]
;========================================================================================
BIT_SELFREFRESH EQU (1<<22) ; SDRAM refresh control register,22位赋值为1即Self Refresh
USERMODE EQU 0x10
FIQMODE EQU 0x11
IRQMODE EQU 0x12
SVCMODE EQU 0x13
ABORTMODE EQU 0x17
UNDEFMODE EQU 0x1b
MODEMASK EQU 0x1f
NOINT EQU 0xc0
;The location of stacks ;定义处理器各模式下堆栈地址常量,都用于后面的各个模式堆栈初始化
UserStack EQU (_STACK_BASEADDRESS-0x3800) ;0x33ff4800 ~
SVCStack EQU (_STACK_BASEADDRESS-0x2800) ;0x33ff5800 ~
UndefStack EQU (_STACK_BASEADDRESS-0x2400) ;0x33ff5c00 ~
AbortStack EQU (_STACK_BASEADDRESS-0x2000) ;0x33ff6000 ~
IRQStack EQU (_STACK_BASEADDRESS-0x1000) ;0x33ff7000 ~
FIQStack EQU (_STACK_BASEADDRESS-0x0) ;0x33ff8000 ~
;=======================================================================================
;arm处理器有两种工作状态 1.arm:32位 这种工作状态下执行字对准的arm指令
;2.Thumb:16位 这种工作状态执行半字对准的Thumb指令
;因为处理器分为16位 32位两种工作状态 程序的编译器也是分16位和32两种编译方式 所以下面的程序用
;于根据处理器工作状态确定编译器编译方式
;code16伪指令指示汇编编译器后面的指令为16位的thumb指令
;code32伪指令指示汇编编译器后面的指令为32位的arm指令;
;Arm上电时处于ARM状态,故无论指令为ARM集或Thumb集,都先强制成ARM集,待init.s初始化完成后再根据用
;户的编译配置转换成相应的指令模式。为此,定义变量THUMBCODE作为指示,跳转到main之前根据其值切换指令模式
;以下这段是为了统一目前的处理器工作状态和软件编译方式(16位编译环境使用tasm.exe编译)
;========================================================================================
;Check if tasm.exe(armasm -16 ...@ADS 1.0) is used.
GBLL THUMBCODE
[ {CONFIG} = 16 ;如果发现是在用16位代码的话(编译选项中指定使用thumb指令)
THUMBCODE SETL {TRUE} ;设置THUMBCODE 为 true
CODE32
|
THUMBCODE SETL {FALSE} ;32位,THUMBCODE 为 false
]
MACRO
MOV_PC_LR
[ THUMBCODE
bx lr ;在ARM模式中要使用BX指令转跳到THUMB指令,并转换模式. bx指令会根据PC最后1位来确定是否进入thumb状态
|
mov pc,lr
]
MEND ;宏结束标准
MACRO
MOVEQ_PC_LR
[ THUMBCODE
bxeq lr
|
moveq pc,lr
]
MEND
;=======================================================================================
;下面这个宏是用于第一次查表过程的实现中断向量的重定向,如果你比较细心的话就是发现
;在_ISR_STARTADDRESS=0x33FF_FF00里定义的第一级中断向量表是采用型如Handle***的方式的.
;而在程序的ENTRY处(程序开始处)采用的是b Handler***的方式.
;在这里Handler***就是通过HANDLER这个宏和Handle***建立联系的.
;这种方式的优点就是正真定义的向量数据在内存空间里,而不是在ENTRY处的ROM(FLASH)空间里,
;这样,我们就可以在程序里灵活的改动向量的数据了.
;;这段程序用于把中断服务程序的首地址装载到pc中,有人称之为"加载程序"。
;本初始化程序定义了一个数据区(在文件最后),34个字空间,存放相应中断服务程序的首地址。每个字
;空间都有一个标号,以Handle***命名。
;在向量中断模式下使用"加载程序"来执行中断服务程序。
;这里就必须讲一下向量中断模式和非向量中断模式的概念
;向量中断模式是当cpu读取位于0x18处的IRQ中断指令的时候,系统自动读取对应于该中断源确定地址上的;
;指令取代0x18处的指令,通过跳转指令系统就直接跳转到对应地址
;函数中 节省了中断处理时间提高了中断处理速度标 例如 ADC中断的向量地址为0xC0,则在0xC0处放如下
;代码:ldr PC,=HandlerADC 当ADC中断产生的时候系统会
;自动跳转到HandlerADC函数中
;非向量中断模式处理方式是一种传统的中断处理方法,当系统产生中断的时候,系统将interrupt pending
;寄存器中对应标志位置位 然后跳转到位于0x18处的统一中断
;函数中 该函数通过读取interrupt pending寄存器中对应标志位 来判断中断源 并根据优先级关系再跳到
;对应中断源的处理代码中
;========================================================================================
MACRO ;宏指令定义
$HandlerLabel HANDLER $HandleLabel
$HandlerLabel
sub sp,sp,#4 ;decrement sp(to store jump address) sp = sp - 4
stmfd sp!,{r0} ;PUSH the work register to stack(lr does't push because it return to original address)
ldr r0,=$HandleLabel;load the address of HandleXXX to r0
ldr r0,[r0] ;load the contents(service routine start address) of HandleXXX
str r0,[sp,#4] ;store the contents(ISR) of HandleXXX to stack
ldmfd sp!,{r0,pc} ;POP the work register and pc(jump to ISR)
MEND
;=========================================================================================
;在这里用IMPORT伪指令(和c语言的extren一样)引入|Image$$RO$$Base|,|Image$$RO$$Limit|...
;这些变量是通过ADS的工程设置里面设定的RO Base和RW Base设定的,
;最终由编译脚本和连接程序导入程序.
;那为什么要引入这玩意呢,最简单的用处是可以根据它们拷贝自已
;Image$$RO$$Base等比较古怪的变量是编译器生成的。RO, RW, ZI这三个段都保存在Flash中,但RW,ZI在Flash中的
;地址肯定不是程序运行时变量所存储的位置,因此我们的程序在初始化时应该把Flash中的RW,ZI拷贝到RAM的对应位置。
;一般情况下,我们可以利用编译器替我们实现这个操作。比如我们跳转到main()时,使用 b __Main,编译器就会在__Main
;和Main之间插入一段汇编代码,来替我们完成RW,ZI段的初始化。 如果我们使用 b Main, 那么初始化工作要我们自己做。
;编译器会生成如下变量告诉我们RO,RW,ZI三个段应该位于什么位置,但是它并没有告诉我们RW,ZI在Flash中存储在什么位置,
;实际上RW,ZI在Flash中的位置就紧接着RO存储。我们知道了Image$$RO$$Base,Image$$RO$$Limit,那么Image$$RO$$Limit就
;是RW(ROM data)的开始。
;一个arm("程序" 笔者少敲俩字 呵呵)由RO,RW,ZI三个断组成 其中RO为代码段,RW是已经初始化的全局变量,ZI是未初始化的全局变量
;(对于GNU工具 对应的概念是TEXT ,DATA,BSS)bootloader
;bootloader要将RW段复制到ram中并将ZI段清零(这句很重要) 编译器使用下列段来记录各段的起始和结束地址
;==========================================================================================
; |Image$$RO$$Base| ; RO段起始地址
; |Image$$RO$$Limit| ; RO段结束地址加1
; |Image$$RW$$Base| ; RW段起始地址
; |Image$$RW$$Limit| ; RW段结束地址加1
; |Image$$ZI$$Base| ; ZI段起始地址
; |Image$$ZI$$Limit| ; ZI段结束地址加1
IMPORT |Image$$RO$$Base| ; Base of ROM code
IMPORT |Image$$RO$$Limit| ; End of ROM code (=start of ROM data)
IMPORT |Image$$RW$$Base| ; Base of RAM to initialise
IMPORT |Image$$ZI$$Base| ; Base and limit of area
IMPORT |Image$$ZI$$Limit| ; to zero initialise
;=================================================================
;这里引入一些在其它文件中实现在函数,包括为我们所熟知的main函数
;=================================================================
IMPORT MMU_SetAsyncBusMode
IMPORT MMU_SetFastBusMode
IMPORT Main ; The main entry of mon program
;=================================================================
;从这里开始就是正真的代码入口了!
;=================================================================
AREA SelfBoot, CODE, READONLY ;AREA 伪指令用于定义一个代码段或数据段,这表明下面的是一个名为SelfBoot的代码段
;板子上电和复位后 程序开始从位于0x0处开始执行硬件刚刚上电复位后 程序从这里开始执行跳转到标为ResetHandler处执行
ENTRY ;定义程序的入口(调试用)
EXPORT __ENTRY
__ENTRY
ResetEntry
;1)The code, which converts to Big-endian, should be in little endian code.
;2)The following little endian code will be compiled in Big-Endian mode.
; The code byte order should be changed as the memory bus width.
;3)The pseudo instruction,DCD can't be used here because the linker generates error.
;=================================================================
;异常中断矢量表(每个表项占4个字节) 下面是中断向量表 一旦系统运行时有中断发生 即使移植了操作;系统 如linux 处理器已经
;把控制权交给了操作系统 一旦发生中断 处理器还是会跳转到从0x0开始 中断向量表中某个中断表项(依据中断类型)开始执行
;ASSERT :DEF:ENDIAN_CHANGE ;判断ENDIAN_CHANGE是否已定义,ASSERT 是断言伪指令,语法是:ASSERT +逻辑表达式 ,
;def 是逻辑伪操作符,格式为: :DEF:label,作用是:判断label是否定义过
;=================================================================
[ ENDIAN_CHANGE ;如果已经定义了ENDIAN_CHANGE,则(在Option.inc里已经设为FALSE )
ASSERT :DEF:ENTRY_BUS_WIDTH ;判断ENTRY_BUS_WIDTH是否已定义
[ ENTRY_BUS_WIDTH=32
;在bigendian中,地址为A的字单元包括字节单元A,A+1,A+2,A+3,字节单元由高位到低位为;A,A+1,A+2,A+3
b ChangeBigEndian ;DCD 0xea000007 ;是b ChangeBigEndian指令,只是由于总线不一样而取机器码的顺序不一样
]
[ ENTRY_BUS_WIDTH=16 ;在option.inc中将ENDIAN_CHANGE设成16就到这儿了,转跳到复位程序入口
andeq r14,r7,r0,lsl #20 ;DCD 0x0007ea00
]
[ ENTRY_BUS_WIDTH=8
streq r0,[r0,-r10,ror #1] ;DCD 0x070000ea
]
|
b ResetHandler
]
b HandlerUndef ;handler for Undefined mode
b HandlerSWI ;handler for SWI interrupt 转跳到SWI 中断程序入口
b HandlerPabort ;handler for PAbort 转跳到PAbort(指令异常)程序入口
b HandlerDabort ;handler for DAbort 转跳到DAbort(数据异常)程序入口
b . ;reserved
b HandlerIRQ ;handler for IRQ interrupt
b HandlerFIQ ;handler for FIQ interrupt
;==================================================================================
;下面是改变大小端的程序,这里采用直接定义机器码的方式,至说为什么这么做就得问三星了
;反正我们程序里这段代码也不会去执行,不用去管它
;条件编译,在编译成机器码前就设定好
;==================================================================================
;@0x20
b EnterPWDN
ChangeBigEndian
;@0x24
[ ENTRY_BUS_WIDTH=32
DCD 0xee110f10 ;0xee110f10 => mrc p15,0,r0,c1,c0,0
DCD 0xe3800080 ;0xe3800080 => orr r0,r0,#0x80; //Big-endian
DCD 0xee010f10 ;0xee010f10 => mcr p15,0,r0,c1,c0,0
]
[ ENTRY_BUS_WIDTH=16
DCD 0x0f10ee11
DCD 0x0080e380
DCD 0x0f10ee01
]
[ ENTRY_BUS_WIDTH=8
DCD 0x100f11ee
DCD 0x800080e3
DCD 0x100f01ee
]
DCD 0xffffffff ;swinv 0xffffff is similar with NOP and run well in both endian mode.
DCD 0xffffffff
DCD 0xffffffff
DCD 0xffffffff
DCD 0xffffffff
b ResetHandler
;==================================================================================
;进入掉电模式功能
; 1. SDRAM 必须在自刷新模式.
; 2. 所有中断必须屏蔽 for SDRAM/DRAM self-refresh.
; 3. LCD 关闭for SDRAM/DRAM self-refresh.
; 4. The I-cache 可能需要开启.
; 5. The location of the following code may have not to be changed.
;==================================================================================
;void EnterPWDN(int CLKCON);
EnterPWDN ;进入PWDN
mov r2,r0 ;r2=rCLKCON
tst r0,#0x8 ;测试是否进入POWER_OFF mode? ;将寄存器 R0 的值与立即数 0x8 按位的标志位 并根据结果设置 CPSR 的标志位
bne ENTER_POWER_OFF
ENTER_STOP ;进入PWDN后如果不是POWER_OFF则进入stop
ldr r0,=REFRESH
ldr r3,[r0] ;r3=rREFRESH
mov r1, r3
orr r1, r1, #BIT_SELFREFRESH
str r1, [r0] ;Enable SDRAM self-refresh ;使SDRAM自动刷新
mov r1,#16 ;wait until self-refresh is issued. may not be needed. ;等待刷新,也可能不需要
0 subs r1,r1,#1
bne %B0 ;不等于则向前后者向后跳转到标号0的位置
ldr r0,=CLKCON ;enter STOP mode.
str r2,[r0]
mov r1,#32
0 subs r1,r1,#1 ;1) wait until the STOP mode is in effect.
bne %B0 ;2) Or wait here until the CPU&Peripherals will be turned-off
; Entering POWER_OFF mode, only the reset by wake-up is available.
ldr r0,=REFRESH ;exit from SDRAM self refresh mode.
str r3,[r0]
MOV_PC_LR
;==================================================================================
;进入POWER_OFF
;==================================================================================
ENTER_POWER_OFF
;NOTE.
;1) rGSTATUS3 should have the return address after wake-up from POWER_OFF mode. ;rGSTATUS3有一个返回地址
ldr r0,=REFRESH
ldr r1,[r0] ;r1=rREFRESH
orr r1, r1, #BIT_SELFREFRESH ;ORR 指令用于在两个操作数上进行逻辑或运算
str r1, [r0] ;Enable SDRAM self-refresh 使能自刷新模式
mov r1,#16 ;Wait until self-refresh is issued,which may not be needed. 直到自刷新出问题,自刷新不能被使用
0 subs r1,r1,#1
bne %B0
ldr r1,=MISCCR
ldr r0,[r1]
orr r0,r0,#(7<<17) ;Make sure that SCLK0:SCLK->0, SCLK1:SCLK->0, SCKE=L during boot-up
str r0,[r1]
ldr r0,=CLKCON
str r2,[r0]
b . ;CPU will die here.CPU不工作
;==================================================================================
;唤醒模式
;==================================================================================
WAKEUP_POWER_OFF
;Release SCLKn after wake-up from the POWER_OFF mode.
ldr r1,=MISCCR
ldr r0,[r1]
bic r0,r0,#(7<<17) ;SCLK0:0->SCLK, SCLK1:0->SCLK, SCKE:L->H
str r0,[r1]
;Set memory control registers 设置存储控制寄存器
ldr r0,=SMRDATA
ldr r1,=BWSCON ;BWSCON Address ;总线宽度和等待控制寄存器
add r2, r0, #52 ;End address of SMRDATA SMRDATA的结束地址
0
ldr r3, [r0], #4
str r3, [r1], #4
cmp r2, r0
bne %B0 ;数据在以SMRDATA为起始的存储区
mov r1,#256
0 subs r1,r1,#1 ;1) wait until the SelfRefresh is released. 直到自刷新被释放,否则程序在此做循环
bne %B0
ldr r1,=GSTATUS3 ;GSTATUS3 has the start address just after POWER_OFF wake-up 在关机唤醒之后GSTATUS3才有起始地址
ldr r0,[r1]
mov pc,r0
;==================================================================================
;异常中断宏调用,下面是具体的中断处理函数跳转的宏,通过上面的$HandlerLabel的宏定义
;展开后跳转到对应的中断处理;函数(对于向量中断)
;==================================================================================
LTORG
HandlerFIQ HANDLER HandleFIQ
HandlerIRQ HANDLER HandleIRQ
HandlerUndef HANDLER HandleUndef
HandlerSWI HANDLER HandleSWI
HandlerDabort HANDLER HandleDabort
HandlerPabort HANDLER HandlePabort
;HandlerUndef
; sub sp, sp, #4 ;decrement sp(to store jump address)
; stmfd sp!, {r14} ;PUSH the work register to stack(lr does't push because it return to original address)
; ldr r0, =HandleUndef ;load the address of HandleXXX to r0
; ldr r0, [r0] ;load the contents(service routine start address) of HandleXXX
; str r0, [sp, #4] ;store the contents(ISR) of HandleXXX to stack
; ldmfd sp!, {r0, pc}
;==================================================================================
;下面这段程序是用来处理非向量中断,具体判断I_ISPR中各位是否置1 置1表示目前此中断等待响应
;(每次只能有一位置1),从最高优先级中断位开始判断,检测到等待服务中断就将pc置为中断服务函数首地址
;采用INTOFFSET寄存器判断IRQ中断源
;==================================================================================
IsrIRQ
sub sp, sp, #4 ;reserved for PC ;预留返回指针的存储位置
stmfd sp!, {r8-r9}
ldr r9, =INTOFFSET ;INTOFFSET中断请求源
ldr r9, [r9]
ldr r8, =HandleEINT0
add r8, r8,r9,lsl #2
ldr r8, [r8]
str r8, [sp,#8]
ldmfd sp!,{r8-r9,pc}
;===================================================================================
;1.禁止看门狗 屏蔽所有中断
; ENTRY 初始化程序入口指令
;扳子上电和复位后 程序开始从位于0x0执行b ResetHandler 程序从跳转到这里执行
;板子上电复位后 执行几个步骤这里通过标号在注释中加1,2,3....标示 标号表示执行顺序
;===================================================================================
ResetHandler
ldr r0,=WTCON ;watch dog disable
ldr r1,=0x0
str r1,[r0] ;将 R0 中的字数据写入以 R1 为地址的存储器中
;(将看门狗定时器清零,查看datasheet,WTCON的第0位是看门狗定时器复位输出信号开关。为0,
;则程序关闭了S3C2440A的看门狗复位功能。)
ldr r0,=INTMSK
ldr r1,=0xffffffff ;all interrupt disable
str r1,[r0]
;(将中断屏蔽寄存器全部置1,将对应的中断全部关闭。)
ldr r0,=INTSUBMSK
ldr r1,=0x3ff ;all sub interrupt disable
str r1,[r0]
;(将子中断屏蔽寄存器全部置1,将子中断屏蔽寄存器对应的中断全部关闭。)
[ {FALSE}
; rGPFDAT = (rGPFDAT & ~(0xf<<4)) | ((~data & 0xf)<<4);
; Led_Display ;启动指示灯亮,查看硬件电路
ldr r0,=GPFCON
ldr r1,=0x5500
str r1,[r0]
ldr r0,=GPFDAT
ldr r1,=0x10
str r1,[r0]
]
;=====================================================================
;2.根据工作频率设置pll
;这里介绍一下计算公式
;Fpllo=(m*Fin)/(p*2^s)
;m=MDIV+8,p=PDIV+2,s=SDIV
;Fpllo必须大于20Mhz小于66Mhz
;Fpllo*2^s必须小于170Mhz
;如下面的PLLCON设定中的M_DIV P_DIV S_DIV是取自option.h中
;#elif (MCLK==40000000)
;#define PLL_M (0x48)
;#define PLL_P (0x3)
;#define PLL_S (0x2)
;所以m=MDIV+8=80,p=PDIV+2=5,s=SDIV=2
;硬件使用晶振为10Mhz,即Fin=10Mhz
;Fpllo=80*10/5*2^2=40Mhz
;=====================================================================
;To reduce PLL lock time, adjust the LOCKTIME register.
ldr r0,=LOCKTIME
ldr r1,=0xffffff
str r1,[r0]
[ PLL_ON_START
;Configure MPLL
ldr r0,=MPLLCON
ldr r1,=((M_MDIV<<12)+(M_PDIV<<4)+M_SDIV) ;Fin=12MHz,Fout=50MHz 参数在option.inc中
str r1,[r0]
]
;Check if the boot is caused by the wake-up from POWER_OFF mode.;检查启动是从休眠模式唤醒
; ldr r1,=GSTATUS2
; ldr r0,[r1]
; tst r0,#0x2
;In case of the wake-up from POWER_OFF mode, go to POWER_OFF_WAKEUP handler.
; bne WAKEUP_POWER_OFF ;是从休眠模式唤醒,跳转到 POWER_OFF_WAKEUP handler
EXPORT StartPointAfterPowerOffWakeUp
StartPointAfterPowerOffWakeUp
;===================================================================================
;3.设置存储相关寄存器的程序
;SMRDATA中涉及的值请参考memcfg.inc程序
;===================================================================================
;Set memory control registers
adr r0, SMRDATA ;can't use ldr r0, =xxxx important!!!
ldr r1, =BWSCON ;BWSCON Address ;BWSCON地址
add r2, r0, #52 ;End address of SMRDATA
0
ldr r3, [r0], #4
str r3, [r1], #4
cmp r2, r0
bne %B0
;Initialize stacks ;初始化堆栈
bl InitStacks ;当程序无条件跳转到标号 InitStacks 处执行时,同时将当前的 PC 值保存到 R14 中
;===================================================================================
; 进入C语言前的最后一步了,就是把我们常说查二级向量表的中断例程安装到一级向量表(异常向量表)里.
;5.设置缺省中断处理函数
;===================================================================================
; Setup IRQ handler ;建立中断表
ldr r0,=HandleIRQ ;This routine is needed
ldr r1,=IsrIRQ ;if there isn't 'subs pc,lr,#4' at 0x18, 0x1c
str r1,[r0] ;initialize the IRQ 将普通中断判断程序的入口地址给HandleIRQ