使用XSL将小写数值转化为中文大写数值

最新推荐文章于 2019-03-04 10:17:15 发布
最新推荐文章于 2019-03-04 10:17:15 发布
阅读量3.1k 收藏
点赞数
分类专栏： WEB开发 XML 文章标签： xsl stylesheet encoding border 测试 output
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/yjs_lh/article/details/330732
版权

在MSXML中使用 <xsl:number format="&#x58f9"/> 等特定的format，可以将小写数值转化为大写数值。但是当XSL解析器不支持这种转换时只能得到一个整数值。

使用下面的XSL，可以正确的将一个数值转换为大写，或者转换为人民币。

<?xml version="1.0" encoding="gb2312"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output encoding="gb2312" method="html"/>
 <!--人民币转大写 只处理两位小数，第三位小数将被四舍五入-->
 <!--
 版权所有 叶建生 yjs_lh@sohu.com yjs_lh@sina.com
 @version 1.0 2005.03.26 01:58 于重庆南坪
 -->
 <xsl:template name="RMB">
  <xsl:param name="value"/>
  <xsl:choose>
   <xsl:when test="contains($value,'.')">
    <xsl:if test="translate(substring-before($value,'.'),'0','') != ''">
    <xsl:call-template name="TOUPPERCHSTR">
     <xsl:with-param name="value" select="substring-before($value,'.')"/>
    </xsl:call-template>
    <xsl:text>元</xsl:text>
    </xsl:if>
    <xsl:variable name="d" select="round(substring(substring-after(concat($value,'000'), '.'), 1, 3) div 10)"/>
    <xsl:variable name="d1" select="floor($d div 10)"/>
    <xsl:variable name="d2" select="$d mod 10"/>
    <xsl:if test="$d1&gt;0">
     <xsl:call-template name="UPPERCHAR">
      <xsl:with-param name="value" select="$d1"/>
     </xsl:call-template>
     <xsl:text>角</xsl:text>
    </xsl:if>
    <xsl:if test="$d2 &gt; 0">
     <xsl:call-template name="UPPERCHAR">
      <xsl:with-param name="value" select="$d2"/>
     </xsl:call-template>
     <xsl:text>分</xsl:text>
    </xsl:if>
    <xsl:if test="not($d2) or $d2=0">整</xsl:if>
   </xsl:when>
   <xsl:otherwise>
    <xsl:call-template name="TOUPPERCHSTR">
     <xsl:with-param name="value" select="$value"/>
    </xsl:call-template>
    <xsl:text>元整</xsl:text>
   </xsl:otherwise>
  </xsl:choose>
 </xsl:template>
 <!--  
  至少处理可 16 位整数而不丢失精度
 -->
 <!--转换数值为大写，传入的参数将被四舍五入取整-->
 <xsl:template name="TOUPPERCHSTR">
  <xsl:param name="value"/>
  <xsl:variable name="v" select="round($value)"/>
  <xsl:choose>
   <xsl:when test="$v &lt; 0">
    <xsl:text>负</xsl:text>
    <xsl:call-template name="TOUPPERCHSTR">
     <xsl:with-param name="value" select="$v * -1"/>
    </xsl:call-template>
   </xsl:when>
   <xsl:when test="$v = 0">零</xsl:when>
   <xsl:when test="string-length($value) &gt; 8">
    <xsl:if test="translate(substring($value,1,string-length($value) - 8), '0','') != ''">
     <xsl:call-template name="TOUPPERCHSTR">
      <xsl:with-param name="value" select="substring($value,1,string-length($value) - 8)"/>
     </xsl:call-template>
     <xsl:text>亿</xsl:text>
    </xsl:if>
    <xsl:variable name="s" select="substring($value,string-length($value) - 7)"/>
    <xsl:if test="number($s) &gt; 0">
     <xsl:if test="translate(substring($value,1,string-length($value) - 8), '0','') != '' and substring($s,1,1) = '0'">零</xsl:if>
     <xsl:call-template name="TOUPPERCHSTR">
      <xsl:with-param name="value" select="$s"/>
     </xsl:call-template>
    </xsl:if>
   </xsl:when>
   <xsl:when test="string-length($v) &gt; 4">
    <xsl:call-template name="TOUPPERCHSTR">
     <xsl:with-param name="value" select="substring($v,1,string-length($v) - 4)"/>
    </xsl:call-template>
    <xsl:text>万</xsl:text>
    <xsl:variable name="s" select="substring($v,string-length($v) - 3)"/>
    <xsl:if test="number($s) &gt; 0">
     <xsl:if test="substring($s,1,1) = '0'">零</xsl:if>
     <xsl:call-template name="TOUPPERCHSTR">
      <xsl:with-param name="value" select="$s"/>
     </xsl:call-template>
    </xsl:if>
   </xsl:when>
   <xsl:otherwise>
    <xsl:call-template name="UPPERCHAR">
     <xsl:with-param name="value" select="substring($v,1,1)"/>
    </xsl:call-template>
    <xsl:call-template name="getweightname">
     <xsl:with-param name="value" select="string-length($v)"/>
    </xsl:call-template>
    <xsl:variable name="v1" select="number(substring($v,2))"/>
    <xsl:if test="$v1 &gt;= 1">
     <xsl:if test="substring($v, 2, 1) = '0'">
      <xsl:choose>
       <xsl:when test="string-length($v) &gt; 5 and $v1 &lt; 10000">万</xsl:when>
       <xsl:otherwise>零</xsl:otherwise>
      </xsl:choose>
     </xsl:if>
     <xsl:call-template name="TOUPPERCHSTR">
      <xsl:with-param name="value" select="$v1"/>
     </xsl:call-template>
    </xsl:if>
   </xsl:otherwise>
  </xsl:choose>
 </xsl:template>
 <!--将数值直接转为大写文字-->
 <xsl:template name="UPPERCHAR">
  <xsl:param name="value"/>
  <xsl:value-of select="translate($value,'0123456789','零壹贰叁肆伍陆柒捌玖')"/>
 </xsl:template>
 <!--获得位的中文位权名-->
 <xsl:template name="getweightname">
  <xsl:param name="value"/>
  <xsl:choose>
   <xsl:when test="$value mod 4 = 2">拾</xsl:when>
   <xsl:when test="$value mod 4 = 3">佰</xsl:when>
   <xsl:when test="$value mod 4 = 0">仟</xsl:when>
   <xsl:otherwise/>
  </xsl:choose>
 </xsl:template>
 
 <!--用于测试-->
 <xsl:template match="/">
  <html>
   <head>
    <META http-equiv="Content-Type" content="text/html;charset=gb2312"/>
    <title> 小写转大写函数示例 </title>
   </head>
   <body>
    <table border="1">
     <tbody>
      <tr>
       <th>原数值</th>
       <th>中文数值</th>
       <th>人民币大写</th>
      </tr>
      <xsl:for-each select="//i">
       <tr>
        <td>
         <xsl:value-of select="."/>
        </td>
        <td>
         <xsl:call-template name="TOUPPERCHSTR">
          <xsl:with-param name="value" select="."/>
         </xsl:call-template>
        </td>
        <td>
         <xsl:call-template name="RMB">
          <xsl:with-param name="value" select="."/>
         </xsl:call-template>
        </td>
       </tr>
      </xsl:for-each>
     </tbody>
    </table>
   </body>
  </html>
 </xsl:template>
