游标与其它的遍历行记录方式

--0. 定义表变量及测试变量，并插入初始化数据
DECLARE @TempTable TABLE(Id INT, TName NVARCHAR(MAX))
DECLARE @row   INT,  @name  NVARCHAR(MAX), @beginT DATETIME

DECLARE @kkk INT, @maxRecords INT
SET @kkk=1
set @maxRecords= 100000
WHILE (@kkk<=@maxRecords)
BEGIN
	INSERT INTO @TempTable SELECT @kkk,CONVERT(VARCHAR(max),@kkk)+'r'
	SET @kkk=@kkk+1
END

--SELECT * FROM   @TempTable

---------------------- 第 1 种循环方式: 利用游标 ------------------------------------------
SET @beginT = GETDATE()
--1. 定义游标, 从一个查询语句中
DECLARE c CURSOR FOR SELECT Id,TName FROM @TempTable ORDER BY Id DESC

--注意：如果游标声明时加了@, 则应先声明再给值
--DECLARE @c2 CURSOR 
--SET @c2 = CURSOR FOR SELECT Id,TName FROM @TempTable ORDER BY Id DESC

--2. 打开游标
OPEN c
--3. 将游标定位到下一行
FETCH NEXT FROM c INTO @row,@name
--4. 当FETCH语句成功, 执行
WHILE @@FETCH_STATUS = 0
BEGIN
    --SELECT @row AS Id,@name TName
    --5. 在循环中将游标定位到下一行
    FETCH NEXT FROM c INTO @row,@name
END
--6. 关闭游标
CLOSE c
--7. 释放游标 
DEALLOCATE c

SELECT '记录数：'+CONVERT(VARCHAR(max),@maxRecords)+', 总时间(毫秒)：' +  CONVERT(VARCHAR(max),DATEDIFF(ms,@beginT,getdate()))
--记录数：100000, 总时间(毫秒)：3576

---------------------- 第 2 种循环方式: 利用表变量与 Row_Number() 函数 ---------------------------

SET @beginT = GETDATE()
--1. 定义相同结构的表变量
DECLARE @T2 TABLE (RowNum INT, Id INT, TName NVARCHAR(MAX))

--2. 将查询结果插入到表变量中
INSERT INTO @T2
	SELECT ROW_NUMBER() OVER(ORDER BY Id DESC), Id, TName  FROM @TempTable

--3. 定义循环变量
DECLARE @r INT, @maxRow INT
SELECT @r = 1, @maxRow = COUNT(1) FROM @T2

--4. 执行循环
WHILE (@r<=@maxRow)
BEGIN
	--SELECT * FROM @T2 t WHERE t.RowNum = @r
	SET @r = @r + 1
END

SELECT '记录数：'+CONVERT(VARCHAR(max),@maxRecords)+', 总时间(毫秒)：' +  CONVERT(VARCHAR(max),DATEDIFF(ms,@beginT,getdate()))
--记录数：100000, 总时间(毫秒)：1643

-- 总结：
-- 1、游标的效率低一些，而且使用没有第2种方式方便；
-- 2、但第2种方式，如果表的记录数过多， 超过10万， 应增大日志文件, 并清空一次日志，否则会出错。
-- DUMP TRANSACTION dbName WITH NO_LOG