windows xp 使用bat文件DOS批处理文件设置网络地址为固定或者动态获取

最新推荐文章于 2024-05-24 09:05:05 发布

yanhc519

最新推荐文章于 2024-05-24 09:05:05 发布

阅读量1.7k

点赞数

分类专栏： Windows 文章标签： windows 网络 dos xp interface makefile

本文链接：https://blog.csdn.net/yanhc519/article/details/6978160

版权

Windows 专栏收录该内容

2 篇文章 0 订阅

订阅专栏

有时候需要来回切换网络的IP地址为静态或者自动获取，很麻烦，只知道linux上可以写shell文件来批处理，原来windows上也可以写批处理文件。

从网上找了找，还真有，挺方便的。这里是设置无线网络地址的，可以在里面修改。

@echo off
cls
rem 这里为固定IP地址的配置信息,请按你自己要求修改rem 
rem 你的IP地址rem 
set IP=192.168.0.10
rem 掩码rem 
set MASK=255.255.255.0
rem 网关rem 
set GATEWAY=192.168.0.1
set DNS=8.8.8.8
rem 连接名称 用ipconfig可以看到你自己的连接名称rem 
set INTERFACE=无线网络连接
:MENU
echo **********************
echo.
echo 动态获取IP地址dynamic 请按-d
echo.
echo 固定IP地址static 请按-s
echo.
echo **********************
echo.
set /p KEY= 请输入您的选择：
if %KEY%  == d goto DHCP
if %KEY%  == s goto MANUAL
goto END
:DHCP
echo.
echo 快速设置IP地址和DNS为“自动获得”
echo.
netsh interface ip set address "%INTERFACE%" dhcp
netsh interface ip set dns "%INTERFACE%" dhcp
goto END
:MANUAL
echo.
echo 即将对“%INTERFACE%”进行设置
ECHO 即将生效的 IP 地址是%IP% 
ECHO 即将生效的 MASK 是%MASK% 
ECHO 即将生效的GATEWAY地址是%GATEWAY%
ECHO 即将生效的 主DNS 地址是%DNS%
echo.
netsh interface ip set address name="%INTERFACE%" source=static addr=%IP% mask=%MASK%
echo IP地址及子网掩码设置完成
netsh interface ip set address name="%INTERFACE%" gateway=%GATEWAY% gwmetric=0
echo 网关地址设置完成
netsh interface ip set dns name="%INTERFACE%" source=static addr=%DNS% register=PRIMARY
echo 主DNS地址设置完成
goto end
:end
echo.
pause

顺便了解了一下bat文件的写法

rem是注释，应该是remarks的意思

echo就是回显

set IP=192.168.0.10是定义并设置变量

addr=%IP%是引用变量

有点像makefile的变量用法。

netsh应该是network shell，是windows系统本身提供的功能强大的网络配置命令行工具。