</xsl:stylesheet>

测试用的XML：

<?xml version="1.0" encoding="GB2312"?>
<Root>
 <i>1</i>
 <i>10</i>
 <i>100</i>
 <i>1000</i>
 <i>10000</i>
 <i>100000</i>
 <i>1000000</i>
 <i>10000000</i>
 <i>100000000</i>
 <i>1000000000</i>
 <i>10000000000</i>
 <i>100000000000</i>
 <i>1000000000000</i>
 <i>10000000000000</i>
 <i>100000000000000</i>
 <i>1000000000000000</i>
 <i>10000000000000000</i>
 <i>100000000000000000</i>
 <i>1000000000000000000</i>
 <i>10000000000000000000</i>
 <i>100000000000000000000</i>
 <i>0000000000000000000000</i>
 <i>00000000001000000000000</i>
 <i>000000000000000100000000</i>
 <i>00000000000000000100000000</i>
 <i>000000000000000000100000000</i>
 <i>0000000000000000000100000000</i>
 <i>00000000000000000000100000000</i>
 <i>000000000000000000000100000000</i>
 <i>00000000000000000000000000000001</i>
 <i>10000000000000000000001000000000</i>
 <i>1000000000000000000000100000000</i>
 <i>100000000000000000000010000000</i>
 <i>10000000000000000000001000000</i>
 <i>1000000000000000000000100000</i>
 <i>100000000000000000000010000</i>
 <i>10000000000000000000001000</i>
 <i>1000000000000000000000100</i>
 <i>100000000000000000000010</i>
 <i>00000200000000000000011</i>
 <i>0000000000000000000001</i>
 <i>000000000000000010000</i>
 <i>000000000000000000001</i>
 <i>10000100000000000001</i>
 <i>1000001000000000001</i>
 <i>100200000000000001</i>
 <i>10000000000000001</i>
 <i>1010000000000001</i>
 <i>100000001000001</i>
 <i>10001000000001</i>
 <i>1000000010001</i>
 <i>100101001010</i>
 <i>10000010001</i>
 <i>1000000001</i>
 <i>100000001</i>
 <i>10000001</i>
 <i>1000001</i>
 <i>100001</i>
 <i>10001</i>
 <i>1001</i>
 <i>101</i>
 <i>11</i>
 <i>9</i>
 <i>123456789</i>
 <i>-123456789</i>
 <i>12313.123</i>
 <i>12313.125</i>
 <i>12313.1236</i>
 <i>12313.001</i>
 <i>12313.005</i>
 <i>12313.501</i>
 <i>12313.606</i>
 <i>00.606</i>
 <i>0.006</i>
 <i>5.606</i>
 <i>10012301</i>
 <i>012010</i>
