ARM新一期第一天

ARM新一期第一天

一、s3c440启动过程

大多数ARM芯片都是从0地址启动的
Nor 启动：NOR flash基地址为0，片内RAM地址为0x4000 0000 why ?
cpu读出 nor 上指令，执行，取址执行
NAND启动：片内 4K RAM基地址为0
2440硬件把 NAND 前4K内容复制到片内RAM，然后CPU从 0 地址取出指令执行

二、点亮LED灯

1. 查看芯片原理图和手册（配置为输出引脚，设置状态）
2. 写代码
   
   
   寄存器：
   LDR:读内存，LDR R0,[R1] 把地址R1上的数据，读入R0
   LDR R0,=0X12345678 伪指令，并不存在的指令，因为一个ARM指令32位，包含指令和数据，数据不能是32位的，不然无法表征是是什么指令，所以引入伪指令。
   STR:写内存，STR R0,[R1] 把R0的数据写入R1地址处
   以下代码使用了简单粗暴的方法（破坏了寄存器）
   代码：

.text //表示是代码段
.global _start//开始的位置

/* 配置GPF4为输出引脚
 * 把0x100写到地址0x56000050
 */
 ldr r1, =0x56000050
 ldr r0, =0x100 /* mov r0, #0x100 */
 str r0, [r1]
 
/* 设置GPF4输出高电平 
 * 把0写到地址0x56000054
 */
 ldr r1, =0x56000054
 ldr r0, =0 /* mov r0, #0 */
 str r0, [r1]
 
 /* 死循环 */
halt:
 b halt

Makefile:

all:
 arm-linux-gcc -c -o led_on.o led_on.S
 arm-linux-ld -Ttext 0 led_on.o -o led_on.elf
 arm-linux-objcopy -O binary -S led_on.elf led_on.bin
 arm-linux-objdump -D led_on.elf > led_on.dis//反汇编
clean:
 rm *.bin *.o *.elf在这里插入代码片

objcopy用法：
-O bfdname == --output-target=bfdname
指定输出文件的bfdname
-S==–strip-all
不从源文件拷贝符号信息和relocation信息
DISASSEMBLY:

