用XSL做字符串替换

最新推荐文章于 2020-09-11 10:36:29 发布

yjs_lh

最新推荐文章于 2020-09-11 10:36:29 发布

阅读量1.1w

点赞数 1

分类专栏： WEB开发 XML 文章标签： xsl stylesheet encoding table 正则表达式 javascript

本文链接：https://blog.csdn.net/yjs_lh/article/details/353268

版权

WEB开发同时被 2 个专栏收录

3 篇文章 0 订阅

订阅专栏

XML

3 篇文章 0 订阅

订阅专栏

稍熟悉XPATH的人都知道，在XSL中使用translate函数可以将一个字符串进行逐字符替换。例如：

translate("bar","abc","ABC") 将得到 BAr

translate("--aaa--","abc-","ABC") 将得到 AAA。

但是，如果要替换一个子字符串为另一个子字符串，对XPATH1.0而言，用translate就有点力不从心了。

一般来讲，在XSL中进行字符串替换有以下两种方法：

(1)使用ms:script嵌入XSL实现，但要求XML解析器必须是MS的。

(2)使用纯XSL模板来实现。

当然，使用第(1)种方法有个好处就是可以充分利用javascript强大的字符串处理功能，例如还可以使用正则表达式。这里使用了一个纯XSL模板来实现字符串替换。源代码如下，其中后面的部分是用于测试的示例：

<?xml version="1.0" encoding="gb2312"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:template name="StringReplace">
  <xsl:param name="SrcString"/>
  <xsl:param name="FromString"/>
  <xsl:param name="ToString"/>
  <xsl:choose>
   <xsl:when test="contains($SrcString,$FromString)">
    <xsl:value-of select="substring-before($SrcString,$FromString)"/>
    <xsl:value-of select="$ToString"/>
    <xsl:call-template name="StringReplace">
     <xsl:with-param name="SrcString" select="substring-after($SrcString,$FromString)"/>
     <xsl:with-param name="FromString" select="$FromString"/>
     <xsl:with-param name="ToString" select="$ToString"/>
    </xsl:call-template>
   </xsl:when>
   <xsl:otherwise><xsl:value-of select="$SrcString"/></xsl:otherwise>
  </xsl:choose>
</xsl:template>

<xsl:template match="/">
  <html>
   <body>
    <table border="1">
     <caption>字符串替换函数</caption>
     <tr>
      <th>源字符串</th>
      <th>FromString</th>
      <th>ToString</th>
      <th>替换结果</th>
     </tr>
     <xsl:for-each select="//S">
      <tr>
      <td>
       <xsl:value-of select="Source"/>
      </td>
      <td>
       <xsl:value-of select="From"/>
      </td>
      <td>
       <xsl:value-of select="To"/>
      </td>
      <td>
       <xsl:call-template name="StringReplace">
        <xsl:with-param name="SrcString" select="Source"/>
        <xsl:with-param name="FromString" select="From"/>
        <xsl:with-param name="ToString" select="To"/>
       </xsl:call-template>
      </td>
      </tr>
     </xsl:for-each>
    </table>
   </body>
  </html>
</xsl:template>
</xsl:stylesheet>

用于测试的XML：

<?xml version="1.0" encoding="GB2312"?>
<Root>
<S>
  <Source>asdflaksdjfalsdkfjaslkdjf</Source>
  <From>a</From>
  <To>bbb</To>
</S>
<S>
  <Source>asdflaksdjfalsdkfjaslkdjf</Source>
  <From>flaksdjfals</From>
  <To>bbb</To>
</S>
<S>
  <Source>asdflaksdjfalsdkfjaslkdjf</Source>
  <From>djfa</From>
  <To>bbb</To>
</S>
<S>
  <Source>asdflaksdjfalsdkfjaslkdjf</Source>
  <From>sdf</From>
  <To>VVV</To>
</S>
<S>
  <Source>我不是四川人</Source>
  <From>四川</From>
  <To>重庆</To>
</S>
<S>
  <Source>SELECT * FROM TAble where a=b</Source>
  <From>=</From>
  <To>*=</To>
</S>
</Root>

转换结果：

字符串替换函数
源字符串	FromString	ToString	替换结果
asdflaksdjfalsdkfjaslkdjf	a	bbb	bbbsdflbbbksdjfbbblsdkfjbbbslkdjf
asdflaksdjfalsdkfjaslkdjf	flaksdjfals	bbb	asdbbbdkfjaslkdjf
asdflaksdjfalsdkfjaslkdjf	djfa	bbb	asdflaksbbblsdkfjaslkdjf
asdflaksdjfalsdkfjaslkdjf	sdf	VVV	aVVVlaksdjfalsdkfjaslkdjf
我不是四川人	四川	重庆	我不是重庆人
SELECT * FROM TAble where a=b	=	*=	SELECT * FROM TAble where a*=b

yjs_lh

关注

1
点赞
踩
4

收藏

觉得还不错? 一键收藏
5
评论
用XSL做字符串替换

稍熟悉XPATH的人都知道，在XSL中使用translate函数可以将一个字符串进行逐字符替换。例如：translate("bar","abc","ABC") 将得到 BArtranslate("--aaa--","abc-","ABC") 将得到 AAA。但是，如果要替换一个子字符串为另一个子字符串，对XPATH1.0而言，用translate就有点力不从心了。一般来讲，在XSL中进行字符串替换
复制链接

扫一扫

专栏目录