</Root>

输出结果：

原数值

中文数值

人民币大写

1

壹

壹元整

10

壹拾

壹拾元整

100

壹佰

壹佰元整

1000

壹仟

壹仟元整

10000

壹万

壹万元整

100000

壹拾万

壹拾万元整

1000000

壹佰万

壹佰万元整

10000000

壹仟万

壹仟万元整

100000000

壹亿

壹亿元整

1000000000

壹拾亿

壹拾亿元整

10000000000

壹佰亿

壹佰亿元整

100000000000

壹仟亿

壹仟亿元整

1000000000000

壹万亿

壹万亿元整

10000000000000

壹拾万亿

壹拾万亿元整

100000000000000

壹佰万亿

壹佰万亿元整

1000000000000000

壹仟万亿

壹仟万亿元整

10000000000000000

壹亿亿

壹亿亿元整

100000000000000000

壹拾亿亿

壹拾亿亿元整

1000000000000000000

壹佰亿亿

壹佰亿亿元整

10000000000000000000

壹仟亿亿

壹仟亿亿元整

100000000000000000000

壹万亿亿

壹万亿亿元整

0000000000000000000000

零

零元整

00000000001000000000000

壹万亿

壹万亿元整

000000000000000100000000

壹亿

壹亿元整

00000000000000000100000000

壹亿

壹亿元整

000000000000000000100000000

壹亿

壹亿元整

0000000000000000000100000000

壹亿

壹亿元整

00000000000000000000100000000

壹亿

壹亿元整

000000000000000000000100000000

壹亿

壹亿元整

00000000000000000000000000000001

壹

壹元整

10000000000000000000001000000000

壹仟万亿亿零壹拾亿

壹仟万亿亿零壹拾亿元整

1000000000000000000000100000000

壹佰万亿亿零壹亿

壹佰万亿亿零壹亿元整

100000000000000000000010000000

壹拾万亿亿亿壹仟万

壹拾万亿亿亿壹仟万元整

10000000000000000000001000000

壹万亿亿亿零壹佰万

壹万亿亿亿零壹佰万元整

1000000000000000000000100000

壹仟亿亿亿零壹拾万

壹仟亿亿亿零壹拾万元整

100000000000000000000010000

壹佰亿亿亿零壹万

壹佰亿亿亿零壹万元整

10000000000000000000001000

壹拾亿亿亿零壹仟

壹拾亿亿亿零壹仟元整

1000000000000000000000100

壹亿亿亿零壹佰

壹亿亿亿零壹佰元整

100000000000000000000010

壹仟万亿亿零壹拾

壹仟万亿亿零壹拾元整

00000200000000000000011

贰拾亿亿零壹拾壹

贰拾亿亿零壹拾壹元整

0000000000000000000001

壹

壹元整

000000000000000010000

壹万

壹万元整

000000000000000000001

壹

壹元整

10000100000000000001

壹仟亿零壹佰万亿零壹

壹仟亿零壹佰万亿零壹元整

1000001000000000001

壹佰亿零壹万亿零壹

壹佰亿零壹万亿零壹元整

100200000000000001