led_on.elf:     file format elf32-littlearm
Disassembly of section .text:
00000000 <_start>:
   0: e59f1014  ldr r1, [pc, #20] ; 1c <.text+0x1c>//ARM三级流水线，当执行此指令时，在（当前指令+4）处译码，在（当前指令）+8处，执行，此时pc的值是当前当前指令 +8.
   4: e3a00c01  mov r0, #256 ; 0x100
   8: e5810000  str r0, [r1]
   c: e59f100c  ldr r1, [pc, #12] ; 20 <.text+0x20>
  10: e3a00000  mov r0, #0 ; 0x0
  14: e5810000  str r0, [r1]
00000018 <halt>:
  18: eafffffe  b 18 <halt>
  1c: 56000050  undefined
  20: 56000054  undefined

mov指令码：

C代码：
main函数：

int main()
{
 unsigned int *pGPFCON = (unsigned int *)0x56000050;
 unsigned int *pGPFDAT = (unsigned int *)0x56000054;
 /* 配置GPF4为输出引脚 */
 *pGPFCON = 0x100; 
 /* 设置GPF4输出0 */
 *pGPFDAT = 0;
 return 0;
}

问题：
①谁来调用main函数？
②main函数变量保存在内存中，这个内存地址是多少？
答：我们需要一个汇编代码，给main函数设置内存，调用main
汇编代码：

.text
.global _start
_start:
 /* 设置内存: sp 栈 */
 ldr sp, =4096  /* nand启动 */ why？
// ldr sp, =0x40000000+4096  /* nor启动 */why？
 /* 调用main */
 bl main
halt:
 b halt

C代码反汇编：

led.elf:     file format elf32-littlearm
Disassembly of section .text:
00000000 <_start>:
   0: e3a0da01  mov sp, #4096 ; 0x1000
   4: eb000000  bl c <main>
00000008 <halt>:
   8: eafffffe  b 8 <halt>
0000000c <main>:
   c: e1a0c00d  mov ip, sp
  10: e92dd800  stmdb sp!, {fp, ip, lr, pc}
  14: e24cb004  sub fp, ip, #4 ; 0x4
  18: e24dd008  sub sp, sp, #8 ; 0x8
  1c: e3a03456  mov r3, #1442840576 ; 0x56000000
  20: e2833050  add r3, r3, #80 ; 0x50
  24: e50b3010  str r3, [fp, #-16]
  28: e3a03456  mov r3, #1442840576 ; 0x56000000
  2c: e2833054  add r3, r3, #84 ; 0x54
  30: e50b3014  str r3, [fp, #-20]
  34: e51b2010  ldr r2, [fp, #-16]
  38: e3a03c01  mov r3, #256 ; 0x100
  3c: e5823000  str r3, [r2]
  40: e51b2014  ldr r2, [fp, #-20]
  44: e3a03000  mov r3, #0 ; 0x0
  48: e5823000  str r3, [r2]
  4c: e3a03000  mov r3, #0 ; 0x0
  50: e1a00003  mov r0, r3
  54: e24bd00c  sub sp, fp, #12 ; 0xc
  58: e89da800  ldmia sp, {fp, sp, pc}
Disassembly of section .comment:
00000000 <.comment>:
   0: 43434700  cmpmi r3, #0 ; 0x0
   4: 4728203a  undefined
   8: 2029554e  eorcs r5, r9, lr, asr #10
   c: 2e342e33  mrccs 14, 1, r2, cr4, cr3, {1}
  10: Address 0x10 is out of bounds.

汇编指令分析：
stmdb：把多个寄存器的值写入内存，sp！是说sp改为被修改的值，高编号寄存器存于高地址
stmdb sp!, {fp, ip, lr, pc}

ldmia:读内存，写入多个寄存器，sp不带！，值不会发生改变
ldmia sp, {fp, sp, pc}：栈中值依次取出来，赋值给fp，sp，pc，也是按照高编号高地址的顺序，和括号中的顺序无关
内存示意图：

按键操作LED标准代码：
C代码：

#include "s3c2440_soc.h"
void delay(volatile int d)
{
 while (d--);
}
int main(void)
{
 int val1, val2; 
 /* 设置GPFCON让GPF4/5/6配置为输出引脚 */
 GPFCON &= ~((3<<8) | (3<<10) | (3<<12));
 GPFCON |=  ((1<<8) | (1<<10) | (1<<12));
 /* 配置3个按键引脚为输入引脚:
  * GPF0(S2),GPF2(S3),GPG3(S4)
  */
 GPFCON &= ~((3<<0) | (3<<4));  /* gpf0,2 */
 GPGCON &= ~((3<<6));  /* gpg3 */
 /* 循环点亮 */
 while (1)
 {
  val1 = GPFDAT;
  val2 = GPGDAT;
  if (val1 & (1<<0)) /* s2 --> gpf6 */
  {
   /* 松开 */
   GPFDAT |= (1<<6);
  }
  else
  {
   /* 按下 */
   GPFDAT &= ~(1<<6);
  }
  if (val1 & (1<<2)) /* s3 --> gpf5 */
  {
   /* 松开 */
   GPFDAT |= (1<<5);
  }
  else
  {
   /* 按下 */
   GPFDAT &= ~(1<<5);
  }
  if (val2 & (1<<3)) /* s4 --> gpf4 */
  {
   /* 松开 */
   GPFDAT |= (1<<4);
  }
  else
  {
   /* 按下 */
   GPFDAT &= ~(1<<4);
  } 
 }
 return 0;
}

头文件：

#ifndef  __S3C2440_SOC_H
#define  __S3C2440_SOC_H

#define     __REG(x)     (*(volatile unsigned int *)(x))

#define     GPFCON                   __REG(0x56000050)  //Port F control                                   
#define     GPFDAT                   __REG(0x56000054)  //Port F data  
#define     GPGCON                   __REG(0x56000060)  //Port G control                                   
#define     GPGDAT                   __REG(0x56000064)  //Port G data 

汇编代码判断Nor or Nand 进行设置栈：

.text
.global _start
_start:
 /* 关闭看门狗 */
 ldr r0, =0x53000000
 ldr r1, =0
 str r1, [r0]
 /* 设置内存: sp 栈 */
 /* 分辨是nor/nand启动
  * 写0到0地址, 再读出来
  * 如果得到0, 表示0地址上的内容被修改了, 它对应ram, 这就是nand启动
  * 否则就是nor启动
  */
 mov r1, #0
 ldr r0, [r1] /* 读出原来的值备份 */
 str r1, [r1] /* 0->[0] */ 
 ldr r2, [r1] /* r2=[0] */
 cmp r1, r2   /* r1==r2? 如果相等表示是NAND启动 */
 ldr sp, =0x40000000+4096 /* 先假设是nor启动 */
 moveq sp, #4096  /* nand启动 */
 streq r0, [r1]   /* 恢复原来的值 */
 bl main
halt:
 b halt