版本库钩子：pre-revprop-change 修订版本属性修改的通知

版本库钩子：pre-revprop-change 修订版本属性修改的通知
描述：

pre-revprop-change钩子在修订版本属性修改之前，正常提交范围之外被执行，不象其他钩子，这个钩子默认是拒绝所有的属性修改，钩子必须实际存在并且返回一个零值，这样属性修改才能实现。
如果pre-revprop-change钩子没有实现或返回一个非零值，对属性的修改就不会成功，所以的标准错误输出会返回到客户端。
输入参数:

传递给你钩子程序的命令行参数，按照顺序是：

1. 版本库路径
2. 要修改属性的修订版本
3. 企图修改属性的认证用户名
4. 属性名称已修改
5. 变更描述：A (添加的)，D (删除的)或M (修改的)

此外，Subversion通过标准输入将属性值传递给钩子程序。

pre-revprop-change.cmd，这个willor 测试通过，放到版本库的hooks目录下即可

@ECHO OFF
:: Set all parameters. Even though most are not used, in case you want to add
:: changes that allow, for example, editing of the author or addition of log messages.
set repository=%1
set revision=%2
set userName=%3
set propertyName=%4
set action=%5

:: Only allow the log message to be changed, but not author, etc.
if /I not "%propertyName%" == "svn:log" goto ERROR_PROPNAME

:: Only allow modification of a log message, not addition or deletion.
if /I not "%action%" == "M" goto ERROR_ACTION

:: Make sure that the new svn:log message is not empty.
set bIsEmpty=true
for /f "tokens=*" %%g in ('find /V ""') do (
set bIsEmpty=false
)
if "%bIsEmpty%" == "true" goto ERROR_EMPTY

goto :eof

:ERROR_EMPTY
echo Empty svn:log messages are not allowed. >&2
goto ERROR_EXIT

:ERROR_PROPNAME
echo Only changes to svn:log messages are allowed. >&2
goto ERROR_EXIT

:ERROR_ACTION
echo Only modifications to svn:log revision properties are allowed. >&2
goto ERROR_EXIT

:ERROR_EXIT
exit /b 1

--------- 以下是别的地方拷贝的， willor 未测试--------------
允许用户修改Subversion日志的钩子脚本 (windows)

我想用过Subversion的人一定有过这样的问题：“为什么不允许用户修改日志？”，因为这种改变不可还原（目前这个操作还没有受到版本控制的管理），所以这项功能默认是被禁止的。如果要开启它，必须设置一个pre-revprop-change钩子。

版本库生成后，hooks目录下就存在一些钩子脚本的模板，用户可以作为参考。这里我们可以把已经存在的pre-revprop- change.tmpl复制一份，将复制后的文件名改为pre-revprop-change.bat，钩子就设置好了。注意Windows下钩子脚本必 须以.bat或者.exe的扩展名形式存在。

默认的钩子模板使用的是linux下的脚本语言，不能在Windows下运行。所以我们必须重写，这里介绍用批处理文件来写钩子脚本的方法。最简 单的允许修改日志的pre-revprop-change.bat连一行都不需要，直接把pre-revprop-change.bat的内容清空就行 了，因为按照Subversion的约定，钩子脚本返回0就是允许修改任何属性。（关于钩子脚本的约定可参考这篇文章 http://blog.donews.com/foxgem/archive/2005/11/03/613854.aspx）

但是假如我们希望作些判断，比如只允许修改日志，而不允许修改用户名或者其他属性，那么下面是一个范例：

SET REPOS="%1"
SET REV="%2"
SET USER="%3"
SET PROPNAME="%4"
SET ACTION="%5"

IF %ACTION% == "M" (IF %PROPNAME% == "svn:log" (EXIT 0))

ECHO "Changing revision properties %PROPNAME% is prohibited" >&2
EXIT 1
利用Subversion的一个程序svnlook，脚本中可以访问的信息就不仅仅只有传递进来的5个参数了，从而可以实现更多的功能。比如判断修改日志的用户是不是以前进行提交的那个作者，如果不是就不允许修改。

只允许用户修改自己的svn日志的钩子脚本：

for /f "usebackq" %%k in (`svnlook author %1 -r%2`) do @set var=%%k

if "%3" == "%var%" goto test
if "%3" == "li" goto test
exit 1

:test
if "%4" == "svn:log" exit 0
echo Property '%4' cannot be changed >&2
exit 1
实现每人可以修改自己的log日志，而管理员li可以任意修改。这个例子是从网上摘抄来的，因为手头上缺少svnlook，所以没有进行测试。
----------------------------------------------------------------------

Subversion提交强制写日志(windows)

在每次提交的时候写明提交的目的是一个很好的习惯，Subversion默认没有提供，但是可以通过钩子实现：

将下面的代码存为pre-commit.bat放到版本库的hooks目录下即可，当你不写日志提交的话就会报告错误。（如果你下载使用，需要修改SVN_BINDIR为你的Subversion安装的程序目录）


@echo off
set SVN_BINDIR=d:\Subversion\bin
setlocal
set REPOS=%1
set TXN=%2
rem check that logmessage contains at least 10 characters
%SVN_BINDIR%\svnlook log "%REPOS%" -t "%TXN%" | findstr ".........." > nul
if %errorlevel% gtr 0 goto err
exit 0
:err
echo Empty log message not allowed. Commit aborted! 1>&2
exit 1