壹拾亿零贰佰万亿零壹

壹拾亿零贰佰万亿零壹元整

10000000000000001

壹亿亿零壹

壹亿亿零壹元整

1010000000000001

壹仟零壹拾万亿零壹

壹仟零壹拾万亿零壹元整

100000001000001

壹佰万亿零壹佰万零壹

壹佰万亿零壹佰万零壹元整

10001000000001

壹拾万零壹拾亿零壹

壹拾万零壹拾亿零壹元整

1000000010001

壹万亿零壹万零壹

壹万亿零壹万零壹元整

100101001010

壹仟零壹亿零壹佰万壹仟零壹拾

壹仟零壹亿零壹佰万壹仟零壹拾元整

10000010001

壹佰亿零壹万零壹

壹佰亿零壹万零壹元整

1000000001

壹拾亿零壹

壹拾亿零壹元整

100000001

壹亿零壹

壹亿零壹元整

10000001

壹仟万零壹

壹仟万零壹元整

1000001

壹佰万零壹

壹佰万零壹元整

100001

壹拾万零壹

壹拾万零壹元整

10001

壹万零壹

壹万零壹元整

1001

壹仟零壹

壹仟零壹元整

101

壹佰零壹

壹佰零壹元整

11

壹拾壹

壹拾壹元整

9

玖

玖元整

123456789

壹亿贰仟叁佰肆拾伍万陆仟柒佰捌拾玖

壹亿贰仟叁佰肆拾伍万陆仟柒佰捌拾玖元整

-123456789

负壹亿贰仟叁佰肆拾伍万陆仟柒佰捌拾玖

负壹亿贰仟叁佰肆拾伍万陆仟柒佰捌拾玖元整

12313.123

壹亿贰仟叁佰壹拾叁

壹万贰仟叁佰壹拾叁元壹角贰分

12313.125

壹亿贰仟叁佰壹拾叁

壹万贰仟叁佰壹拾叁元壹角叁分

12313.1236

壹拾贰亿叁佰壹拾叁

壹万贰仟叁佰壹拾叁元壹角贰分

12313.001

壹亿贰仟叁佰壹拾叁

壹万贰仟叁佰壹拾叁元整

12313.005

壹亿贰仟叁佰壹拾叁

壹万贰仟叁佰壹拾叁元壹分

12313.501

壹亿贰仟叁佰壹拾肆

壹万贰仟叁佰壹拾叁元伍角整

12313.606

壹亿贰仟叁佰壹拾肆

壹万贰仟叁佰壹拾叁元陆角壹分

00.606

壹

陆角壹分

0.006

零

壹分

5.606

陆

伍元陆角壹分

10012301

壹仟零壹万贰仟叁佰零壹

壹仟零壹万贰仟叁佰零壹元整

012010

壹万贰仟零壹拾

壹万贰仟零壹拾元整

yjs_lh
关注
  • 0
    点赞
  • 踩
  • 0
    收藏
    觉得还不错? 一键收藏
  • 1
    评论
专栏目录
Python将xml和xsl转换为html的方法
09-22
主要介绍了Python将xml和xsl转换为html的方法,实例分析了使用libxml2模块操作xml和xsl转换为html的技巧,具有一定参考借鉴价值,需要的朋友可以参考下
xsl 函数大全
爱莎可实验室
06-02 8946
XSLT supplies a number of functions. --------------------------------------------------------------------------------XSLT FunctionsName Description current() Returns the current node docum
如何在XSLT中将字符串转换为大写或小写形式
ddjq1044的博客
04-17 215
　　查阅w3school的文档，你会看到XSLT提供了两个系统函数用于转换字符串的大小写形式：upper-case()和lower-case()。但是这两个函数是针对于XSLT2.0以上版本的，Microsoft所使用的XSLT都是1.0版本的，所以当你在代码中使用这两个函数时会提示无效。这里有一个替代的解决方案，使用translate()函数可以解决这个问题。 <xsl:v...
利用XSL对XML数据进行加密和大小写转换
jxufewbt的专栏
08-08 1598
XML数据一个最普通的问题就是数据的大小写，在进行数据转换时常常产生令人头疼的麻烦。下面就是一个 解决的办法。 假设你有一些数据要发送到另外一个系统，它也识别XML格式的数据，而且要求全部大写，例子数据如下：  例子1：person.xml             net_lover        Xianhui Meng        孟宪会    假设你要转换成如下的格式：
XSL:XSL基础之九
天地会
05-06 543
 本实例目的：用函数实现统计功能Student009.xml    0000001张三910000002李四90Student009.xslhttp://www.w3.org/1999/XSL/Transform">平均分:  说明：CEILING(X)取不小于X的最小整数FLOOR(X)取不大于X的最大整数ROUND(X)取四舍五入后的整数COUN
