CTE

最新推荐文章于 2024-08-13 15:40:03 发布
xyj052
最新推荐文章于 2024-08-13 15:40:03 发布
阅读量589
点赞数
分类专栏： SQL SERVER
SQL SERVER 专栏收录该内容
9 篇文章 0 订阅
订阅专栏
 
create table tb(id varchar(3) , pid varchar(3) , name varchar(10))
insert into tb values('001' , null  , '广东省')
insert into tb values('002' , '001' , '广州市')
insert into tb values('003' , '001' , '深圳市')
insert into tb values('004' , '002' , '天河区')
insert into tb values('005' , '003' , '罗湖区')
insert into tb values('006' , '003' , '福田区')
insert into tb values('007' , '003' , '宝安区')
insert into tb values('008' , '007' , '西乡镇')
insert into tb values('009' , '007' , '龙华镇')
insert into tb values('010' , '007' , '松岗镇')
go
 
--查询各节点的父路径函数(从父到子)
create function f_pid1(@id varchar(3)) returns varchar(100)
as
begin
  declare @re_str as varchar(100)
  set @re_str = ''
  select @re_str = name from tb where id = @id
  while exists (select 1 from tb where id = @id and pid is not null)
    begin
      select @id = b.id , @re_str = b.name + ',' + @re_str from tb a , tb b where a.id = @id and a.pid = b.id
    end
  return @re_str
end
go
--查询各节点的父路径函数(从子到父)
create function f_pid2(@id varchar(3)) returns varchar(100)
as
begin
  declare @re_str as varchar(100)
  set @re_str = ''
  select @re_str = name from tb where id = @id
  while exists (select 1 from tb where id = @id and pid is not null)
    begin
      select @id = b.id , @re_str = @re_str + ',' + b.name from tb a , tb b where a.id = @id and a.pid = b.id
    end
  return @re_str
end
go
 
select * , 
       dbo.f_pid1(id) [路径(从父到子)] ,
       dbo.f_pid2(id) [路径(从子到父)]
from tb order by id
 
drop function f_pid1 , f_pid2
drop table tb
 
/*
id   pid  name    路径(从父到子)               路径(从子到父)              
---- ---- ------  ---------------------------  ----------------------------
001  NULL 广东省  广东省                       广东省
002  001  广州市  广东省,广州市                广州市,广东省
003  001  深圳市  广东省,深圳市                深圳市,广东省
004  002  天河区  广东省,广州市,天河区         天河区,广州市,广东省
005  003  罗湖区  广东省,深圳市,罗湖区         罗湖区,深圳市,广东省
006  003  福田区  广东省,深圳市,福田区         福田区,深圳市,广东省
007  003  宝安区  广东省,深圳市,宝安区         宝安区,深圳市,广东省
008  007  西乡镇  广东省,深圳市,宝安区,西乡镇  西乡镇,宝安区,深圳市,广东省
009  007  龙华镇  广东省,深圳市,宝安区,龙华镇  龙华镇,宝安区,深圳市,广东省
010  007  松岗镇  广东省,深圳市,宝安区,松岗镇  松岗镇,宝安区,深圳市,广东省
 
（所影响的行数为 10 行）
*/
 
 
 
 
 
create table tb(id varchar(3) , pid varchar(3) , name nvarchar(10))
insert into tb values('001' , null  , N'广东省')
insert into tb values('002' , '001' , N'广州市')
insert into tb values('003' , '001' , N'深圳市')
insert into tb values('004' , '002' , N'天河区')
insert into tb values('005' , '003' , N'罗湖区')
insert into tb values('006' , '003' , N'福田区')
insert into tb values('007' , '003' , N'宝安区')
insert into tb values('008' , '007' , N'西乡镇')
insert into tb values('009' , '007' , N'龙华镇')
insert into tb values('010' , '007' , N'松岗镇')
go
 
;with t as
(
    select id , pid = id from tb 
    union all
    select t.id , pid = tb.pid from t inner join tb on t.pid = tb.id
) 
select id , 
       [路径(从父到子)] = STUFF((SELECT ',' + pid FROM t WHERE id = tb.id order by t.id , t.pid FOR XML PATH('')) , 1 , 1 , ''),
       [路径(从子到父)] = STUFF((SELECT ',' + pid FROM t WHERE id = tb.id FOR XML PATH('')) , 1 , 1 , '')
from tb
group by id
order by id
/*
id   路径(从父到子)   路径(从子到父)
---- ---------------  ---------------
001  001              001
002  001,002          002,001
003  001,003          003,001
004  001,002,004      004,002,001
005  001,003,005      005,003,001
006  001,003,006      006,003,001
007  001,003,007      007,003,001
008  001,003,007,008  008,007,003,001
009  001,003,007,009  009,007,003,001
010  001,003,007,010  010,007,003,001
 
(10 行受影响)
*/
 
 
;with t as
(
    select id , name , pid = id , path = cast(name as nvarchar(100)) from tb 
    union all
    select t.id , t.name , pid = tb.pid , path = cast(tb.name as nvarchar(100)) from t join tb on tb.id = t.pid 
)
select id , 
       name ,
       [路径(从父到子)_1] = pid1, 
       [路径(从父到子)_2] = reverse(substring(reverse(path1) , charindex(',' , reverse(path1)) + 1 , len(path1))) ,
       [路径(从子到父)_1] = pid2,
       [路径(从子到父)_2] = substring(path2 , charindex(',' , path2) + 1 , len(path2)) from
