1、寄存器
CPU内部里有很多寄存器R1~R15
GPIO控制器里也有很多寄存器GPFCON GPFDATA等等
我们写代码时，可以直接访问R1~R15，
但是我们想访问GPIO控制器里的寄存器时，需要地址。
（注：GPIO控制器里的寄存器的地址和内存地址相当于不同小区里的门牌号）
2、怎么编写一个LED程序
（1）查看原理图
n表示低电平有效 , 我们搜索下nLED_1:
（2）打开芯片手册,设置引脚
（3）编写汇编代码
.text：表明是个代码段
程序代码如下：
/***** 编写第1个程序点亮LED *****/
.text
.global _start
_start:
/*配置GPF4为输出引脚
*将0x100写入地址0x56000050
*/
MOV R0, #0x100 //相当于LDR R0，=0x100
LDR R1, =0x56000050
STR R0, [R1]
/*配置GPF4为高电平
*将0写入地址0x56000054
*/
MOV R0, #0
LDR R1, =0x56000054
STR R0, [R1]
/*死循环*/
halt:
B halt
注意为什么需要死循环？
如果不死循环的话，此程序执行完后，就跑去执行其他东西，其他东西是什么我们并不知道，后果可能不可预料。
先编译：
arm-linux-gcc -c -o led_on.o led_on.s;
再链接：
arm-linux-ld -Ttext 0 led_on.o -o led_on.elf;
生成bin文件：
arm-linux-objcopy -O binary -S led_on.elf led_on.bin；
可以写入makefile文件：
all:
arm-linux-gcc -c -o led_on.o led_on.S
arm-linux-ld -Ttext 0 led_on.o -o led_on.elf
arm-linux-objcopy -O binary -S led_on.elf led_on.bin
clean:
rm *.bin *.o *.elf
arm-linux-objcopy的意思：
1、概述
arm-linux-objcopy被用来复制一个目标文件的内容到另一个文件中.此选项可以进行格式的转换
2、选项
-S --strip-all Remove all symbol and relocation information
删除所有符号和重定位信息
-O --output-target Create an output file in format
创建一个输出文件格式
http://blog.sina.com.cn/s/blog_1404a9e570102wuu6.html
3、分析汇编代码——汇编与机器码
（1）生成反汇编文件
在前面的Makefile中加上：
arm-linux-objdump -D led_on.elf > led_on.dis #将.elf文件反汇编到 .dis文件
arm-linux-objdump的意思：
1、概述
arm-linux-objdump常用来显示二进制文件信息,常用来查看反汇编代码
2、选项
—dissassemble-all或者-D 反汇编所有段
http://blog.chinaunix.net/uid-23254875-id-341029.html
生成的led_on.dis就是反汇编文件，如下：
led_on.elf: file format elf32-littlearm
Disassembly of section .text:
00000000 <_start>:
0: e59f1014 ldr r1, [pc, #20] ; 1c <.text+0x1c>
4: e3a00c01 mov r0, #256 ; 0x100
8: e5810000 str r0, [r1]
c: e59f100c ldr r1, [pc, #12] ; 20 <.text+0x20>
10: e3a00000 mov r0, #0 ; 0x0
14: e5810000 str r0, [r1]
00000018 <halt>:
18: eafffffe b 18 <halt>
1c: 56000050 undefined
20: 56000054 undefined
第一列是地址，第二列是机器码，第三列是汇编；
在2440这个SOC里面，R0-R15都在CPU里面可以打开文件<ARM指令集E004armproc.chm>查看16个寄存器，其中：
R13 别名：sp （Stack Pointer）栈指针
R14 别名：lr （Link Register）返回地址
R15 别名：pc （program Counter）程序计数器=当前指令+8
为什么PC寄存器的计数值需要在当前指令的地址基础上+8？
CPU是以三级流水线的方式工作的：当前执行A地址的指令，已经对A+4地址的指令译码，已经在读取A+8地址的指令，因此A+8就是PC的值
（2）通过反汇编文件，了解LDR R1, =0x56000050伪指令是如何变成存在的ARM指令
ldr r0,=0x100即是转换成了mov r0,#256
然而伪指令是：
ldr r1, =0x56000050被转换成ldr r1, [pc, #20]
==> r1 = [pc + 20] = [(0+8) + 20] = [0x1c] 因此去0x1c地址上读取出 56000050
（3）立即数
作业：led_on.bin文件存放的就是机器码，我们只通过修改bin文件，点亮led2(GPF5)
参照GPF4 4: e3a00c01 mov r0, #256 ; 0x100 ，可知mov r0, #0x100的机器码为e3a00c01, 我们如何改成mov r0, #0x400的机器码？
打开芯片手册< ARM Architecture Reference Manual.pdf >,搜索mov查看下mov的32位码：
11-0位是立即数，12位立即数的前4位是rotate，后8位是immed_8；
立即数=immed_8向右循环ratate*2；
因此e3a00c01的c01为立即数0x100的表示，所以我们把‘c01’替换掉；
替换成什么呢？
0x400的32位二进制为0000 0000 0000 0000 0000 0100 0000 0000；
则immed_8 = 1,1向右循环22位得到0x400，则rotate = 22/2 = 11；
11的二进制为1011，立即数的机器码的二级制就为1011[rotate] 00000001[immed_8]；
把101100000001转换为16进制为‘0xb01’；
则立即数0x400的机器码就为0xb01；
因此我们把GPF4得到的bin文件的e3a00c01修改为e3a00b01就可以点亮led2。
4、用C程序点亮led
led.c源码：
int main()
{
unsigned int *GPFCON = (unsigned int *)0x56000050;
unsigned int *GPFDAT = (unsigned int *)0x56000054;
/*配置GPF4为输出引脚*/
*GPFCON = 0x100;
/*配置GPF4输出0*/
*GPFDAT = 0;
return 0;
}
a.我们写出了main函数，谁去调用它？
b.main函数种变量保存在内存中，这个内存地址是多少？
答：我们需要写一个汇编代码，给main函数设置内存，然后去调用main函数
我们都知道，局部变量保存在栈中，但是栈的地址在哪是需要设置的
start.S源码：
.text
.global _start
_start:
/*设置内存：sp栈*/
ldr sp,=4096 /*nand启动*/ 0地址对应的4K空间，把栈设置在顶部
// ldr sp, =0x40000000 + 4096 /*nor启动*/
/*调用main,并保存返回地址，保存在lr寄存器离，返回地址就是下一句的halt，*/
bl main
halt:
b halt
makefile：
all:
arm-linux-gcc -c -o led.o led.c
arm-linux-gcc -c -o start.o start.S
arm-linux-ld -Ttext 0 start.o led.o -o led.elf
arm-linux-objcopy -O binary -S led.elf led.bin
arm-linux-objdump -D led.elf > led.dis
clean:
rm *.bin *.o *.elf *.dis
5、解析C程序的内部机制
（1）从C程序的执行过程，我们的疑惑与解答
start.s的作用：
① 设置栈
②调用main，并把返回地址(下一条指令的地址)保存在lr中
问题：
(1)汇编程序，为什么要设置栈？
因为设置栈，才能调用c函数。
https://blog.csdn.net/dcx1205/article/details/47184489
(2)栈的作用？
a.保存局部变量
b.保存lr等寄存器里的值
试想下，main函数的返回地址存在lr中，那么如果main函数里调用子函数，子函数的返回地址也存在lr中，不就被覆盖了吗？
说明栈不止保存lr寄存器的值，还有其他寄存器。
(3)调用者（main函数）如何传参给被调用者（子函数）？
通过r0-r3寄存器。
(4)被调用者如何传返回值给调用者？
通过r0-r3寄存器。
(5)怎么从栈中恢复lr等寄存器？
通过r4-r11寄存器。
（3）（4）（5）这三个问题，通过以下知识了解原理：
（2）ATPCS规则
ATPCS(ARM-THUMB procedure call standard ARM-THUMB过程调用标准) <查看韦东山的书 第三章>
①r0-r3
r0-r3寄存器是参数/结果寄存器：
调用者怎么传参给被调用者，被调用者怎么传返回值给调用者？
通过r0-r3寄存器。
②r4-r11
在函数中，r4-r11可能被使用，所以在函数的入口暂存它们的值，在函数的出口恢复它们原来的值。
（3）分析反汇编文件
led.dis如下：
led.elf: file format elf32-littlearm
Disassembly of section .text:
00000000 <_start>:
0: e3a0da01 mov sp, #4096 ; 0x1000
4: eb000000 bl c <main>
00000008 <halt>:
8: eafffffe b 8 <halt>
0000000c <main>:
c: e1a0c00d mov ip, sp
10: e92dd800 stmdb sp!, {fp, ip, lr, pc}
//pc = 当前地址+8 = 10+8 = 18
//lr = 8
//ip = 4096
//fp 未知
//最后sp=4080
14: e24cb004 sub fp, ip, #4 ; 0x4 //fp = ip-4 = 4096-4 =4092
18: e24dd008 sub sp, sp, #8 ; 0x8 //sp = 4080 - 8 = 4072
1c: e3a03456 mov r3, #1442840576 ; 0x56000000 //r3 = 0x56000000
20: e2833050 add r3, r3, #80 ; 0x50 //r3 = 0x56000050
24: e50b3010 str r3, [fp, #-16] //r3保存在 fp-16 = 4076 的地方
28: e3a03456 mov r3, #1442840576 ; 0x56000000 //r3 = 0x56000000
2c: e2833054 add r3, r3, #84 ; 0x54 //r3 = 0x56000054
30: e50b3014 str r3, [fp, #-20] //r3保存fp-20 = 4072 的地方
34: e51b2010 ldr r2, [fp, #-16] // 把fp-16 = 4076地方的值赋给r2，则r2=0x56000050
38: e3a03c01 mov r3, #256 ; 0x100 //r3 = 0x100
3c: e5823000 str r3, [r2] //把0x100存入 0x56000050的地址里
40: e51b2014 ldr r2, [fp, #-20] //把4072里的值赋给r2，则r2=0x56000054
44: e3a03000 mov r3, #0 ; 0x0 //r3=0x0
48: e5823000 str r3, [r2] //0x0存入0x56000054地址里
4c: e3a03000 mov r3, #0 ; 0x0 //r3 = 0x0
50: e1a00003 mov r0, r3 //r0 = 0x0 这里是c语言里return 0 的代码
54: e24bd00c sub sp, fp, #12 ; 0xc //sp = fp - 12 = 4092 - 12 = 4080
58: e89da800 ldmia sp, {fp, sp, pc} //恢复栈，从栈中恢复寄存器
//fp = [4080] = 原来保存的fp
//sp = [4084] = 4096
//pc [4088] = 8 说明又跳回0x8的地址了
Disassembly of section .comment:
00000000 <.comment>: //注释代码，bin文件里就没有保存这些
0: 43434700 cmpmi r3, #0 ; 0x0
4: 4728203a undefined
8: 2029554e eorcs r5, r9, lr, asr #10
c: 2e342e33 mrccs 14, 1, r2, cr4, cr3, {1}
10: Address 0x10 is out of bounds.
内存数据存放示意：
从以上反汇编代码中，我们知道了被调用者通过r0-r3寄存器，传返回值0给调用者
我们写一个程序，
看看调用者，如何传参给被调用者
led.c
void delay(volatile int d)
//volatile防止编译器优化，因为聪明点的编译器看到你这个函数没做什么事情，就不执行了
{
while (d--);
}
int led_on(int which)
{
unsigned int *pGPFCON = (unsigned int *)0x56000050;
unsigned int *pGPFDAT = (unsigned int *)0x56000054;
if (which == 4)
{
/* 配置GPF4为输出引脚 */
*pGPFCON = 0x100;
}
else if (which == 5)
{
/* 配置GPF5为输出引脚 */
*pGPFCON = 0x400;
}
/* 设置GPF4/5输出0 */
*pGPFDAT = 0;
return 0;
}
Start.s
.text
.global _start
_start:
/* 设置内存: sp 栈 */
ldr sp, =4096 /* nand启动 */
// ldr sp, =0x40000000+4096 /* nor启动 */
mov r0, #4 //通过R0~R3传传参
bl led_on
ldr r0, =100000 //灯太快，做个延迟
bl delay
mov r0, #5 //通过R0~R3传传参
bl led_on
halt:
b halt
makefile
all:
arm-linux-gcc -c -o led.o led.c
arm-linux-gcc -c -o start.o start.S
arm-linux-ld -Ttext 0 start.o led.o -o led.elf
arm-linux-objcopy -O binary -S led.elf led.bin
arm-linux-objdump -D led.elf > led.dis
clean:
rm *.bin *.o *.elf *.dis
led.dis
led.elf: file format elf32-littlearm
Disassembly of section .text:
00000000 <_start>:
0: e3a0da01 mov sp, #4096 ; 0x1000
4: e3a00004 mov r0, #4 ; 0x4
8: eb000012 bl 58 <led_on>
c: e59f000c ldr r0, [pc, #12] ; 20 <.text+0x20>
10: eb000003 bl 24 <delay>
14: e3a00005 mov r0, #5 ; 0x5
18: eb00000e bl 58 <led_on>
0000001c <halt>:
1c: eafffffe b 1c <halt>
20: 000186a0 andeq r8, r1, r0, lsr #13
00000024 <delay>:
24: e1a0c00d mov ip, sp
28: e92dd800 stmdb sp!, {fp, ip, lr, pc}
2c: e24cb004 sub fp, ip, #4 ; 0x4
30: e24dd004 sub sp, sp, #4 ; 0x4
34: e50b0010 str r0, [fp, #-16]
38: e51b3010 ldr r3, [fp, #-16]
3c: e2433001 sub r3, r3, #1 ; 0x1
40: e50b3010 str r3, [fp, #-16]
44: e51b3010 ldr r3, [fp, #-16]
48: e3730001 cmn r3, #1 ; 0x1
4c: 0a000000 beq 54 <delay+0x30>
50: eafffff8 b 38 <delay+0x14>
54: e89da808 ldmia sp, {r3, fp, sp, pc}
00000058 <led_on>:
58: e1a0c00d mov ip, sp
5c: e92dd800 stmdb sp!, {fp, ip, lr, pc}
60: e24cb004 sub fp, ip, #4 ; 0x4
64: e24dd00c sub sp, sp, #12 ; 0xc
68: e50b0010 str r0, [fp, #-16]
6c: e3a03456 mov r3, #1442840576 ; 0x56000000
70: e2833050 add r3, r3, #80 ; 0x50
74: e50b3014 str r3, [fp, #-20]
78: e3a03456 mov r3, #1442840576 ; 0x56000000
7c: e2833054 add r3, r3, #84 ; 0x54
80: e50b3018 str r3, [fp, #-24]
84: e51b3010 ldr r3, [fp, #-16]
88: e3530004 cmp r3, #4 ; 0x4
8c: 1a000003 bne a0 <led_on+0x48>
90: e51b2014 ldr r2, [fp, #-20]
94: e3a03c01 mov r3, #256 ; 0x100
98: e5823000 str r3, [r2]
9c: ea000005 b b8 <led_on+0x60>
a0: e51b3010 ldr r3, [fp, #-16]
a4: e3530005 cmp r3, #5 ; 0x5
a8: 1a000002 bne b8 <led_on+0x60>
ac: e51b2014 ldr r2, [fp, #-20]
b0: e3a03b01 mov r3, #1024 ; 0x400
b4: e5823000 str r3, [r2]
b8: e51b3018 ldr r3, [fp, #-24]
bc: e3a02000 mov r2, #0 ; 0x0
c0: e5832000 str r2, [r3]
c4: e3a03000 mov r3, #0 ; 0x0
c8: e1a00003 mov r0, r3
cc: e24bd00c sub sp, fp, #12 ; 0xc
d0: e89da800 ldmia sp, {fp, sp, pc}
Disassembly of section .comment:
00000000 <.comment>:
0: 43434700 cmpmi r3, #0 ; 0x0
4: 4728203a undefined
8: 2029554e eorcs r5, r9, lr, asr #10
c: 2e342e33 mrccs 14, 1, r2, cr4, cr3, {1}
10: Address 0x10 is out of bounds.
448
被折叠的 条评论
为什么被折叠?
到【灌水乐园】发言