Python实现把xml或xsl转换为html格式
09-22
主要介绍了Python实现把xml或xsl转换为html格式,本文直接给出实现代码,需要的朋友可以参考下
XSL转换XML的技术
03-18
编写文件名为student2.xsl的XSL文件，其中，用<xsl:sort>对学生信息数据按照专业进行排序，并用<xsl:if>筛选出专业为“计算机”的学生信息。要求显示出的计算机专业的学生信息记录单元格背景色为黄色，字符为加粗的...
WordXML-to-HTML:XSL将MS Word生成的XML转换为HTML
05-01
这些核心转换将Word XML转换为符合HTMLBook规范HTML，并由少数其他ruby和XSL转换建立，以创建可插入较大的Macmillan工作流程HTML文件。 具体来说，这些XSL转换是bookmaker_htmlmaker流程的一部分-。 对于格式良好...
JS和XSLT里都有的数据计算问题.
沉淀雄起
05-25 1189
在IE里写个JS脚本: alert((7.89*2.5).toFixed(2));竟然弹出19.72, 而不是19.73 接着试了试: alert(7.89*2.5);   弹出19.72499999998. 而不是19.725 才知道原来是这样使得四舍五入至小数点后两位结果值成了19.72, 而不是19.73. 最后只好自己写了个函数代替toFixed函数:function Round(a_Nu
利用xslt与xml实现具体字段字母的大小写转换
ApplicationJoke的博客
09-04 667
定义一个全局的变量 &lt;xsl:variable name="smallcase" select="'abcdefghijklmnopqrstuvwxyz'" /&gt; &lt;xsl:variable name="uppercase" select="'ABCDEFGHIJKLMNOPQRSTUVWXYZ'" /&gt; 利用 translate函数进行数据转换 例如： &a
跟我学XSL（二）(转)
hyde82的专栏
07-14 1750
表一、运算符与特殊字符  运算符描述/选择子元素，返回左侧元素的直接子元素；如果"/"位于最左侧表示选择根结点的直接子元素//递归下降，不论深度，搜索指定的元素；如果位于最左侧表示从根结点出发递归下降搜索指定元素.表示当前元素*通配符，选择任意元素，不考虑名字@取得属性值，作为属性名的前缀@*通配符，选择任意属性，不考虑名字:名字作用范围分隔符，将名字作用范围前缀与元素或属性名分隔开来!*在相关节
format-number，返回一位小数xslt
LaoChai的专栏
09-12 2395
  1">Dis/@v)=0">1米  0">Dis/@v)>0 and number(1000">Dis/@v)>1000"> select="format-number((number(Dis/@v) div 1000),#.0)"/>公里  Dis/@v)>0 and number(Dis/@v)<1000"> select="number(Dis/@v)"/>米     1
xsl标签函数
夜上窗的博客
03-04 2532
http://www.w3school.com.cn/xml/xml_validator.asp --xslt，xml方法 http://www.w3school.com.cn/xsl/xsl_w3celementref.asp 一、 XML验证器 字符串转换成数字格式 &lt;PremAmt&gt;&lt;xsl:value-of select='format-number($vTot...
xsl:choose, xsl:when 和 xsl:otherwise
shuilv2000的专栏
09-27 4614
xsl:choose, xsl:when 和 xsl:otherwise xsl:if语法没有else的属性。如果我们要进行多项选择，那么就要使用xsl:choose / xsl:when / xsl:otherwise系列流程控制语法了。具体的使用请看下面的XSL文件例子：  No name available 说明：首先在PEOPLE节点下寻找属
go语言 运用xsl将xml转化为html
最新发布
05-19
要使用 Go 语言将 XML 转换为 HTML，可以使用第三方库如 `github.com/antchfx/xquery/xml` 和 `github.com/antchfx/xslt`。 以下是一个基本示例： ```go package main import ( "io/ioutil" "log" "os" ...

“相关推荐”对你有帮助么？

  • 非常没帮助
  • 没帮助
  • 一般
  • 有帮助
  • 非常有帮助
提交
评论 1
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值