MySQL 启动 备份 助手v1.03.bat 批处理

MySQL 启动助手v1.03.bat 批处理

测试：MySQL 5.5.62 绝对可以用。

今天写了一个方便MySQL 在Windows下启动和备份，等待小白来测试，有问题请留言告诉我，谢谢使用。

功能：1.启动服务  3.查询分析器  5.导出数据库  7.设置手动
           2.关闭服务  4.导入数据    6.导出数据表  8.设置自动
           9.设置禁止 10一键备份    0.退出

1.03版本更新说明

1.增加远程备份，增加一键备份，增加修改备份目录，

2.更新了菜单选项

使用说明：

1.请将下面的文件保存成 MySQL 启动助手v1.03.bat

2.直接在Windows下双击运行。

@echo off
title MySQL启动助手 v1.03

:: MySQL 主机IP地址
set HOSTIP=localhost
:: MySQL 用户名 
set USERNAME=root 
:: MySQL 密码 
set PASSWORD=123456
:: 备份路径
set BACKUPDIR=D:/

::批处理解决十点前获取小时补零
if %time:~0,2% lss 10 (set hour=0%time:~1,1%) else (set hour=%time:~0,2%)

::设置保存路径
set BACKUP_NAME=%date:~0,4%%date:~5,2%%date:~8,2%^_%hour%%time:~3,2%%time:~6,2%

:menu
cls
echo.  ------------------------------------------------------------
echo.  +               欢迎使用MySQL启动助手                      +
echo.  +  指令菜单：                                              +
echo.  +  1.启动服务  3.查询分析器  5.导出数据库  7.设置手动      +
echo.  +  2.关闭服务  4.导入数据    6.导出数据表  8.设置自动      +
echo.  +  9.设置禁用 10.一键备份  0.退出                          +
echo.  +                                                          +
echo.  +  温馨提醒：                                              +
echo.  +  1.请启动服务器后，再进行备份                            +
echo.  +  2.导出数据存放在备份目录，可手动修改                    +
echo.  +    导出的文件名(数据库名_数据表_日期_时间.sql            +
echo.  +  3.导入数据表时，如果数据库不存在，请先创建再导入        +
echo.  +  作者：风云无痕 QQ：925776958 版本 1.03 时间：2019-01-05 +
echo.  ------------------------------------------------------------
echo.  
echo.  日期：%date% 时间：%time%
echo.
set choose=""
set /p choose= 请输入指令[0/./n/./10]:
if /i "%choose%"=="0" (goto:exit)
if /i "%choose%"=="1" (goto:start)
if /i "%choose%"=="2" (goto:stop)
if /i "%choose%"=="3" (goto:login)
if /i "%choose%"=="4" (goto:import)
if /i "%choose%"=="5" (goto:database_backup)
if /i "%choose%"=="6" (goto:table_backup)
if /i "%choose%"=="7" (goto:demand)
if /i "%choose%"=="8" (goto:auto)
if /i "%choose%"=="9" (goto:disabled)
if /i "%choose%"=="10" (goto:all_backup)

:: 0 → exit
:exit
cls
echo. 谢谢使用MySQL启动助手...
ping -n 2 127.0.0.1>nul
exit

:: 1 → start
:start
echo.
net start mysql
echo 服务启动完毕!
pause
goto:menu

:: 2 → stop
:stop
echo.
net stop mysql
echo 服务已关闭!
pause
goto:menu

:: 3 → login
:login
echo. 输入密码：
mysql -uroot -p
goto:menu

:: 4 → import
:import
set /p DATABASES= 需要导入的数据库名字:
set /p file_name= 需要导入的文件路径:
echo. 开始导入数据库... 
for %%D in (%file_name%) do ( 
echo. 正在导入 %%D 数据库... 
mysql -u%USERNAME% -p%PASSWORD% %DATABASES% < %%D 
) 
echo. 完成数据库导入！
pause
goto menu

:: 5 → database_backup
: database_backup 
set /p DATABASES= 需要导出的数据库名字(多个用空格分隔):
echo. 开始导出数据库... 
for %%D in (%DATABASES%) do ( 
echo. 正在导出 %%D 数据库... 
mysqldump -u%USERNAME% -p%PASSWORD% --host=%HOSTIP% %%D > %BACKUPDIR%%%D_%BACKUP_NAME%.sql 2>nul 
) 
echo. 完成数据库导出！
pause
goto menu

:: 6 → table_backup
: table_backup 
set /p DATABASES= 需要导出的数据库名字(只能输入一个):
set /p TABLES= 需要导出的表名字(多个用空格分隔):
echo. 开始导出数据库... 
for %%D in (%TABLES%) do ( 
echo. 正在导出 %DATABASES% 数据库的 %%D 数据表... 
mysqldump -u%USERNAME% -p%PASSWORD% --host=%HOSTIP% %DATABASES% %%D > %BACKUPDIR%%DATABASES%_%%D_%BACKUP_NAME%.sql 2>nul 
) 
echo. 完成数据库导出！
pause
goto menu

:: 7 → demand
: demand
sc config MySQL start= demand
pause
goto menu

:: 8 → auto
: auto
sc config MySQL start= auto
pause
goto menu

:: 9 → disabled
: disabled
sc config MySQL start= disabled
pause
goto menu

:: 10 → 一键备份
:all_backup
echo. 开始备份所有数据库... 
mysqldump -u%USERNAME% -p%PASSWORD% --host=%HOSTIP% --all-databases > %BACKUPDIR%all_databases_%BACKUP_NAME%.sql 2>nul 
) 
echo. 完成所有数据库导出！
pause
goto menu