2644 线段树练习题一

题目

桌子上零散地放着若干个盒子，桌子的后方是一堵墙。如右图所示。现在从桌子的前方射来一束平行光， 把盒子的影子投射到了墙上。问影子的总宽度是多少？

题解

这道题目是一个经典的模型。在这里，可以略去某些处理的步骤，直接分析重点问题，可以把题目抽象地描述如下：x轴上有若干条线段，求线段覆盖的总长度。

然后可以发现这是一道线段树的模型：
线段树的每个节点都表示一个线段，它的左儿子通常是线段的左半部分，右儿子就是右半部分。在处理问题时，可以用数组储存线段树（此时数组的大小>=2n），也可以在递归中直接设两个变量来表示

线段树的每个节点上往往都增加了一些其他的域。在这些域中保存了某种动态维护的信息，视不同情况而定。这些域使得线段树具有极大的灵活性，可以适应不同的需求。

在这道题中给线段树每个节点增加一个域cover。cover=1表示该结点所对应的区间被完全覆盖，cover=0表示该结点所对应的区间未被完全覆盖。

最后进行统计

时间复杂度O（m log n）

代码

type
  bec=record
        b,e:longint;
        c:longint;
      end;
var
  n,m,i,j,k:longint;
  t:array[1..1000000]of bec;

procedure setup(p:longint);
var
  m:longint;
begin
  if t[p].e-t[p].b>1 then
    begin
      m:=(t[p].b+t[p].e) div 2;
      t[p*2].b:=t[p].b;
      t[p*2].e:=m;
      t[p*2+1].b:=m;
      t[p*2+1].e:=t[p].e;
      setup(p*2);
      setup(p*2+1);
    end;
end;

procedure insert(p,l,r:longint);
var
  m:longint;
begin
  if t[p].c=0 then
    begin
      m:=(t[p].e+t[p].b) div 2;
      if (l=t[p].b)and(r=t[p].e) then t[p].c:=1 else
      if r<=m then insert(p*2,l,r) else
      if l>=m then insert(p*2+1,l,r) else
        begin
          insert(p*2,l,m);
          insert(p*2+1,m,r);
        end;
    end;
end;

function count(p:longint):longint;
begin
  if t[p].c=1 then count:=t[p].e-t[p].b else
  if t[p].e-t[p].b=1 then count:=0 else
  if t[p].e-t[p].b>1 then count:=count(p*2)+count(p*2+1);
end;

begin
  readln(n);
  readln(m);
  t[1].b:=1;t[1].e:=n;
  setup(1);
  for i:=1 to m do
    begin
      readln(j,k);
      insert(1,j,k);
    end;
  writeln(count(1));
end.