(
select id , name ,
       pid1 = STUFF((SELECT ',' + pid FROM t WHERE id = tb.id order by t.id , t.pid FOR XML PATH('')) , 1 , 1 , ''),
       pid2 = STUFF((SELECT ',' + pid FROM t WHERE id = tb.id FOR XML PATH('')) , 1 , 1 , ''),
       path1 = STUFF((SELECT ',' + path FROM t WHERE id = tb.id order by t.id , t.pid FOR XML PATH('')) , 1 , 1 , ''),
       path2 = STUFF((SELECT ',' + path FROM t WHERE id = tb.id FOR XML PATH('')) , 1 , 1 , '')
from tb
group by id , name
) m
order by id
/*
id   name    路径(从父到子)_1  路径(从父到子)_2             路径(从子到父)_1  路径(从子到父)_2
---- ------  ----------------  ---------------------------  ----------------  ---------------------------
001  广东省  001               广东省                       001               广东省
002  广州市  001,002           广东省,广州市                002,001           广州市,广东省
003  深圳市  001,003           广东省,深圳市                003,001           深圳市,广东省
004  天河区  001,002,004       广东省,广州市,天河区         004,002,001       天河区,广州市,广东省
005  罗湖区  001,003,005       广东省,深圳市,罗湖区         005,003,001       罗湖区,深圳市,广东省
006  福田区  001,003,006       广东省,深圳市,福田区         006,003,001       福田区,深圳市,广东省
007  宝安区  001,003,007       广东省,深圳市,宝安区         007,003,001       宝安区,深圳市,广东省
008  西乡镇  001,003,007,008   广东省,深圳市,宝安区,西乡镇  008,007,003,001   西乡镇,宝安区,深圳市,广东省
009  龙华镇  001,003,007,009   广东省,深圳市,宝安区,龙华镇  009,007,003,001   龙华镇,宝安区,深圳市,广东省
010  松岗镇  001,003,007,010   广东省,深圳市,宝安区,松岗镇  010,007,003,001   松岗镇,宝安区,深圳市,广东省
 
(10 行受影响)
*/
 
drop table tb
 
--参考一下实例
--> 生成测试数据表:tb
IF NOT OBJECT_ID('[tb]') IS NULL
 DROP TABLE [tb]
GO
CREATE TABLE [tb](GUID INT IDENTITY,[col1] NVARCHAR(10),[col2] NVARCHAR(20))
INSERT [tb]
SELECT N'A','01' UNION ALL
SELECT N'B','01.01' UNION ALL
SELECT N'C','01.01.01' UNION ALL
SELECT N'F','01.01.01.01' UNION ALL
SELECT N'E','01.01.01.02' UNION ALL
SELECT N'D','01.01.01.03' UNION ALL
SELECT N'O','02' UNION ALL
SELECT N'P','02.01' UNION ALL
SELECT N'Q','02.01.01' 
GO
--SELECT * FROM [tb]
 
-->SQL查询如下:
 
---另一种方法
;WITH T AS
(
   SELECT *,PATH=CAST([COL1] AS VARCHAR(1000)) FROM TB A
       WHERE NOT EXISTS(
        SELECT 1 FROM TB 
     WHERE A.COL2 LIKE COL2+'%' 
   AND LEN(A.COL2)>LEN(COL2))
   UNION ALL
   SELECT A.*,CAST(PATH+'-->'+A.COL1 AS VARCHAR(1000))
   FROM TB A 
   JOIN T B 
        ON A.COL2 LIKE B.COL2+'%' 
 
           AND LEN(A.COL2)-3=LEN(B.COL2)
)
 
SELECT * FROM T ORDER BY LEFT(COL2,2)
 
/*
 
GUID        COL1        COL2                  PATH
 
----------- ---------- -------------------- --------------------
 
1           A          01                   A
 
2           B          01.01                A-->B
 
3           C          01.01.01             A-->B-->C
 
4           F          01.01.01.01          A-->B-->C-->F
 
5           E          01.01.01.02          A-->B-->C-->E
 
6           D          01.01.01.03          A-->B-->C-->D
 
7           O          02                   O
 
8           P          02.01                O-->P
 
9           Q          02.01.01             O-->P-->Q
(9 行受影响)
 
*/
 
 
;WITH T AS
 
(
    SELECT *,CAST(COL1  AS VARCHAR(1000)) AS PATH
    FROM  TB 
    WHERE COL2 NOT LIKE '%.%'
    UNION ALL
    SELECT A.*,CAST(B.PATH+'-->'+A.COL1 AS VARCHAR(1000))
    FROM TB A,T B
    WHERE A.COL2 LIKE B.COL2+'.[01-99][01-99]'
)
 
SELECT * FROM T 
ORDER BY LEFT(COL2,2)
 
/*
 
GUID        COL1        COL2                  PATH
 
----------- ---------- -------------------- --------------------
 
1           A          01                   A
 
2           B          01.01                A-->B
 
3           C          01.01.01             A-->B-->C
 
4           F          01.01.01.01          A-->B-->C-->F
 
5           E          01.01.01.02          A-->B-->C-->E
 
6           D          01.01.01.03          A-->B-->C-->D
 
7           O          02                   O
 
8           P          02.01                O-->P
 
9           Q          02.01.01             O-->P-->Q
 
 (9 行受影响)
 
*/